Command Line Utility To Check For Open Ports (SOLVED)

@echo off
::
::  chkOpenPort.cmd
::  only batch
::       gastone canali
setlocal
if +%1+==++ goto :_err nohost
if +%2+==++ goto :_err
set host=%1
set port=%2
set result=Port:%port% on %host% closed!
start /min telnet.exe %host% %port%
for /f "tokens=5 delims= " %%p in ('netstat -ao^|find /i "ESTABLISHED"^| find /i "%host%:%port%"') do (
   rem echo Port:%port% on %host% OPEN!
   set result=Port:%port% on %host% OPEN!
   ping -n 2 localhost >nul 2>&1
   tskill %%p >nul 2>&1
)
echo %result%
goto :_END
:_err
echo error: Not enought parameters
echo syntax: chkOpenPort.cmd hostname port

:_END

I did not know that netstat can check for open ports on remote servers are you sure about that ?
I did use portqry which was designed for that purpose

Netstat don't check open ports! The idea behind the script is open a telnet connection to the remote host remotePort (is the fast way to test if a TCP port is open ) if connection is succesful give you an "ESTABLISHED" line (the port is open) and then I kill the telnet process.

My solution is for check open ports only with standard OS installation without the need of other tool...  is another way, is not the way and is not a portqry substitute...

I would not want to give the users telnet access in any kind of way to my servers..that would be to much of a security risk..telnet is only open on the localhost for testing purposes.

I speak about telnet.exe (client) ...
You don't need Telnet server!!!!

I got you...but still it cant check for upd and tcp ports...what if I wana check for UDP 53 or TCP 53..

And it gave the following result on www.google.com

C:\Documents and Settings\ali.jawad\Desktop>poing.bat www.google.com 80
Port:80 on www.google.com closed!
The system cannot find the batch label specified - _END

@echo off
::
::  chkOpenPort.cmd
::  only batch
::       gastone canali
:: v.0.1
setlocal
if +%1+==++ goto :_err nohost
if +%2+==++ goto :_err
set host=%1
set port=%2
for /f "tokens=2* delims=[" %%h in ('ping -n 1 %host%^|find /i "["') do for /f "tokens=1 delims=]" %%H in ('echo %%h') do set hostIP=%%H
if +%hostIP%+==++ goto :_IPNOTFOUND
set result=Port:%port% on %host% closed!
start /min telnet.exe %hostIP% %port%
ping -n 2 localhost >nul 2>&1
for /f "tokens=5 delims= " %%p in ('netstat -ano^|find /i "ESTABLISHED"^| find /i "%hostIP%:%port%"') do (
   rem echo Port:%port% on %host% OPEN!
   set result=Port:%port% on %host% OPEN!
   tskill %%p >nul 2>&1
)
echo %result%
goto :_END
:_err
echo error: Not enought parameters
echo syntax: chkOpenPort.cmd hostname port
goto :_END
:_IPNOTFOUND
echo %host%: host unknown
:_END