Exctracting output from a system varible into a text file or database using pstool

That worked, excelent. I actualy had it typed right before except I can't get the variable for the number of processors. I am also trying to to retrieve information when I run it with the /d (which is drive space). This one is pretty confusing, I am trying different token varibles. Here is what I have so far after some editing.

@echo off

for /F "tokens=2* delims=:. " %%a in ('psinfo ^| find /I "Processor speed"') do set proc=%%b
for /F "tokens=2* delims=:. " %%c in ('psinfo ^| find /I "Physical memory"') do set mem=%%d
for /F "tokens=1* delims=:. " %%e in ('psinfo /d ^| find /I "c:"') do set dspace=%%f
echo %DATE%, %COMPUTERNAME%, %proc%, %mem%, %dpace%>> "C:\sp.txt"

still tinkering with the delim values.

Use this:

@echo off
setlocal
for /f "tokens=2*" %%a in ('psinfo ^| find /I "Processor speed"') do set proc=%%b
for /f "tokens=2*" %%a in ('psinfo ^| find /I "Physical memory"') do set mem=%%b
for /f "tokens=5-8" %%a in ('psinfo /d ^| find /I "C:"') do (
  set dspace=%%a %%b
  set fspace=%%c %%d
)
echo %DATE%, %COMPUTERNAME%, %proc%, %mem%, %dspace% ^(%fspace% free^)

In this output, you actually don't even need to redefine the delims value. You can use the same for variable in all three commands as well, they're local to the for command. For more information about the different uses of the "for" command, enter "help for" in a command window.

oBdA
Thank you very much for your fast and accurate response. I wish I knew this scripting as good as you do. I'm thinking of what class @ my community college would give me a good start? Any suggestions? Here is my final script that I have and am thought I would ask one last thing. If you so choose to do it, then great. If it's to much don't worry about it ....Please do it :) LOL

@echo off
setlocal
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Processor speed"') do set proc=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Physical memory"') do set mem=%%b
for /f "tokens=4-8" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo /d ^| find /I "C:"') do (
  set dspace=C: %%a %%b
  set fspace=%%c %%d available, %%e
)
echo %DATE%, %COMPUTERNAME%, %proc%, %mem%, %dspace%, %fspace% free>> "\\vo-phx-fs02\security$\serinf.txt

I entered the C: because the I need the output to identify the drive that it is referring to. Here is what the output looks like:
Tue 04/06/2004, PHX-ADM-007530, 1.0 GHz, 512 MB, C: 55.9 GB, 36.7 GB available, 66% free

The question is are servers have more then one fixed drive. So we were wondering is there a way to pull all the fixed drive information from that machine using the same output format.

give us the full output of
   psinfo /d
and i'm sure we can work something out.
if not so short on time i'd download it and check it, i know it's free.

Something like this:
Tue 04/06/2004, PHX-ADM-007530, 1.0 GHz, 512 MB
      C: 55.9 GB, 36.7 GB available, 66% free
      D: 55.9 GB, 36.7 GB available, 66% free
      E: 55.9 GB, 36.7 GB available, 66% free


MIGHT come from something like this:  (you would have to make sure the string searched does not match wrong lines, does match drives info lines and fields pulled included the drive letter)
@echo off
setlocal
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Processor speed"') do set proc=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Physical memory"') do set mem=%%b
echo %DATE%, %COMPUTERNAME%, %proc%, %mem%>> "\\vo-phx-fs02\security$\serinf.txt
for /f "tokens=4-8,3" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo /d ^| find /I "Physical drive"') do (
  echo.    %%f %%a %%b, %%c %%d available, %%e free>> "\\vo-phx-fs02\security$\serinf.txt
)


Good Luck,
2K
(\o/)

Just noted that there can be of course drives without label, which messes up the number of tokens and makes the (IMHO) ugly direct string manipulation necessary.
For more information about the "call: process" construction (sort of a subroutine in a batch script), enter "help call".

@echo off
setlocal
set dspace=
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Processor speed"') do set proc=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Physical memory"') do set mem=%%b
for /f "delims=" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo /d ^| find /I ": Fixed"') do call :process %%a
set dspace=%dspace:~2%
echo %DATE%, %COMPUTERNAME%, %proc%, %mem%, %dspace%
goto :leave

:process
set line=%*
set letter=%line:~0,2%
set line=%line:~47%
for /f "tokens=1-5" %%a in ("%line%") do set dspace=%dspace%, %letter% [%%a %%b, %%c %%d avail, %%e%% free]
goto :eof

