Using batch file to save files with date and time stamp

Hi Marcus,

varSaveFile is your only file with a date and time portion in it. But is only written once, and that is a empty line. On every other occasion you use varNOTSigned, which is a fixed name containing the username as variable part.
However, even if not intended, this should open a notepad with the "correct" file containing all the stuff you put in it. And then send it.

As t0t0 tried to tell you already, %date% and %time% cannot be used without transformation in filenames, as there are slashes and colons, which are not allowed as part of filenames.

I for myself prefer to use a construction of

You can create a underscore in the filename easily by using

set installer=%installer: =_%

so the users do not need to use underscores.
However, why the space is a problem is not obvious to me. You are using the quoted filename all way long, so there shouldn't be any issue with it ...

I see you did not adopt my echo redirection recommendation. Maybe you like that one more:

>> %varSaveFile% echo.
>> %varSaveFile% echo    Don't echo this at home!
>> %varSaveFile% echo.

It puts the file redirection into direct attention, and looks better (more schematic).

Regarding the "agree" part:
It has a flaw, because ANY answer but Y or y will result in "DoesNotAgree". It should only allow for a clear Y or N, IMHO. You could do that with this code:

REM ...
        :agreeLoop
        set /p agree= Do you agree to this? (Y) Yes  (N) No  
        echo.
        IF "%agree%" == "Y" GOTO AGREED
        IF "%agree%" == "N" GOTO DOESNOTAGREE
        GOTO agreeLoop
:DOESNOTAGREE:
        @echo off
REM ...

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:

I was thinking of something more along these lines:


::========================================
:: Computer-RX Installations
::
:: Automated Script
::========================================
:main
   @echo off
   set spaces=[                            ]
   set spc16=%spaces:~1,16%
   set spc26=%spaces:~1,26%

   ::------------------------------
   :: GET DRIVE LETTER
   ::------------------------------
   set varDriveLetter=
   call :get_driveletter
   if not %errorlevel%==0 (
      call :display_titlescreen
      echo.
      echo %spc16%Cannot locate application
      echo.
      set /p .=%spc16%<nul
      pause
      cls
      exit /b 1
   )

   ::------------------------------
   :: GET INSTALLER
   ::------------------------------
   set varErrorCode=0
   :loop1
      call :display_titlescreen
      set varInstaller=
      call :get_installer %varErrorCode%
      call :validate_installer "%varInstaller%"
      set varErrorCode=%errorlevel%
   if %varErrorCode% gtr 0 goto loop1

   ::------------------------------
   :: Substitue space with underline
   ::------------------------------
   set varInstaller=%varInstaller: =_%

   ::------------------------------
   :: GET GL CODE
   ::------------------------------
   set varErrorCode=0
   :loop2
      call :display_titlescreen
      set varGL=
      call :get_glcode %varErrorCode%
      call :validate_glcode %varGL%
      set varErrorCode=%errorlevel%
   if %varErrorCode% gtr 0 goto loop2
   
   call :initialise_variables

   ::------------------------------
   :: GET AGREEMENT
   ::------------------------------
   :loop3
      call :display_titlescreen
      call :display_agreement
     
      echo.
      set varAgree=
      set /p varAgree=%spc26%Do you agree to this [Y/N]:
     
      if not defined varAgree goto loop3
   
      if /i "%varAgree%"=="y" (
         goto agreed
      ) else (
         if /i "%varAgree%"=="n" (
            goto disagreed
         ) else (
            goto loop3
         )
      )
   
   :: Some more code may go here
   :: Some more code may go here
   
   ::------------------------------
   :: END PROGRAM
   ::------------------------------
   call display_titlescreen
   echo %spc16%Thank you.
   echo.
   pause
   cls
exit /b



::========================================
:: DISPLAY TITLE SCREEN
::========================================
:display_titlescreen
   cls
   echo.
   echo      _____________________________________________________________________
   echo.
   echo                          Automated Script written for
   echo                 Computer-RX Installations by Marcus Horner 2009
   echo                          Server 2008 Image Preparation
   echo      _____________________________________________________________________
   echo.
   echo.
      echo.
      echo.
   echo.
   echo.
exit /b 0



::========================================
:: GET DRIVE LETTER
::========================================
:get_driveletter
      set varPrograms=Installation_Files\Computer-Rx\Phase1\Programs
   set varDriveLetter=
   for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
      if exist "%%a:\%varPrograms%\" set varDriveLetter=%%a:
   )
   if not defined varDriveLetter exit /b 0
exit /b 0



::========================================
:: GET INSTALLER
::========================================
:get_installer
   if %1==0 (
      echo.
   ) else (
      if %1==1 (
         echo %spc16%ERROR: You must enter your name...
      ) else (
         if %1==2 (
            echo %spc16%ERROR: Name contains Invalid characters...
         ) else (
            if %1==3 (
               echo %spc16%ERROR: Invalid name...
            )
         )
      )
   )
   
   echo.
   echo.
   echo.
   set /p varInstaller=%spc16%Please enter your name:
exit /b 0



::========================================
:: GET GL CODE
::========================================
:get_glcode
   if %1==0 (
      echo.
   ) else (
      if %1==4 (
         echo %spc16%ERROR: You must enter a GL code...
      ) else (
         if %1==5 (
            echo %spc16%ERROR: Invalid GL code...
         ) else (
            if %1==6 (
               echo %spc16%ERROR: Not enough digits...
            ) else (
               if %1==7 (
                  echo %spc16%ERROR: Too many digits...
               )
            )
         )
      )
   )

   echo.
   echo.
   echo.
   echo %spc16%Please enter your name: %varInstaller%
   echo.
   echo.
   set /p varGL=%spc16%Please enter your store's 4-digit GL code:
exit /b 0



::========================================
:: DISPLAY AGREEMENT
::========================================
:display_agreement
      echo      Welcome %varInstaller%. I hope you are having a nice day.
      echo.
      echo.
      echo      This program is an installation and functions as the installer's
      echo.
      echo      digital checklist for verifying they have installed and configured
      echo.
      echo      the various tasks presented in the Server 2008 Image Preparation.
      echo.
      echo.
      echo      By agreeing to these terms you are signing off that you will have
      echo.
      echo      completed and verified the accuracy of all steps in this installation.
      echo.
   echo.
exit /b 0



::========================================
:: AGREED
::========================================
:agreed
   call :display_titlescreen
   echo %spc16%Unfinished section...
   echo.
   echo %spc16%[%varInstaller%]
   echo.
   echo %spc16%[%varGL%]
   echo.
   echo %spc16%[%varAgree%]
   echo.
   set /p .=%spc16%<nul
   pause
exit /b
   

   
::========================================
:: DISAGREED
::========================================
:disagreed
   rem set varNOTsigned="c:\Installation_Files\Logs\%dude%_Phase1_Installer_Agreement_NOT_Signed.txt"
   rem set varNOTsignedTemp="c:\Installation_Files\Logs\%dude%_Phase1_Installer_Agreement_NOT_Signed.tmp"

   set varNOTsigned="%temp%\%dude%_Phase1_Installer_Agreement_NOT_Signed.txt"
   set varNOTsignedTemp="%temp%\%dude%_Phase1_Installer_Agreement_NOT_Signed.tmp"
   
   call :display_titlescreen
   echo      Well %varInstaller% that is unfortuntate. Please explain why you refuse to
   echo      accept the installer's user agreement.
   echo.
   echo.
   echo      I will open a file for your to report your reasons.
   echo.
   echo.
   echo.     When finished simply save and close the file.
   echo.
   set /p .=     <nul
   pause
   
   (:redirect
      echo My reason for not accepting the installers user agreement is:
      echo.
      echo.
      echo.
   )>%varNOTsignedTemp%
   
   notepad %varNOTsignedTemp%
   
   (:redirect
      echo USA Drug IT Department Digital Installation Form for Store: %varGL%
      echo.
      echo Local Date: %date%
      echo Local Time: %time%
      echo.
      echo Installer:  %varInstaller%
      echo Computer:   %computername%
      echo.
     
      echo %varInstaller% has chosen not to sign their digital signature for %computername% Phase 2 Server 2008 C-Rx Installation for the following reasons:
      echo.
      echo.
      echo  Reasons...
      echo.
   )>%varNOTsigned%
   
   copy %varNOTsigned% + %varNOTsignedTemp% %varNOTsignedTemp% >nul
   move %varNOTsignedTemp% %varNOTsigned%
   
      (::redirect
      echo.
      echo.
      echo  Signed:
   )>>%varNOTsigned%

   pushd %cd%
   cd "%varDriveLetter%\Installation_Files\MailMan\"
      sendemail.exe -u "Phase 2 Installer Agreement Issue" -t "mhorner@usadrug.com" -f "%varInstaller% <installer@usadrug.com>" -o message-file="%varNOTsigned%" -s "email.usadrug.local" -a "%varNOTsigned%"
   popd
   set /p .=     <nul
   pause

      call :display_titlescreen
   echo %spc16%This program will now close.
   echo.
   set /p .=%spc16%<nul
   pause
   cls
exit /b



::========================================
:: VALIDATE INSTALLER
::========================================
:validate_installer
   setlocal enabledelayedexpansion

   set varErrorCode=0
   set varInstaller=%~1
   
   ::------------------------------
   :: If blank, exit with code 1
   ::------------------------------
   if not defined varInstaller exit /b 1

   ::------------------------------
   :: Save name to file & Get length of name -1
   ::------------------------------
   echo %varInstaller%>len
   for %%a in (len) do set /a len=%%~za - 3

   ::------------------------------
   :: Check name is alpha and space
   ::------------------------------
   for /l %%l in (0,1,%len%) do (
      set character=!varInstaller:~%%a,1!
     
      if /i not "!character!" equ " " (
         if /i "!character!" lss "a" set varErrorCode=2  
         if /i "!character!" gtr "z" if /i "!character!" lss "A" set varErrorCode=2
         if /i "!character!" gtr "Z" set varErrorCode=2
      )
   )

   if %varErrorCode%==2 exit /b 2

   ::------------------------------
   :: Search for valid employee name - DISABLED
   ::------------------------------
   :: findstr "\<%varInstaller%\>" installers.txt >nul
   :: if not %errorlevel%==0 exit /b 3
exit /b 0

   
   
::========================================
:: VALIDATE GL CODE
::========================================
:validate_glcode
   set varErrorCode=0
   set varGL=%~1
   
   if not defined varGL exit /b 4

   ::------------------------------
   :: Check length is 4
   ::------------------------------
   echo %varGL%>len
   for %%a in (len) do set /a len=%%~za-2
   if %len% lss 4 exit /b 6
   if %len% gtr 4 exit /b 7
   
   ::------------------------------
   :: Search for GL code - DISABLED
   ::------------------------------   findstr "\<%varGL%\>" glcodes.txt >nul
   :: if not %errorlevel%==0 exit /b 5
exit /b 0