Set variables from text file

SETLOCAL ENABLEDELAYEDEXPANSION
will allow what  dexter3 is trying.

Quote from "set /?" :
Delayed environment variable expansion allows you to use a different
character (the exclamation mark) to expand environment variables at
execution time.  If delayed variable expansion is enabled, the above
examples could be written as follows to work as intended:

    set VAR=before
    if "%VAR%" == "before" (
        set VAR=after
        if "!VAR!" == "after" @echo If you see this, it worked
    )

replace the % with ! in the right spots above and you're all set,  pardon the pun.

2K
(\o/)

K_2K

I dont understand what do u mean.
Please explain it better, My skills in batch files are not the best  
=(

zawa,

Sorry,  I did not intend to confuse,  but to let dexter3 finish the work he spent so much time on and deserves credit for.

By placing ! instead of % for each variable you desire to be expanded during execute and not before, you get the desired effect.  
For instance: The first line FOR runs against (string1     <1000>) gets the entire loop for do and the entire if command to the last ) parsed with %counter% replaced by 0 (MS calls it "expanded") since that is it's value.  
   set %varname%%counter%=%%i
gets written by the command parser as
   set var0=string1
while executed, the counter gets bumped up, but the set line has already been written so the wrong variable gets set.  If we turn on delayed expansion:
   set %varname%!counter!=%%i
gets written by the command parser as
   set var!counter!=string1
While executed, the counter gets bumped up, and !counter! can acurately show the correct number where %counter% can not.

Something like this should do the job nicely, if you remember to use the strings you need after the pause and before ending the script:


@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set myfile=c:\temp\experts\mystrings.txt
set varname=var
set counter=0

rem I'm not sure if you can group the general DO command with parentheses
rem but I know you can within an IF statement, so compare to equals.
for /F "tokens=1,2 delims= " %%i in ('type %myFile% ^| find/i "1000"') do (
   set /A counter+=1
   set %varname%!counter!=%%i
   echo !counter! %%i
   )
echo Total strings found: %counter%
pause

SETLOCAL causes the variables to be local to that script, so if you really need all those extra strings laying around after the script finishes, you can't use SETLOCAL ENABLEDELAYEDEXPANSION.  I prever the above, change the pause to whatever command you need to use each variable set,  or simply use them inside the do loop and you don't need to keep track of them anyway.

It occurs to me that still does not answer your original question if you really want those strings left behind.

This one below uses a separate process to do the work, and leave behind VAR1 through VAR<whatever>.   No delayed expansion issues here because FOR only parses the entire DO loop:
   CALL :setprocess %%K
and %%K is the correct string you want, expanded immediately in all cases.


:setstrings.cmd
@echo off
set myfile=C:\Documents and Settings\Myusernam.Mymachine\My Documents\Batch\myfile.txt
set varname=var
set counter=0


for /F %%K in ( ' type "%myFile%" ^| find /i "1000" ' ) do CALL :setprocess %%K
goto :setdone

:setprocess
set /A counter+=1
set %varname%%counter%=%1
echo %counter% %1
goto :EOF

:setdone
echo Total strings found: %counter%
for %%K in ( myfile varname counter ) do set %%K=

Hello again,

 K_2K im using your first example that seems to work just fine, but i just need a final help.
How can i  get the variables so that i can work with them??
if i need to compare  the first string that he found %var1% with something, or %var15%.
EX: if %var%%counter15% == something goto end
its something like this that i need but i cant figure it out how to make it.
I dont know if i explained well, if u dont understand something please let me know.