Selecting all records in a Line

I don't think this can be done in a single select statement. You could however write a loop in a block like this to achieve a similar effect.

set serveroutput on
declare
outstr varchar2(500);
cursor word_cursor is select name from address_book where rownum < 10;
begin
for c in word_cursor loop
 outstr := outstr || c.name || ',';
end loop;
dbms_output.put_line(outstr);
end;
/

I added the "where rownum < 10" in the code to limit the number of rows, you could remove that for getting all records. You would also need to increase the size of outstr accordingly.

I don't want to use PL/SQL.
I'm using Oracle 8i.
Thanks

SDutta is correct, it would be difficult to do in a single statement, especially if you don't know the number of rows, But you could create a function that could be used for any table and any columns.  It depends on the version of oracle.  It looks involved, but once the TYPE and FUNCTION are created, it's always there.

Provide from the AskTom web page

***************************************************************
***        To concatenate rows into columns in version 9i for any table.          ***
***************************************************************

create or replace type string_agg_type as object
 (total varchar2(4000),
  static function ODCIAggregateInitialize
        (sctx IN OUT string_agg_type )  return number,
  member function ODCIAggregateIterate
        (self IN OUT string_agg_type ,
         value IN varchar2 )            return number,
  member function ODCIAggregateTerminate
        (self IN string_agg_type,
         returnValue OUT  varchar2,
         flags IN number)               return number,
  member function ODCIAggregateMerge
        (self IN OUT string_agg_type,
         ctx2 IN string_agg_type)       return number
 );
/

create or replace type body string_agg_type is
   
 static function ODCIAggregateInitialize
       (sctx IN OUT string_agg_type) return number is
 begin
   sctx := string_agg_type( null );
   return ODCIConst.Success;
 end;
 
 member function ODCIAggregateIterate
       (self IN OUT string_agg_type,
        value IN varchar2 )    return number is
 begin
   self.total := self.total || ',' || value;
   return ODCIConst.Success;
 end;
   
 member function ODCIAggregateTerminate
       (self IN string_agg_type,
        returnValue OUT varchar2,
        flags IN number)    return number    is
 begin
   returnValue := ltrim(self.total,',');
   return ODCIConst.Success;
 end;
   
 member function ODCIAggregateMerge
       (self IN OUT string_agg_type,
        ctx2 IN string_agg_type)   return number is
 begin
   self.total := self.total || ctx2.total;
   return ODCIConst.Success;
 end;
end;
 /


CREATE or replace FUNCTION stragg
         (input varchar2 ) RETURN varchar2
 PARALLEL_ENABLE AGGREGATE USING string_agg_type;
/



TO USE:   Select STRAGG(NAME) from address_book ;