:leave

For some good batch examples, check out for example http://www.robvanderwoude.com/

oBdA, I copied your script and added the >> command and ran it on my exchange server. All the volumes have labels. This is what I got back:
Wed 04/07/2004, VO-PHX-EX01, 1.7 GHz, 3776 MB, C: [16.9 GB, 7.1 GB avail, 42% free], D: [9.8 GB, 9.4 GB avail, 96% free], E: [332.0 GB, 312.2 GB avail, 94% free]

It's beatiful! Should I expect a problem if the volume doesn't have a label? If so I can just make sure that the volumes do have labels.

My Final Script::::::
@echo off
setlocal
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "kernel version"') do set kern=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "service pack"') do set sp=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "processors"') do set np=%%a
set dspace=
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "service pack"') do set sp=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "processors"') do set np=%%a
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Processor speed"') do set proc=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "Physical memory"') do set mem=%%b
for /f "delims=" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo /d ^| find /I ": Fixed"') do call :process %%a
set dspace=%dspace:~2%
echo %DATE%, %COMPUTERNAME%, %kern%, %sp%, %np%, %proc%, %mem%, %dspace%>> "\\vo-phx-fs02\security$\systemspec.txt"
goto :leave

:process
set line=%*
set letter=%line:~0,2%
set line=%line:~47%
for /f "tokens=1-5" %%a in ("%line%") do set dspace=%dspace%, %letter% [%%a %%b, %%c %%d avail, %%e%% free]
goto :eof

:leave


I use Hyena with a command that runs psexec which will run this batch file on remote machines. All I have to do is select the machines I want in Hyena and run it. It works AWSOME!!! (note: NT4 doesn't come out with date echo or the drive letter but who cares) I did go through and label all of my server volumes. You guys are the greatest.

I moved these two lines back up above the set dspace.
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "service pack"') do set sp=%%b
for /f "tokens=2*" %%a in ('\\vo-phx-fs05\Scripts\HyenaTools\Pstools\psinfo ^| find /I "processors"') do set np=%%a


ps, how do I edit a post, I can't find it on here.

Trammel

I have had this batch file running in the GPO policies for over a week now. It seems that every few days my log file is being over written. The data started out with data from April 6, then a few days later I only have data back from the 8 and today it only has data back from the 12th. I am thinking that some systems may not see the log.txt and there for just writes a new fiile. Which in turn over writes the file. I have set the advanced ntfs permissions so that the delete is unchecked. But that was when I had data on the 8th. Anyone have any ideas what or why my data is being over written?

Trammel

I can't say that I have an idea. Anything special about the very first entry in the "new" log (the line itself, the machine OS, something else that's different from the rest)?

I looked at the first entry on the file and the first line has been three different machines (with the last three files that have emerged). The data is the same as the rest as far as out put goes. Is there a way to put a wait command before the append. Im trying to figure out how I can debug this somehow. The log looks great with the information that it gathers (thanks again).

In this case, this shouldn't make a difference, but you can try to replace the "echo" line with this:
>>"\\vo-phx-fs02\security$\systemspec.txt" echo %DATE%, %COMPUTERNAME%, %kern%, %sp%, %np%, %proc%, %mem%, %dspace%

There are several possibilities for pausing:
If you have the Resource Kit, put sleep.exe in a share and call it with the number of seconds to wait:
\\SomeServer\SomeShare\sleep.exe <SecondsToWait>

Or you can misuse ping:
ping -n 1 -w <SecondsToWait*1000> <Unreachable IP>
(for this to work, the IP address you ping has to be unreachable!)

If you want to wait for a key, you can use
pause

If you'd like to try it without any third party utilities, and with code that will run CONSISTENTLY across ALL NT-based operating systems from NT4SP6A+ through Server 2003, you might be interested in the following one-line command:

(((%.GetLogDate%)&(%.GetLogTime%))%.Silent%) & (FOR /F %A IN ('%.eNetView%') DO @ (FOR %B IN (%#UPPER:~4%) DO @(%.Kity%  ( (PUSHD \\%A\%B$) && (%.GetFreeM% %.Silent% & CALL ECHO ^%#LogDate^%,^%#LogTime^%,%A,%B,^%#FreeM^% & POPD) ) ) ) )

The above command provides a date and time coded Free Space Report for all local drives on all machines that display in the output of "Net View".  It is assumed that you have access to the administrative shares (C$, D$, etc.).

The command interpreter processes this as one line of code, so it's usually quite fast.  In extremely large networks, the code is easily modified to use a temporary file for storing the machine names.  To use it in a script, change the following items:
%A                        becomes          %%A
%B                        becomes          %%B
^%#LogDate^%     becomes         ^%%#LogDate^%%
^%#LogTime^%    becomes         ^%%#LogTime^%%
^%#FreeM^%       becomes         ^%%#FreeM^%%

*******

The output of this command is a comma separated list that looks like this:

20040416,052826,SERVER1,C,1067
20040416,052826,SERVER1,D,3754
20040416,052826,WORKSTATION1,C,801
20040416,052826,WORKSTATION1,D,1234
20040416,052826,WORKSTATION1,L,5468
20040416,052826,WORKSTATION1,R,0
.
.
.
etc.


The format is YYYYMMDD,HHMNSS,Computername,Drive,FreeSpaceInMillionsOfBytes

*******

How does this work?

.GetLogDate and .GetLogTime retrieve YYYYMMDD and HHMNSS and save these values in variables named #LogDate and #LogTime.  The .Silent command suppresses the display of YYYYMMDD and HHMNSS to the console.

The outer loop (FOR /F %A) sends the output of the command .eNetView (a formatted list of all systems displayed by the "Net View" command) to the inner loop (FOR /F %B).  The inner loop processes a space-delimited list of drive letters from C through Z and tries to execute a PUSHD command to the administrative share associated with that drive letter on each system (\\ComputerName\C$, \\ComputerName\D$, etc.)

The .Kity command (KITY stands for Keep-It-To-Yourself) suppresses any errors from PUSHD when it does not find, or cannot access, any of the administrative shares.

If PUSHD is successful, commands after the "&&" are executed for the machine represented by %A and the drive letter represented by %B.

The command .GetFreeM retrieves the free space, in whole millions of bytes, that is available on the subject drive and saves this value in variable #FreeM.  Again, we use %.Silent% to suppress the console display of the free space value.

The CALL ECHO command displays the final output while dynamically expanding the contents of #LogDate, #LogTime and #FreeM.

Finally POPD returns us to the original directory (only if PUSHD was successful).

*******

The resources used above are present on EVERY installation of Windows NT-based systems without adding any additional software to the base OS.  Reference pages follow.

#Constants

    #UPPER (http://TheSystemGuard.com/NTCmdLib/Constants)

.Mount/\Commands

    .Silent (http://TheSystemGuard.com/MtCmds/RedirRapids)
    .Kity (http://TheSystemGuard.com/MtCmds/RedirRapids)

   .GetFreeM (http://TheSystemGuard.com/MtCmds/GetValue/GetFreeM.htm)
   .GetLogDate (http://TheSystemGuard.com/MtCmds/GetValue/GetLogDate.htm)
   .GetLogTime (http://TheSystemGuard.com/MtCmds/GetValue/GetLogTime.htm)

   .eNetView (http://TheSystemGuard.com/MtCmds/NetValue)

Common Command Set - Internal

   CALL (http://TheSystemGuard.com/TheGuardBook/CCS-Int/CALL.htm)
   ECHO (http://TheSystemGuard.com/TheGuardBook/CCS-Int/ECHO.htm)
   FOR (http://TheSystemGuard.com/TheGuardBook/CCS-Int/FOR.htm)
   POPD (http://TheSystemGuard.com/TheGuardBook/CCS-Int/POPD.htm)
   PUSHD (http://TheSystemGuard.com/TheGuardBook/CCS-Int/PUSHD.htm)
   SET (http://TheSystemGuard.com/TheGuardBook/CCS-Int/SET.htm)

!GuardNote about calculating various values using SET /A commands

   (http://TheSystemGuard.com/TheGuardBook/CCS-Int/SET.htm#MaxValuesForSet/A)

*******

Much of the info mentioned in previous comments is also available without third party tools.  For example the :System_Info procedure returns the current ServicePack, installed HotFixes and the IE Version, if installed.  A list of installed applications (same as the list in Control Panel, Add/Remove Programs) is also made available.

   :System_Info (http://TheSystemGuard.com/NTCmdLib/Procedures/SI.htm)

Finally, ".Wait" is a non-CPU intensive timed pause command.

   .Wait (http://TheSystemGuard.com/MtCmds/CrystalClear/Wait.htm)

*******

The main advantage of putting this in a one-liner is that you can now create your own Mount/\Command called, for example, ".ReportFreeSpace".  All you have to do is store the code in an environment variable under a name that makes sense to you.

In your actual script, you use one self-documenting command:

   %.ReportFreeSpace%

and the entire report is generated.

Further explanation and a color-coded example can be provided upon request.  For a list of all the commands and resources available, see (http://TheSystemGuard.com/default.asp#MasterCommandList).

After trying a few of these on my XP box with no luck, I checked some of the documentation from thesystemguard.

These are all available ONLY if you have installed the third-party Command Library that attaches itself internally and partially externally to the MS command interpreter.

This is available at  http://thesystemguard.com/NTCmdLib.asp and function very similar to www.systeminternals.com utilities.  The mount commands from thesystemguard helps you mount your commands as listed above by placing a "hook" into cmd.exe through which variable substitution is redirected.  Most stuff from system internals is less intrusive to the MS Operating Systems and hence does not try to "hide" OS differenes as deeply as mount commands.  Mount commands are available "as low as $2 per computer"

The notices pasted on most  thesystemguard.com pages are carefully worded to state "no OTHER third party" software need be added for various versions of NT past the earliest supported service pack.  It does NOT state ( unless on pages I did not see ) that itself is not a third party add-on.  Indeed it is one even if it does state otherwise somewhere, so i doubt that they make that claim.  
Being a third party add-on is not a bad thing, if you can talk your local IT security team into evaluating it, and if it fills your needs.


(\o/)  Hope This Helps,
2K

A color coded example of the code posted in my previous comment can be viewed as Example 2 on the GetFreeM Page at (http://TheSystemGuard.com/MtCmds/GetValue/GetFreeM.htm).

*******

Some clarifications:

Command Libraries are implemented as shell scripts.  There is no binary code, only scripting commands.  There is no installation necessary as all resources are contained within a single file (NTCmdLib.cmd).  There are no hooks or attachements into cmd.exe, and NOTHING WHATSOEVER is modified on the host system.  The library does not even have to be on the local disk but can be called from, for example, the same directory as the system login script.

To use the library, you "Initialize" it by typing "NTCmdLib /Init".  The initialization process involves checking various system parameters (using only the builtin scripting commands COMMON to all four platforms - NT, 2K, XP and K3) and then preloading about 50K of highly compressed and optimized scripting code into the local environment.  The actual code that gets placed in the environment is extremely session-specific for THIS COMPUTER at THIS TIME.  This code is available for immediate use, using a "sounds like what it does" syntax, without having to access the hard disk.  These "Mounted Commands" behave and perform like other "internal commands" such as FOR, IF, and SET.

The Initialization process smooths out the the various OS-specific and configuration-specific "bumps".  You can use the same script for all of your machines and write code like:

   %.ifServer% (
      [skip workstation updates]
   ) ELSE (
     [install workstation updates]
   )

*******

The reason they are presented as NOT "third-party" is because a typical usage is on a system where it is OK for someone to write their own shell script, but it is not OK to install (or even run) a third party executable.  This leads to many frustrated SysAdmins asking questions like "How do I write a script to do <insert-problem-description-here> using only the builtin commands?!"  Once the problem is solved and briefly tested, the code is put in production, and we're on to put out the next fire.  Until something goes wrong and we have to go back and look at the code again....

Unless you work with batch files often ( and even if you do), it's easy to forget what the code you wrote last month does.  Especially if you cut and pasted it from somewhere on the Internet.  How many times have you spent many fuming hours trying to get a percent sign to stand on it's head at just the right angle?!

So, when a script contains

   %.Silent% COPY Source Destination

instead of

   COPY Source Destination >NUL 2>&1

it is much easier to maintain, even for the part-time System Admin who is responsible for the office network but their real job (the one that demands the majority of their attention) is something else (like Office Manager, Accountant, Engineer, etc.).

*******

For a step by step example of how a MountCommand is constructed, read the sample issues of our KnowledgeLetter at (http://BoomingOrFuming.com).

And finally, there *IS* a FREE Advanced Command Library (ntlib.cmd) available at (http://ntlib.com).  It includes all the commands in the previous example except .GetFreeM and .eNetView.  There are other commands included in the Advanced Library such as ".GetFree" and ".NetView", that could be used to create a similar, but not identical, solution.

*******

To Mr. 2K:

Thanks for taking the time to look at the site.  Why don't you give the Command Library a trial run and see for yourself the benefits I've described?!