How do I create a batch file to read values in a .XML file?

But that's not really an IP Address, is it?

By the way, the easiest way to troubleshoot a FOR command like that is just to use a "tokens=x" value that exceeds the number of expected tokens, and echo back that many, like this:

@echo off
 
for /f "tokens=1-6 delims=><" %%a in ('type settings.xml ^| find "<_LANLocation>"') do (
    echo a: %%a
    echo b: %%b
    echo c: %%c
    echo d: %%d
    echo e: %%e
    echo f: %%f
)
 
echo.
pause
exit

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:

Works like a charm now!  Thanks for the quick help!  For my knowledge, what do the tokens mean in that statement?

The output for that command is:

a:
b: _LANLocation
c: NF-LAPTOP\emunworks
d: /_LANLocation
e:
f:

So, you know it's %%c and can use that many tokens.

No, I'm basically needing to store a SQL server name and database nameso that I can send in some SQL statements through a batch file instead of having to install a management tool.  This will be an easier way to give updates to our clients.

By the way, what are tokens in this statement?

Thanks!

Thank you nafaught.

OK, this is how I think of the FOR command.  Sorry if you already know some of the basics.

Whatever is in the ( ) part of the command is looked at or executed first.  I suppose it's easiest to regard this as the "source" data.  The ( ) can contain:
A file name, eg. "settings.xml",
A literal text string if double-quoted,
A command if single-quoted, the results of the command then being your source,
A number of other types of source not applicable to your example or needs.

So, in your case the bit in the ( ) is just a command to find only one line in the source file.  The FOR command will walk through as many lines as there are in the source data processing each in turn, so it's a loop.  Your's has only one line, but just remember that the FOR command is a looping thing.

In my troubleshooting example I added a block of echo commands by placing an opening ( after the DO part of the command, and then used a closing ) after the last echo command.  That is still part of the loop.  The FOR command will only exit that loop after the last line of the source data is parsed.

So, for each line in the source data, the process will look for your specified delimeters.  Consider these like field separators.  When it gets to the first delimeter, it grabs the chunk of data up to that as Token1.  The chunk grabbed up to the next delimeter found is Token2, etc.

My example used "tokens=1-4", so it's going to break the line into 4 chunks separated by each instance of a < or > and that includes the leading white space before the first <
Because you used a starting variable of %%a then that chunk of white space is Token1 and will be stored in variable %%a.  The 2nd Token will be the part after the first < delimeter and the next delimeter which is > and this will be stored in %%b, etc, etc.

Not sure if this is going to line up:

          <_LANLocation>NF-LAPTOP\emunworks</_LANLocation>
|   1    |          2           |                  3                 |           4           |
  %%a        %%b                      %%c                          %%d    

If your filtered line contained more than just 4 delimeted chunks, then by specifying "tokens=1-4" you would be telling it not to grab any more chunks of data after Token4 or %%d

There are different ways to do this, so Shift3's suggestion is actually correct also, as demonstrated below.

If instead you just used     "tokens=3 delims=><"    then you are just telling it to START at the 3rd token defined by your delimeters.  In that case because your starting variable is %%a then THAT would be storing the 3rd token or 3rd chunk of data.

Use the modified troubleshooting batch file below to demonstrate this:

@echo off
 
for /f "tokens=3 delims=><" %%a in ('type settings.xml ^| find "<_LANLocation>"') do (
    echo a: %%a
    echo b: %%b
    echo c: %%c
)
 
echo.
pause
exit

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:

Output of the above command using the same XML data source:

a: NF-LAPTOP\emunworks
b: %b
c: %c

Remember these rules:

Whatever you specify as delimeters will NOT be included in the data stored in the variables.  You are grabbing the data BETWEEN the delimeters.

You can use an uppercase or lowercase letter as your starting variable as long as you match the case of the variables on the other side of the (source) part of the command.  So if you start with %%A then %%a is not the same.

The starting variable does not have to be %%a
It can be any letter of the alphabet, but remember to leave enough spare to hold as many tokens as you are specifying.  Some people use a different starting letter depending on the type of data they are parsing, but it's a whole lot easier "counting" up from %%a than from something like %%i

Regards
Bill