Day Script Not Working Anymore

Thanks, but I need this script to work on any version of Windows no matter how the %date% is formatted. Hence the point of the first section of code where it analyises %date% and calculates the day name.

There was an adjustment I made to the original code that goes before this line:

set /A dayNum=%dd% + (2 * %mm%) + (3 * (%mm% + 1) / 5) + %yyyy% + (%yyyy% / 4) - (%yyyy% / 100) + (%yyyy% / 400) + 1

Here it is:

if /I %mm% LSS 3 set /a mm+=12&set /a yyyy-=1

Good Luck,
Steve

Can you explain what that does please Steve?

Will it be future proof for FOREVER?!

Can't say if it will work forever... The bit of code I added was left out of the original formula.

So if the month is less than 3 it adds 12 to the month and goes back 1 year... that right?

How does that find the right dayname?

You are correct. You'll have to look up the formula. Look at the prior question, I believe I posted links. Otherwise do a search on google. Got to run.

I have done some searches, but can't find anything about this particular script.

I've tried it now and the month is coming out at 14! So something aint right.

Did you implement my update correctly? Here's the first part of your code with the change:

@echo off
REM cls
REM setlocal ENABLEDELAYEDEXPANSION

set yyyy=
set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
 for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
    set %%x=%%u
    set %%y=%%v
    set %%z=%%w
    set $d1=
    set $tok=))
if "%yyyy%"=="" set yyyy=%yy%
if /I %yyyy% LSS 100 set /A yyyy=2000 + 1%yyyy% - 100
set /A dd=1%dd% - 100
set /A mm=1%mm% - 100

if /I %mm% LSS 3 set /a mm+=12&set /a yyyy-=1

set /A dayNum=%dd% + (2 * %mm%) + (3 * (%mm% + 1) / 5) + %yyyy% + (%yyyy% / 4) - (%yyyy% / 100) + (%yyyy% / 400) + 1
set /A dayNum=%dayNum% %% 7

echo dayNum=%dayNum%

Today, it displays the correct number 4.

You need the script to work on any windows version. Is the old windows 9x and ME included?
If so, this solution will not work on the old windows versions.

Steve, which variables should I be using as the output ones then? There is so many used it's hard to know.
For-Soft, sorry I meant I need it to work on new Windows versions - 2000/XP/2003/(Vista!) plus any that have a differently formated %date%

You can use:

yyyy
dd
mm
dayNum

Well that doesn't work here...

I get:

-------------
dayNum=5
03/02/2006
2005
3
14
-------------

From running with the variables echo'ed:

----------------------------------------------------------------------------------
@echo off
REM cls
REM setlocal ENABLEDELAYEDEXPANSION

set yyyy=
set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
 for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
    set %%x=%%u
    set %%y=%%v
    set %%z=%%w
    set $d1=
    set $tok=))
if "%yyyy%"=="" set yyyy=%yy%
if /I %yyyy% LSS 100 set /A yyyy=2000 + 1%yyyy% - 100
set /A dd=1%dd% - 100
set /A mm=1%mm% - 100

if /I %mm% LSS 3 set /a mm+=12&set /a yyyy-=1

set /A dayNum=%dd% + (2 * %mm%) + (3 * (%mm% + 1) / 5) + %yyyy% + (%yyyy% / 4) - (%yyyy% / 100) + (%yyyy% / 400) + 1
set /A dayNum=%dayNum% %% 7

echo dayNum=%dayNum%
echo %date%
echo %yyyy%
echo %dd%
echo %mm%
----------------------------------------------------------------------------------

I did think of setting the dd mm and yyyy variables to other variables before the new line, which does work, but trouble is that I want this to be as flexible as possible so I dont have to fix it every year.

Hey, if you want to make sure it works for every date and every year (within reason) why don't you hardcode the values and test it?

Remember that we do this here for free... You don't pay me anything to do your work. So stop complaining and take some responsibility for the code. I see you've answered some MS-DOS questions so you are no novice. Time to start learning as we all did here and stop whinning. Sorry for being blunt, but my hope is that you'll become a better DOS programmer if you just do a little of the work.

Sorry Steve. I wasn't complaining, didn't mean any offence certainly. Thanks anyways.

"future proof" for days on "every year possible" indicates knowing the code for leap years ( i don't have it memorized but something like every four years except not every 100 except not every 400 except . . . )   -  the bottom line is a true year is not nothing near a neat and pretty division of days, and some group of people long ago thought this type of adjustment sequence was better than setting the clocks back 6 hours X minutes and X seconds every year.  That would require adjustingworking hours every year but never worry about this being a leap year again.  having handled that little piece we could also re-lable Jan 1st as Monday each year as well.  

oops,  I digress again,  sry,  kinda.  

 My point is, several programs have solved this already, including vbscript, and the vbscript version is not too dificult to pull into DOS batch with a small learning curve.  
(For learning DOS batch, you're better off doing the whole thing with addition and subtraction in set commands and understanding the logic in each line, never forgetting numbers that start with 0 are NOT decimal, etc.  this wheele rewriting helps keep a valuable skill honed for other tasks that have not been pre-solved.)

Anywho,  lemme stop babbleing, poke around a few of my scripts that use vb to get date, and mod one to help a bit  . . .

This was easy, and the vb portion is minimal and understandable, but i don't like this version.  
It's kludgy and puts the conversion job in batch instead of VB

I didn't even finish this,  you have to copy the two lines from the weekday conversion to the month setting and change "1 Monday" to "1 January" and so forth.

I include it as an alternative for those who like mostly DOS, while i prefer to rewrite a version that uses the VB conversions that are faster, and also allow DOS to call the script only once.  Your virus checkers will like that better. (this version took a second or two on my machine and i feel that's the time to scan the temporary vbscript as it started up 7 times)

so,  you play with this or wait a bit for my second attempt:


:: dateas.bat
:: return date as day, date, month, etc
:: this is an re-usable example, not a finished product
:: i've prepended all my variables with t to help prevent conflicts with yours
::
:: you must skip to the "start" line, delete what you don't need and
:: re-adjust what you do need to fit your program.
::
@echo off
setlocal


:: setup - done once at the top
set tscript=%temp%\%~n0.vbs
set tget=cscript -nologo "%tscript%"
set tbatch=%temp%\%~n0_A.bat
:: write the vbscript to get time and difference - XP/2K/NT/9x all the same
>"%tscript%" echo sInterval = wscript.arguments^(0^)
>>"%tscript%" echo wscript.echo DatePart^(sInterval, now^)


:: time setup complete, include your own job setups here


:: subroutines here
goto :start

:setconversions
if "%1"=="%2" set thisis=%3
goto :EOF

:: end of subroutines

:start
for /f %%K in ('%tget% w') do set daynamefull=%%K
::convert 1 to Sunday, etc
for %%K in ("1 Sunday" "2 Monday" "3 Tuesday" "4 Wednesday" "5 Thursday" "6 Friday" "7 Saturday") do call :setconversions %daynamefull% %%~K
set daynamefull=%thisis%

for /f %%K in ('%tget% d') do set day=%%K

for /f %%K in ('%tget% m') do set monthname=%%K
::convert month 1 to Jan, etc

for /f %%K in ('%tget% yyyy') do set year=%%K
for /f %%K in ('%tget% h') do set hour=%%K
for /f %%K in ('%tget% m') do set minute=%%K
for /f %%K in ('%tget% s') do set second=%%K


echo %daynamefull% %day% %monthname% %year% %hour%:%minute%:%second%
pause


 

as i thought,  this is MUCH cleaner, allowing the vb functions to do the convert, even though it makes the vb part longer, and requires DOS to take in a specific format.
Note that a one line vbscript  (wscript.echo now) would also give DOS a date and time to work with, EXCEPT: Like the built in DOS dates and times, the regional registry and "Shortdate format" changeable in the control panel effect the output format of the now function making it different for different users on the same machine, so we're back again to string compares and gymnastics to straighten it out.  by streatching the vbscript out long enough to force a desired format, the DOS part becomes also much simpler to use.

Enjoy (\o/)

:: dateas.bat
:: return date as day, date, month, etc
:: this is an re-usable example
:: i've prepended all my variables with t to help prevent conflicts with yours
::
:: you must skip to the "start" line, delete what you don't need and
:: re-adjust what you do need to fit your program.
::
@echo off
setlocal

:: setup - done once at the top
set tscript=%temp%\%~n0.vbs
set tget=cscript -nologo "%tscript%"
set tbatch=%temp%\%~n0_A.bat
:: write the vbscript to get time and difference - XP/2K/NT/9x all the same
>"%tscript%" echo dTemp = now
>>"%tscript%" echo wscript.echo weekdayname ^( weekday ^( dTemp ^) ^) _
>>"%tscript%" echo      ^& " " ^& day ^( dtemp ^) _
>>"%tscript%" echo      ^& " " ^& monthname ^( month ^( dtemp ^) ^) _
>>"%tscript%" echo      ^& " " ^& year ^( dtemp ^) _
>>"%tscript%" echo      ^& " " ^& hour ^( dtemp ^) _
>>"%tscript%" echo      ^& " " ^& minute ^( dtemp ^) _
>>"%tscript%" echo      ^& " " ^& second ^( dtemp ^)

:: time setup complete, include your own job setups here


:start
for /f "tokens=1-7" %%K in ('%tget% weekday') do (
   set daynamefull=%%K
   set day=%%L
   set monthname=%%M
   set year=%%N
   set hour=%%O
   set minute=%%P
   set second=%%Q
   )

echo %daynamefull% %day% %monthname% %year% %hour%:%minute%:%second%
pause

ERROR in semantics !

Please change this one comment line:
:: write the vbscript to get time and difference - XP/2K/NT/9x all the same
to this one line instead:
:: write the vbscript to get time in a specific format

This above does NOT work in Windows 9x.
This above does NOT calculate differences.

Sorry, The first 5 lines of setup, I copied from a longer script to re-use the auto-nameing of temp files from another utility I wrote.  I did not include here the DOS SET commands into the vbscript that would allow you to call it with Windows 9x redirected to a temp and then run the temp to set the variables. Windows 9x does not understand FOR /F so this script fails there.

thanks (\o/),
2K

Thanks simonprr, I was a little stressed at work. I need to learn more patience... Sorry :)

No problem Steve, I know the feeling.

K_2K: Wow, this looks awesome! I'll check it out and let you know how I get on. Thanks!

K_2K, well, I've tested both of your scripts and they work nicely. I'm a litle confused with a few things, wonder if you can help....

Script1 and 2 both output basically the same info, what is really the difference between them? Both of them generate a VB script to do the job?

Are you saying that Script 2 is now fool proof and works everything out from whatever the date format is set in control panel? ie. it will work with any format of day/date and any year (even leap years)?

Can you explain Script 2 a little bit... I see that it creates the vb script to put the date info, but where it run it?
Is that this line:  set tget=cscript -nologo "%tscript%"

And whats this line for?:
set tbatch=%temp%\%~n0_A.bat
I don't see it create that bat file ?!

Cool stuff though, thanks :)