what register does readstring goto?

;--------------------------------------------------------
ReadString PROC LOCAL bufSize:DWORD, saveFlags:DWORD, junk:DWORD
;
; Reads a string from the console and places the characters in a buffer.
;
; Receives: EDX offset of the input buffer
;           ECX = maximum characters to input (including terminal null)
; Returns:  EAX = size of the input string.
; Comments: Stops when Enter key (0Dh,0Ah) is pressed. If the user types more characters than (ECX-1), the excess characters are ignored.
;
;; Written by Kip Irvine and Gerald Cahill
;
; Last update: 11/19/92, 03/20/2003
;--------------------------------------------------------
.data
_$$temp DWORD ?		         ; added 03/20/03
.code
	pushad
	CheckInit
 
	mov edi,edx		; set EDI to buffer offset
	mov bufSize,ecx		; save buffer size
 
	push edx
	INVOKE ReadConsole,
	  consoleInHandle,		; console input handle
	  edx,		         ; buffer offset
	  ecx,		         ; max count
	  OFFSET bytesRead,
	  0
	pop edx
	cmp bytesRead,0
	jz  L5 		         ; skip move if zero chars input
 
	dec bytesRead	         ; make first adjustment to bytesRead
	cld		         ; search forward
	mov ecx,bufSize		; repetition count for SCASB
	mov al,0Ah		; scan for 0Ah (Line Feed) terminal character
	repne scasb
	jne L1		         ; if not found, jump to L1
 
	;if we reach this line, length of input string <= (bufsize - 2)
 
	dec bytesRead		; second adjustment to bytesRead
	sub edi,2		         ; 0Ah found: back up two positions
	cmp edi,edx 		; don't back up to before the user's buffer
	jae L2
	mov edi,edx 		; 0Ah must be the only byte in the buffer
	jmp L2		         ; and jump to L2
 
L1:	mov edi,edx		; point to last byte in buffer
	add edi,bufSize
	dec edi
	mov BYTE PTR [edi],0    	; insert null byte
 
	; Save the current console mode
	INVOKE GetConsoleMode,consoleInHandle,ADDR saveFlags
 
	; Switch to single character mode
	INVOKE SetConsoleMode,consoleInHandle,0
 
	; Clear excess characters from the buffer, 1 byte at a time
L6:	INVOKE ReadConsole,consoleInHandle,ADDR junk,1,ADDR _$$temp,0
 
	mov al,BYTE PTR junk
	cmp al,0Ah 		; the terminal line feed character
	jne L6     		; keep looking, it must be there somewhere
 
	INVOKE SetConsoleMode,consoleInHandle,saveFlags ; restore console mode.
	jmp L5
 
L2:	mov BYTE PTR [edi],0	; insert null byte
 
L5:	popad
	mov eax,bytesRead
	ret
ReadString ENDP
                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77: