Batch file - Please look

On Error Resume Next
 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" _
    & strComputer & "\root\cimv2")
 
Set colItems = objWMIService.ExecQuery("Select * from Win32_Printer")
 
WScript.Echo "Device_ID" & "," _
    & "Port_Name" & "," _
    & "Is_Default"
 
For Each objItem In colItems
    WScript.Echo objItem.DeviceID & "," _
        & objItem.PortName & "," _
        & objItem.Default
 
    'WScript.Echo
Next

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:

::===================================================
:: Automated Printer Driver Change
::
:: This batch file was written by NetCMH
::
:: Version 1.0 for Windows XP
::
:: Script to:
:: 1. Enumerate the printers on the computer
:: 2. List the default printer
:: 3. Delete and re-add printers with UPD 5.0 driver
:: 4. Re-establish the default printer
::===================================================
@echo off
setLocal EnableDelayedExpansion
 
set DEBUG=echo.*DEBUG*_
set DEBUG=%DEBUG:_= %
set DEBUG=
 
call :get_windows_version
goto :ver_%WinVer%
 
:ver_2003
:ver_xp
  echo Windows XP
  call :create_temp
  call :list_printers
  call :list_default_printer
  call :rename_old_files
  call :change_drivers
  call :cleanup
  exit /b
 
:ver_2000
  echo Windows 2000: Not supported in this version
  exit /b
 
:ver_nt
  echo Windows NT: Not supported in this version
  exit /b
 
:ver_none
  echo Windows version not determined
  exit /b
 
:get_windows_version
  set WinVer=none
  ver | find "2003" > nul
  if %ERRORLEVEL% == 0 (
    set WinVer=2003
    exit /b
  )
  ver | find "XP" > nul
  if %ERRORLEVEL% == 0 (
    set WinVer=xp
    exit /b
  )
  ver | find "2000" > nul
  if %ERRORLEVEL% == 0 (
    set WinVer=2000
    exit /b
  )
  ver | find "NT" > nul
  if %ERRORLEVEL% == 0 (
    set WinVer=nt
    exit /b
  )
  exit /b
 
:create_temp
  if not exist "c:\temp\" mkdir "c:\temp"
  exit /b
 
:list_printers
  echo Listing printers and ports to text files: c:\temp\prns.txt, c:\temp\prts.txt
  cscript //nologo %SYSTEMROOT%\SYSTEM32\prnmngr.vbs -l | findstr /c:"Printer name" | findstr /v "Microsoft">>c:\temp\prns.txt
  cscript //nologo %SYSTEMROOT%\SYSTEM32\prnmngr.vbs -l | findstr /c:"Port name" | findstr /v "Microsoft">>c:\temp\prts.txt
  exit /b
 
:list_default_printer
  echo Listing default printer to text file : c:\temp\defprn.txt
  cscript //nologo %SYSTEMROOT%\SYSTEM32\prnmngr.vbs -g>>c:\temp\defprn.txt
  exit /b
 
:rename_old_files
  %DEBUG%ren C:\WINDOWS\system32\spool\drivers\w32x86\3\HPBMINI.dll C:\WINDOWS\system32\spool\drivers\w32x86\3\OLD_HPBMINI.dll
  %DEBUG%ren C:\WINDOWS\system32\spool\drivers\w32x86\3\HPCDMC32.dll C:\WINDOWS\system32\spool\drivers\w32x86\3\OLD_HPCDMC32.dll
  exit /b
 
:change_drivers
  echo Changing Drivers:
  cd %SystemRoot%\system32
  echo Deleting exisiting UPD 5.0 driver if exists
  %DEBUG%Cscript Prndrvr.vbs -d -m "HP Universal Printing PCL 5 (v5.0)" -v 3 -e "Windows NT x86"
  echo Installing fresh UPD 5.0 driver from server
  %DEBUG%rundll32 printui.dll,PrintUIEntry /ia /m "HP Universal Printing PCL 5 (v5.0)" /f "\\server01\upd5pcl5\hpcu091b.inf" /u
 
  set /a i=0
  for /F "tokens=* delims=" %%A in ('type c:\temp\prns.txt') do (
    set /a i+=1
    set myVar1=%%A
    set myvar1=!myvar1:Printer name =!
    set /a j=0
    for /F "tokens=* delims=" %%B in ('type c:\temp\prts.txt') do (
      set /a j+=1
      if !i!==!j! (
        set myVar2=%%B
        set myvar2=!myvar2:Port name =!
        echo Deleting printers
        %DEBUG%Cscript Prnmngr.vbs -d -p "!myvar1!"
        echo Adding printers
        %DEBUG%cscript prnmngr.vbs -ac -p "!myvar1!" -m "HP Universal Printing PCL 5 (v5.0)" -r "!myvar2!"
      )
    )
  )
 
  echo Re-instating the default printer
  for /F "tokens=* delims=" %%C in ('type c:\temp\defprn.txt') do (
    set myvar3=%%C
    set myvar3=!myvar3:The default printer is =!
  )
  %DEBUG%Cscript Prnmngr.vbs -t -p "%myvar3%"
  exit /b
 
:cleanup
  echo Cleaning up
  %DEBUG%if exist c:\temp\prns.txt del c:\temp\prns.txt
  %DEBUG%if exist c:\temp\prts.txt del c:\temp\prts.txt
  %DEBUG%if exist c:\temp\defprn.txt del c:\temp\defprn.txt
  exit /b
 
 
===== OUTPUT LOG FILE =====
Windows XP
Listing printers and ports to text files: c:\temp\prns.txt, c:\temp\prts.txt
Listing default printer to text file : c:\temp\defprn.txt
*DEBUG* ren C:\WINDOWS\system32\spool\drivers\w32x86\3\HPBMINI.dll C:\WINDOWS\system32\spool\drivers\w32x86\3\OLD_HPBMINI.dll
*DEBUG* ren C:\WINDOWS\system32\spool\drivers\w32x86\3\HPCDMC32.dll C:\WINDOWS\system32\spool\drivers\w32x86\3\OLD_HPCDMC32.dll
Changing Drivers:
Deleting exisiting UPD 5.0 driver if exists
*DEBUG* Cscript Prndrvr.vbs -d -m "HP Universal Printing PCL 5 (v5.0)" -v 3 -e "Windows NT x86"
Installing fresh UPD 5.0 driver from server
*DEBUG* rundll32 printui.dll,PrintUIEntry /ia /m "HP Universal Printing PCL 5 (v5.0)" /f "\\server01\upd5pcl5\hpcu091b.inf" /u
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "Text"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "Text" -m "HP Universal Printing PCL 5 (v5.0)" -r "FILE:"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "Send To OneNote 2007"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "Send To OneNote 2007" -m "HP Universal Printing PCL 5 (v5.0)" -r "XPSPort:"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "MFP"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "MFP" -m "HP Universal Printing PCL 5 (v5.0)" -r "IP_192.168.59.132"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "Duplex"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "Duplex" -m "HP Universal Printing PCL 5 (v5.0)" -r "IP_192.168.59.86"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "Color"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "Color" -m "HP Universal Printing PCL 5 (v5.0)" -r "IP_192.168.59.85"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "Adobe PDF"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "Adobe PDF" -m "HP Universal Printing PCL 5 (v5.0)" -r "My Documents\*.pdf"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "\\pvdres02\PVDRCH03LZ02"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "\\pvdres02\PVDRCH03LZ02" -m "HP Universal Printing PCL 5 (v5.0)" -r "IP_192.168.59.132"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "\\pvdres02\RCH03-LZR-01"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "\\pvdres02\RCH03-LZR-01" -m "HP Universal Printing PCL 5 (v5.0)" -r "IP_192.168.59.86"
Deleting printers
*DEBUG* Cscript Prnmngr.vbs -d -p "\\pvdres02\RCH03-LZR-02"
Adding printers
*DEBUG* cscript prnmngr.vbs -ac -p "\\pvdres02\RCH03-LZR-02" -m "HP Universal Printing PCL 5 (v5.0)" -r "IP_192.168.59.85"
Re-instating the default printer
*DEBUG* Cscript Prnmngr.vbs -t -p "MFP"
Cleaning up

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102:
103:
104:
105:
106:
107:
108:
109:
110:
111:
112:
113:
114:
115:
116:
117:
118:
119:
120:
121:
122:
123:
124:
125:
126:
127:
128:
129:
130:
131:
132:
133:
134:
135:
136:
137:
138:
139:
140:
141:
142:
143:
144:
145:
146:
147:
148:
149:
150:
151:
152:
153:
154:
155:
156:
157:
158:
159:
160:
161:
162:
163:
164:
165:
166:
167:
168:
169:
170:
171:
172:
173:
174:
175:
176:
177:
178:
179:
180:
181:
182:
183: