I need a checksum calculation written in C converted to VB

Hi, thanks for the response. I wondered if there was another way of approaching the problem? I just found the following VB code on the site. This code calculates the CRC-8 checksum which looks pretty close to what I need. Unfortunately I don't understand the original C code enough to be able to figure out what changes I need to make. I know this VB code isn't giving me the right answer but it might be along the right lines?

'---------------------------------------------------------------------------------------
' Procedure : XGetCRC8
' Purpose   : Calculate the CRC8 code for the entire string
'---------------------------------------------------------------------------------------
'
Private Function XGetCRC8(CRC8 As String) As Integer
Dim l_Len As Integer
Dim l_Char As String
Dim l_CRC8 As Integer

    l_CRC8 = 0
    For l_Len = 1 To Len(CRC8)
        l_Char = Mid(CRC8, l_Len, 1)
        l_CRC8 = XCalculateCRC8(l_CRC8, l_Char)
    Next
   
    XGetCRC8 = l_CRC8
End Function

'---------------------------------------------------------------------------------------
' Procedure : XCalculateCRC8
' Purpose   : Calculate the cumulative CRC8 code for the given character
'---------------------------------------------------------------------------------------
'
Private Function XCalculateCRC8(CRC8 As Integer, Character As String) As Byte
Dim l_BitPopped As Boolean
Dim l_Bit As Byte
Dim l_Char As Integer

    l_Char = Asc(Character)
    For l_Bit = 0 To 7
        l_BitPopped = (CRC8 And &H80)
        CRC8 = CRC8 * 2
        If l_Char And &H80 Then
            CRC8 = CRC8 Or &H1
        Else
            CRC8 = CRC8 And &HFE
        End If
         
        If l_BitPopped Then
            CRC8 = CRC8 Xor &H85
        End If
        l_Char = l_Char * 2
    Next

    XCalculateCRC8 = CRC8 And &HFF
End Function

Thanks for the suggestion. I have tried this, but I don't seem to be able to get the solution. I think the two function s are doing slightly different things. For example, the VB code is using &H80 and &H1 and &HFE and &H85 as Hex constants whereas the C code seems to be using just &H8C and &H01.
I feel like I'm just hacking away! Clearly I'm out of my depth here - this is what happens when you give am SQL developer a 'proper programmers' job!!

That sounds like a great idea, I'll look into this asap.
Thanks Andy

Paul

This is great. I think I can make some progress based on this ...

Mike

A colleague came up with this, which works perfectly:
Public Function checksum8(HexString As String) As String

        Dim buff(255) As Byte
        Dim CRC As Byte
        Dim x As Integer
        Dim y As Integer

        CRC = 255
       
        For x = 1 To Len(HexString) Step 2
       
            buff(x) = hex2dec(Mid$(HexString, x, 2))
           
            CRC = CRC Xor buff(x)
            For y = 1 To 8
                If CRC And 1 Then
                    CRC = CRC - 1
                    CRC = CRC / 2       '     Shift Right 1 bit
                    CRC = CRC Xor 140   '     0x8C
                Else
                    CRC = CRC / 2       '     Shift Right 1 bit
                End If
            Next y
        Next x
       
        checksum8 = CRC

End Function

Thanks to everyone who helped.

Thanks for the points.

I don't think you need:

                    CRC = CRC - 1

as it is odd at this point and you are just about to divide by 2 anyway.

Paul

Hi Paul

Intersting point. I have tested it extensively and it works so I am reluctant to change it.
But I will bear your comment in mind should there be any further problems.
Thanks for the ongoing interest

Mike

Hi Mike,

If yours works reliably then this should too:

Public Function checksum8(HexString As String) As String

        Dim buff As Byte
        Dim CRC As Byte
        Dim x As Integer
        Dim y As Integer

        CRC = 255
       
        For x = 1 To Len(HexString) Step 2
       
            buff = hex2dec(Mid$(HexString, x, 2))
           
            CRC = CRC Xor buff
            For y = 1 To 8
                If CRC And 1 Then
                    CRC = CRC / 2       '     Shift Right 1 bit
                    CRC = CRC Xor 140   '     0x8C
                Else
                    CRC = CRC / 2       '     Shift Right 1 bit
                End If
            Next y
        Next x
       
        checksum8 = CRC

End Function

Note that you also don't need buff as an array as you only process it one byte at a time. Sorry to bang on but I just don't feel comfortable with code that is just 'space'.

Paul

Now, that is an improvement. Can't argue with that. I will incorporate your version - interestingly I was concerned about the array, I didn't get it so I'm glad you've explained that it was redundant.
Mind you, if I have any problems you're now my Level 1 support! Hah!

Paul
Thought you'd want to know. Buff doesn't need to be an array - as you rightly pointed out.
But removing the CRC = CRC -1 stopped it from working!
Re-instating this line restored functionality.
Interesting?!
Mike

>>But removing the CRC = CRC -1 stopped it from working!
Extraordinary!! I wonder why.

If CRC is odd then subtracting one and then dividing by two should have exactly the same effect as just dividing by 2 with integer types.

Perhaps VB recognises the bit loss and turns it into a float. Yukk!!! Glad I don't work in VB.

Paul
.

Cracked it!!

See Wikipedia on VB:

http://en.wikipedia.org/wiki/Visual_basic#Language_features

quote: ... Integers are automatically promoted to reals in expressions involving the normal division operator (/) so that division of an odd integer by an even integer produces the intuitively correct result. There is a specific integer divide operator (\) which does truncate.

So this should work using the '\' integer divide operator:

Public Function checksum8(HexString As String) As String

        Dim buff As Byte
        Dim CRC As Byte
        Dim x As Integer
        Dim y As Integer

        CRC = 255
       
        For x = 1 To Len(HexString) Step 2
       
            buff = hex2dec(Mid$(HexString, x, 2))
           
            CRC = CRC Xor buff
            For y = 1 To 8
                If CRC And 1 Then
                    CRC = CRC \ 2       '     Shift Right 1 bit
                    CRC = CRC Xor 140   '     0x8C
                Else
                    CRC = CRC \ 2       '     Shift Right 1 bit
                End If
            Next y
        Next x
       
        checksum8 = CRC

End Function



Paul

I see you have the bit between your teeth.
Well, I'm off home (it's 10 PM here) but I promise to try this version when I'm back in the office on Thursday. You'll be the first to know! Thanks for your continuing interest.
M