Timer problem converting VB6 to VBA

Option Explicit 
Private Const CURSOR_PRECISION = 2
Private Const RESIZE_CURSOR = vbSizeNS 
Private Declare Function GetCursorPos Lib "user32.dll" (ByRef lpPoint As POINTAPI) As Long
Private Declare Function ScreenToClient Lib "user32.dll" (ByVal hwnd As Long, ByRef lpPoint As POINTAPI) As Long
Private Type POINTAPI
   x As Long
   y As Long
End Type 
Private m_bIsResizing As Boolean
Private m_lRowToResize As Long
Private m_lOrigRowHeight As Long
Private m_lYMouseDown As Long
Private m_lCursorX As Long
Private m_lCursorY As Long 

Private Sub Form_Load()
   TimerGridMouseLeave.Enabled = False
   TimerGridMouseLeave.Interval = 20
   
   With iGrid1
      .ColCount = 5
      .RowCount = 15
      
      ' Some sample data for testing
      .CellValue(1, 1) = "The quick brown fox jumps over the lazy dog"
      .CellTextFlags(1, 1) = igTextWordBreak
      With .CellFont(3, 1)
         .Bold = True
         .Size = 16
      End With
      .CellValue(3, 1) = "Some text"
   End With
End Sub 
' The sub checks whether we need to indicate with the special mouse pointer
' that there is a row's bottom edge under the cursor and thus the row can be resized
Private Sub CheckResizePossible(ByVal pxCursor As Long, ByVal pyCursor As Long, _
   ByVal plRowUnderCursor As Long, ByVal plColUnderCursor As Long)
   
   Dim lLeft As Long, lTop As Long, lWidth As Long, lHeight As Long
   
   If plRowUnderCursor = 0 Or plColUnderCursor = 0 Then
      ' No row under the cursor.
      ' Check for the last row taking into account our precision.
      If iGrid1.RowCount > 0 Then
         iGrid1.CellBoundary iGrid1.RowCount, 1, lLeft, lTop, lWidth, lHeight
         Dim lDelta As Long
         lDelta = pyCursor - (lTop + lHeight - 1)
         If lDelta >= 0 And lDelta <= CURSOR_PRECISION Then
            m_lRowToResize = iGrid1.RowCount
            GoTo AllowResizing
         End If
      End If
   Else
      ' The cursor is over a row.
      iGrid1.CellBoundary plRowUnderCursor, plColUnderCursor, lLeft, lTop, lWidth, lHeight
      If (lTop + lHeight - 1) - pyCursor <= CURSOR_PRECISION Then
         m_lRowToResize = plRowUnderCursor
         GoTo AllowResizing
      End If
      If plRowUnderCursor > 1 Then
         If pyCursor - lTop <= CURSOR_PRECISION Then
            m_lRowToResize = plRowUnderCursor - 1
            GoTo AllowResizing
         End If
      End If
   End If
   
   ' No resizing
   SetNoResizePossible
   Exit Sub
   
AllowResizing:
   Me.MousePointer = RESIZE_CURSOR ' this will also indicate for our code that the row can be resized
   m_lOrigRowHeight = iGrid1.RowHeight(m_lRowToResize)
   TimerGridMouseLeave.Enabled = True
End Sub 
Private Sub SetNoResizePossible()
   Me.MousePointer = vbDefault
   TimerGridMouseLeave.Enabled = False
End Sub 
Private Sub iGrid1_DblClick(ByVal lRow As Long, ByVal lCol As Long, bRequestEdit As Boolean)
   If Me.MousePointer = RESIZE_CURSOR Then
      ' Auto-height the row instead of editing
      bRequestEdit = False
      iGrid1.AutoHeightRow m_lRowToResize
      CheckResizePossible m_lCursorX, m_lCursorY, lRow, lCol
   End If
End Sub 
Private Sub iGrid1_MouseDown(Button As Integer, Shift As Integer, ByVal x As Single, ByVal y As Single, ByVal lRow As Long, ByVal lCol As Long, bDoDefault As Boolean, ByVal bOverCellCtrl As Boolean)
   If Me.MousePointer = RESIZE_CURSOR Then
      m_lYMouseDown = y
      m_bIsResizing = True
      bDoDefault = False ' do not select the cell in this mode
   End If
End Sub 
Private Sub iGrid1_MouseUp(Button As Integer, Shift As Integer, ByVal x As Single, ByVal y As Single, ByVal lRow As Long, ByVal lCol As Long, bDoDefault As Boolean)
   If Me.MousePointer = RESIZE_CURSOR Then
      m_bIsResizing = False
   End If
End Sub 
Private Sub iGrid1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As Single, ByVal y As Single, ByVal lRow As Long, ByVal lCol As Long)
   m_lCursorX = x: m_lCursorY = y
   
   If m_bIsResizing Then
      Dim lNewHeight As Long
      lNewHeight = m_lOrigRowHeight + y - m_lYMouseDown
      If lNewHeight < 0 Then lNewHeight = 0
      iGrid1.RowHeight(m_lRowToResize) = lNewHeight
      Exit Sub
   End If 
   CheckResizePossible x, y, lRow, lCol
End Sub 
' Here we check whether we need to set the mouse pointer to the default value
' when the user moves it outside of the cell area.
Private Sub TimerGridMouseLeave_Timer()
   If Not m_bIsResizing Then
      ' We do not receive the VB MouseMove event outsideof the cell area,
      ' so we should use WinAPI to get the mouse coordinates inside our control
      Dim pt As POINTAPI
      GetCursorPos pt ' in the screen coordinate system
      ScreenToClient iGrid1.hwnd, pt
      ' Now the pt structure conatins what we need
      If pt.x < 0 Or pt.x >= iGrid1.Sys(igSysCellsAreaWidth) Or _
            pt.y < 0 Or pt.y >= iGrid1.Sys(igSysCellsAreaHeight) + iGrid1.Header.Height Then
         SetNoResizePossible
      End If
   End If
End Sub