Pull User Info from Active Directory using .net for SSIS package

ALTER PROCEDURE [dbo].[spActiveDirectoryTable]
AS
BEGIN
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON;
 
---------------------
-- Declare Variables
---------------------
DECLARE @chvAlphaChars VARCHAR(60)
,@chvSearch VARCHAR(10)
,@chvSearchLevel1 VARCHAR(1)
,@chvSearchLevel2 VARCHAR(1)
,@chvSearchLevel3 VARCHAR(1)
,@intcountLevel1 INT
,@intcountLevel2 INT
,@intcountLevel3 INT
,@intRowCount INT
,@strSQL NVARCHAR(4000) ,@strADSISQL NVARCHAR(4000)
 
------------------------------------
-- Delete existing data from table
------------------------------------
TRUNCATE TABLE dbo.ActiveDirectoryUsers
 
-------------------------------------------------
-- Search letters to cycle through
-- any chars, but the first char must be a space
-------------------------------------------------
SET @chvAlphaChars = ' ABCDEFGHIJKLMNOPQRSTUVWXYZ'
 
---------------------------
-- Start on non space char
SET @intcountLevel1 = 2
---------------------------
 
--------------------
-- First level loop
--------------------
WHILE @intcountLevel1 <= LEN(@chvAlphaChars) BEGIN
-- Get first level char
SET @chvSearchLevel1 = SUBSTRING(@chvAlphaChars,@intcountLevel1,1)
-- Reset start on space
SET @intcountLevel2 = 1
-- Second level loop
WHILE @intcountLevel2 <= LEN(@chvAlphaChars) BEGIN
-- Reset start on space
SET @intcountLevel3 = 1
-- Third level loop
WHILE @intcountLevel3 <= LEN(@chvAlphaChars) BEGIN
 
-------------------------------------------------------------------------------------------------------------
-- Setup the string to search for. By using the trim function we can form each level depending on no records
-- eg A 99, B 1000 > BA 9, BB 20 etc
-- Trim the spaces forming just A, B, C ; AA, AB for search etc
-------------------------------------------------------------------------------------------------------------
SET @chvSearchLevel1 = SUBSTRING(@chvAlphaChars,@intcountLevel1,1)
SET @chvSearchLevel2 = RTRIM(SUBSTRING(@chvAlphaChars,@intcountLevel2,1))
SET @chvSearchLevel3 = RTRIM(SUBSTRING(@chvAlphaChars,@intcountLevel3,1))
SET @chvSearch = @chvSearchLevel1 + @chvSearchLevel2 + @chvSearchLevel3
 
SET @strADSISQL = 'SELECT samaccountname,sn,givenname,mail,mobile,telephonenumber,homephone,facsimiletelephonenumber,physicaldeliveryofficename, useraccountcontrol '
+ CHAR(13) + 'FROM ''''LDAP://xx.ssss.kkkkkk.com'''' '
+ CHAR(13) + 'WHERE objectCategory = ''''Person'''' '
+ CHAR(13) + 'AND objectClass = ''''user'''' '
+ CHAR(13) + 'AND sAMAccountName = ''''' + @chvSearch + '*'''' '
 
SET @strSQL = 'INSERT INTO dbo.ActiveDirectoryUsers (EID,LastName,FirstName,EmailAddress,MobilePhone,WorkPhone,HomePhone,FaxNumber,OfficeLocation, UserControlAccount) '
+ CHAR(13) + 'SELECT samaccountname AS EID,sn AS LastName,givenname AS FirstName,mail AS EmailAddress,mobile AS MobilePhone,telephonenumber AS WorkPhone,homephone AS HomePhone,facsimiletelephonenumber AS FaxNumber,physicaldeliveryofficename AS OfficeLocation, useraccountcontrol as UserControlAccount '
+ CHAR(13) + 'FROM OPENQUERY(MVCIADADSI,''' + @strADSISQL + ''' ) '
 
EXEC SP_EXECUTESQL @strSQL
 
SET @intRowCount = @@ROWCOUNT
-- Prints what string is being searched for : no of inserts. DEBUG CODE
-- PRINT @chvSearch + ' : ' + CONVERT(VARCHAR,@intRowCount)
 
-- If searched on @chvSearchLevel1 and under 1000 then everything is fine so skip search2 to next search1 eg A > B
IF @intRowCount < 1000
AND @chvSearchLevel2 = ''
SET @intcountLevel2 = @intcountLevel2 + 100
 
-- If searched on @chvSearchLevel2 and under 1000 then everything is fine so skip to next search2 eg AA > AB
IF @intRowCount < 1000
AND @chvSearchLevel3 = ''
SET @intcountLevel3 = @intcountLevel3 + 100
 
-- Else over 1000 so increment third level
SET @intcountLevel3 = @intcountLevel3 + 1 END
 
------------------------------------
-- Increment next second level char
------------------------------------
SET @intcountLevel2 = @intcountLevel2 + 1 END
 
------------------------------------
-- Increment next first level char
------------------------------------
SET @intcountLevel1 = @intcountLevel1 + 1
END
END

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102: