asked on

How can I delete all the "Account Unknown" profiles using a batch file?

Greetings -

Is anyone aware of a way to delete all the "Account Unknown" user profiles listed on a workstation via a batch file?

Perhaps I'm drawing a blank but I can't seem to think of a way to do it from the command line. Please do not point out the "delprof.exe" utility from Microsoft as it is not designed to do this and won't recognize anything listed as "Account Unknown".

The domain is not using roaming profiles. These "Account Unknown" profiles are remnants of some old local accounts that used to exist that were not deleted completely. I basically want to delete anything that is an "Account Unknown" profile.

Thanks!

haim96

https://www.experts-exchange.com/questions/21645626/Batch-file-to-delete-Account-Unknown-profiles.html

did you see this?

amendala

ASKER

Yes, I did. But unfortunately, it doesn't apply to what I'm after. That thread relates to removing user profile directories that are beyond a certain age.

I am not concerned about age or any other factors other than that if it is listed as "Account Unknown", I want it deleted.

Shift-3

Here's my attempt. Please test this thoroughly before using it on a production system.

Once you are certain it is doing what you want, remove the echo commands from lines 28 and 29. It will not actually delete anything until you do so.

@echo off
setlocal
 
set reglist=HKLM\software\microsoft\windows nt\currentversion\profilelist
 
for /F "tokens=* usebackq" %%G in (`reg query "%reglist%"`) do (
 for /F "tokens=* usebackq skip=4" %%H in (`reg query "%%G" /v ProfileImagePath 2^>NUL`) do call :_process1 "%%G" "%%H"
)
goto :_end
 
:_process1
for /F "tokens=1,2 delims=." %%J in ("%~n2") do call :_process2 "%~1" "%%J" "%%K"
goto :eof
 
:_process2
set active=
if "%~3"=="" (set prof=%~2) else (set prof=%~2.%~3)
dir >NUL
net user %2 > NUL 2>&1
if "%errorlevel%"=="0" set active=true
dir >NUL
net user %2 /domain > NUL 2>&1
if "%errorlevel%"=="0" set active=true
if /I "%~2"=="systemprofile" set active=true
if /I "%~2"=="LocalService" set active=true
if /I "%~2"=="NetworkService" set active=true
if not defined active (
 echo reg delete %1
 echo rd /q /s "%allusersprofile%\..\%prof%"
)
goto :eof
 
:_end
endlocal

Open in new window

Shift-3

Some corrections and comments added.

@echo off
setlocal
 
REM Registry location of the profile list shown in System properties.
set reglist=HKLM\software\microsoft\windows nt\currentversion\profilelist
 
REM Queries the profile list for each profile's path
for /F "tokens=* usebackq" %%G in (`reg query "%reglist%"`) do (
 for /F "tokens=* usebackq skip=4" %%H in (`reg query "%%G" /v ProfileImagePath 2^>NUL`) do call :_process1 "%%G" "%%H"
)
goto :_end
 
:_process1
REM Subroutine to strip out the user name from the profile path.
for /F "tokens=1,2 delims=." %%J in ("%~n2") do call :_process2 "%~1" "%%J" "%%K"
goto :eof
 
:_process2
set active=
REM Corrects for user.domain profile paths
if "%~3"=="" (set prof=%~2) else (set prof=%~2.%~3)
REM Runs the net user command to determine if the username is valid locally
dir >NUL
net user %2 > NUL 2>&1
if errorlevel 0 set active=true
REM Runs the net user command to determine if the username is valid on the domain
dir >NUL
net user %2 /domain > NUL 2>&1
if errorlevel 0 set active=true
REM Checks for the built-in profiles
if /I "%~2"=="systemprofile" set active=true
if /I "%~2"=="LocalService" set active=true
if /I "%~2"=="NetworkService" set active=true
REM If none of the above conditions are met, deletes the profile's registry entry and folder.
if not defined active (
 reg delete %1 /f
 rd /q /s "%allusersprofile%\..\%prof%"
)
goto :eof
 
:_end
endlocal

Open in new window

ASKER CERTIFIED SOLUTION

Shift-3

membership

This solution is only available to members.

To access this solution, you must be a member of Experts Exchange.

Start Free Trial

How can I delete all the &quot;Account Unknown&quot; profiles using a batch file?

How can I delete all the "Account Unknown" profiles using a batch file?