3ds max breaking up an object by element

(--start execute loop
 
--***********************************************************************************************************   FUNCTION DEFINITIONS START	
	local DetachPolyElements_fn, DetachSplineElements_fn, DetachMeshElements_fn
	
	FN DetachPolyElements_fn SourceOBJ =
	(--start function for detaching elements from an editable poly object
		MasterObj = SourceOBJ 
		faceCount = MasterObj.getnumfaces()
		
		FaceTest = ((MasterObj.getnumfaces()) != 0)
		
		for ii in 1 to faceCount while FaceTest do	--ends loop when there are no faces left to select
		(--start element detach loop
			newName = (uniquename (MasterObj.name as string))
			
			MasterObj.EditablePoly.SetSelection #Face #{1}
			MasterObj.selectElement()
			TargetElement = polyop.getFaceSelection MasterObj
			polyop.detachFaces MasterObj TargetElement asNode:true name:newName
			
			NewObj = getnodebyname newName
			resetXForm NewObj 
			convertTo NewObj (Editable_Poly)
			ResetTransform NewObj 
			ResetScale NewObj 
			ResetPivot NewObj 
			centerpivot NewObj
			FaceTest = ((MasterObj.getnumfaces()) != 0)
		)--end element detach loop
		delete MasterObj	
	)--end function for detaching elements from an editable poly object
	
	FN DetachSplineElements_fn SourceOBJ =
	(--start function for detaching from editable splines
		MasterSpline = SourceOBJ 
		ns = numsplines MasterSpline 	
	
		for i in 1 to ns do    -- for each element in the spline it re-orders the elements
		(
			tempMaster = copy MasterSpline 
			tempMaster.name = (MasterSpline.name + "_Element_" + (i as string))
			select tempMaster 
			setFirstSpline tempMaster i
			
			for ii = ns to 2 by -1 do    -- deletes all of the elements except the first one
			(
				deleteSpline tempMaster ii
			)
			select MasterSpline
		)
		delete MasterSpline	
	)--end function for detaching from editable splines
	
	FN DetachMeshElements_fn SourceOBJ =
	(--start function for detaching elements from an editable Mesh object
		MasterObj = SourceOBJ
		convertTo MasterObj (Editable_Poly) 
		faceCount = MasterObj.getnumfaces()
		
		FaceTest = ((MasterObj.getnumfaces()) != 0)
		
		for ii in 1 to faceCount while FaceTest do	--ends loop when there are no faces left to select
		(--start element detach loop
			newName = (uniquename (MasterObj.name as string))
			
			MasterObj.EditablePoly.SetSelection #Face #{1}
			MasterObj.selectElement()
			TargetElement = polyop.getFaceSelection MasterObj
			polyop.detachFaces MasterObj TargetElement asNode:true name:newName
			
			NewObj = getnodebyname newName
			resetXForm NewObj 
			convertTo NewObj (Editable_Mesh)
			ResetTransform NewObj 
			ResetScale NewObj 
			ResetPivot NewObj 
			centerpivot NewObj
			FaceTest = ((MasterObj.getnumfaces()) != 0)
		)--end element detach loop
		delete MasterObj	
	)--end function for detaching elements from an editable Mesh object
--***********************************************************************************************************   FUNCTION DEFINITIONS END	
	
	max create mode
	ObjsSource = getCurrentSelection()	--create array of all selected objects
	if ObjsSource[1] == undefined then messagebox "Nothing is selected!"    -- checks to see something is selected
			
	else for obj in 1 to ObjsSource.count do with redraw off
	(--start Object loop
		SourceOBJ = ObjsSource[obj]
		if (classof SourceOBJ  == editable_poly) then (DetachPolyElements_fn SourceOBJ)			-- operates only on those objects that are editable polys
		else if (classOf SourceOBJ == SplineShape or classOf SourceOBJ == line) then (DetachSplineElements_fn SourceOBJ)    -- operates only on those objects that are splines
		else if (classOf SourceOBJ == Editable_Mesh) then (DetachMeshElements_fn SourceOBJ)		-- operates only on those objects that are editable meshes
	)--end Object loop
	max views redraw
)--end execute loop
                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97: