ksilvoso
asked on
modify dconcat to allow linking on an integer field
How could I modify the dconcat code below (Thanks, MatthewsPatrick) to allow me to link on an integer field. The code works fine if I link on a text field but when I try to link on an integer field I get an error:
Here's the sql code in the query. Ancestor number is a text field:
ListSpouses: Nz(DConcat("' m ',[ancestor wife], [ancestor wife surname], [marriage date]","[jcnAncestorWife]" ,"[Ancesto r number] = '" & [Ancestor number] & "'"),"")
Here's the sql code in the query. Ancestor number is a text field:
ListSpouses: Nz(DConcat("' m ',[ancestor wife], [ancestor wife surname], [marriage date]","[jcnAncestorWife]"
Option Compare Database
Option Explicit
Function DConcat(ConcatColumns As String, tbl As String, Optional Criteria As String = "", _
Optional Delimiter1 As String = "; ", Optional Delimiter2 As String = " ", _
Optional Distinct As Boolean = True, Optional OrderBy As String = "", _
Optional Limit As Long = 0)
' Function by Patrick G. Matthews, basically embellishing an approach seen in many
' incarnations over the years
' Requires reference to Microsoft DAO library
' This function is intended as a "domain aggregate" that concatenates (and delimits) the
' various values rather than the more usual Count, Sum, Min, Max, etc. For example:
'
' Select Field1, DConcat("Field2", "SomeTable", "[Field1] = '" & Field1 & "'") AS List
' FROM SomeTable
' GROUP BY Field1
'
' will return the distinct values of Field1, along with a concatenated list of all the
' distinct Field2 values associated with each Field1 value.
' ConcatColumns is a comma-delimited list of columns to be concatenated (typically just
' one column, but the function accommodates multiple). Place field names in square
' brackets if they do not meet the customary rules for naming DB objects
' Tbl is the table/query the data are pulled from. Place table name in square brackets
' if they do not meet the customary rules for naming DB objects
' Criteria (optional) are the criteria to be applied in the grouping. Be sure to use And
' or Or as needed to build the right logic, and to encase text values in single quotes
' and dates in #
' Delimiter1 (optional) is the delimiter used in the concatenation (default is ", ").
' Delimiter1 is applied to each row in the code query's result set
' Delimiter2 (optional) is the delimiter used in concatenating each column in the result
' set if ConcatColumns specifies more than one column (default is ", ")
' Distinct (optional) determines whether the distinct values are concatenated (True,
' default), or whether all values are concatenated (and thus may get repeated)
' OrderBy (optional) indicates how to sort the results. The argument value should consist
' of an entire ORDER BY clause (without the actual words "ORDER BY"), or be omitted
' Limit (optional) places a limit on how many items are placed into the concatenated string.
' The Limit argument works as a TOP N qualifier in the SELECT clause
Dim rs As DAO.Recordset
Dim SQL As String
Dim ThisItem As String
Dim FieldCounter As Long
On Error GoTo ErrHandler
' Initialize to Null
DConcat = Null
' Build up a query to grab the information needed for the concatenation
SQL = "SELECT " & IIf(Distinct, "DISTINCT ", "") & _
IIf(Limit > 0, "TOP " & Limit & " ", "") & _
ConcatColumns & " " & _
"FROM " & tbl & " " & _
IIf(Criteria <> "", "WHERE " & Criteria & " ", "") & _
IIf(Trim(OrderBy) <> "", "ORDER BY " & OrderBy, "")
' Open the recordset and loop through it:
' 1) Concatenate each column in each row of the recordset
' 2) Concatenate the resulting concatenated rows in the function's return value
Set rs = CurrentDb.OpenRecordset(SQL)
With rs
Do Until .EOF
' Initialize variable for this row
ThisItem = ""
' Concatenate columns on this row
For FieldCounter = 0 To rs.Fields.Count - 1
ThisItem = ThisItem & Delimiter2 & Nz(rs.Fields(FieldCounter).Value, "")
Next
' Trim leading delimiter
ThisItem = Mid(ThisItem, Len(Delimiter2) + 1)
' Concatenate row result to function return value
DConcat = Nz(DConcat, "") & Delimiter1 & ThisItem
.MoveNext
Loop
.Close
End With
' Trim leading delimiter
If Not IsNull(DConcat) Then DConcat = Mid(DConcat, Len(Delimiter1) + 1)
GoTo Cleanup
ErrHandler:
' Error is most likely an invalid database object name, or bad syntax in the Criteria
DConcat = CVErr(Err.Number)
Cleanup:
Set rs = Nothing
End Function
I'm not sure what your goal is. What do you mean by "linking on an integer field"?
ListSpouses: Nz(DConcat("' m ',[ancestor wife], [ancestor wife surname], [marriage date]","[jcnAncestorWife]" ,"[Ancesto r number] = " & [Ancestor number]),"")
Here ya go :)
Here ya go :)
ASKER CERTIFIED SOLUTION
membership
This solution is only available to members.
To access this solution, you must be a member of Experts Exchange.
ASKER
Sorry I abandoned this question. It's because I abandoned the project but now I'm back on it. I forgot to close the question. Sorry about the etiquette breach. If you're still out there, cyberkiwi, could you still help me out with this? I still get an error message when I run the query with your altered sql statement.
Thanks
Thanks
Can you please elaborate on the error? What is the message that you get?
And are you using http:#a33845961 verbatim (just checking)?
And are you using http:#a33845961 verbatim (just checking)?