Batch file to change file names in dir to part of dir name

@ECHO OFF
REM Remove any local variables and allow for delayed expansion.
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM Change drive and directory - you will probably want to edit this.
CD /D Z:\
 
REM Iterate the directory tree, executing the rest of the FOR in each directory.
FOR /R . %%A IN (.) DO (
 
        REM Report where we are.
        ECHO Examining %%A
        
        REM Store just the name of the parent folder for later use.
        SET ParentFolder="%%~nxA"
        
        REM Initialize the file counter.
        SET FileCount=0
        
        REM Iterate the found subdirectory, counting the files and remembering the last name.
        FOR %%B IN ("%%~A"\*.RPT) DO (
                SET /A FileCount+=1
                SET FileName="%%~B"
        )
        
        REM If only 1 file was found then rename it.
        IF !FileCount! EQU 1 (
                ECHO Renaming !FileName! to !ParentFolder!.RPT
                REN !FileName! !ParentFolder!.RPT
        )
        
        REM If many files were found, then reset the counter and re-iterate the folder renaming as we go.
        IF !FileCount! GTR 1 (
                SET FileCount=0
                FOR %%B IN ("%%~A"\*.RPT) DO (
                        SET /A FileCount+=1
                        ECHO Renaming "%%~B" to !ParentFolder!_!FileCount!.RPT
                        REN "%%~B" !ParentFolder!_!FileCount!.RPT
                )
        )
)