How can I create a folder in a directory that is 5 levels deep without specifying the path?

Isn't there a way to use wildcards? like if exist c:\*\*\*\*\test_folder mkdir c:\*\*\*\*\test_folder  ?

No you can't.  we can do a for loop to lok in the dirs if you can specify them etc.

Can you give an example of the dirs involved pls.

I just tried that and it doesn't work, I think in dos scripting anyways you'll need to do alot of IF statements to check all the possible locations, there should be a way to set this to do it recursively, but I haven't given it enough thought to actually write the code - I am sure it can be done to search a hard drive and if the directory doesn't exist then to create it ...

There are literally thousands of directories. If it were only a few, I'd be able to write the script.

I'd list out the directorys in excel to get the path, but there are too many to list.

ok. what I mean is examples... I.e. how do we know where to create them... e.g. is it a dir under ALL 5 level deep dirs under a certain path etc?

ok. what I mean is examples... I.e. how do we know where to create them... e.g. is it a dir under ALL 5 level deep dirs under a certain path etc?

It would look something like this. we'll use c:\ as the root

c:\1\a\b\c\d\e\test_folder
c:\2\f\g\h\i\j\test_folder
c:\3\t\u\v\w\x\test_folder
etc

So what i'm trying to do is  traverse 5 levels beneath each directory in the root of c:\ and check if test_folder exists. If it doesn't, create it.

of course c:\ isn't the root directory i'm wotking with. Each folder in the actual root directory will always have a minimum of 5 levels.

Hope this explains things a bit better.

ok sorry if im being thick here but do you mean that

1. start at directory path C:\x say and then in the subdirs a b c d there are multiple dirs and in each of those multiple dirs.. a dir /s /b /ad might be useful if poss of part of the area

thanks

Steve

You example looks like it's 6 folders deep.

Try the script below.
It will currently only pretend to create the folders, that is, instead of creating the folders, it will print out the "md" commands it would normally run, so that you can test and adjust the settings, if necessary. Once you've tested it, simply remove the capitalized ECHO.
The level count is *absolute* from the root of the drive, so in your "wildcard" example above, it would actually be 5, but for "c:\1\a\b\c\d\e\test_folder", it would have to be 7 to create test_folder in the desired level (seems like you miscalculated there; count as I might, if C:\ is the root, then test_folder is not 5 levels deep). Anyway, you can simply adjust it at the beginning of the script.

@echo off
setlocal
set Root=C:\
set Create=Test_Folder
set Level=5
REM ----- No changes below this line -----
set /a Level1 = Level + 1
for /d /r "%Root%" %%a in (*.*) do (
  call :process "%%a"
)
goto :eof
:process
set Folder=%~1
for /f "tokens=%Level%,%Level1% delims=\" %%a in ("%Folder%") do (
  if not "%%a"=="" (
    if "%%b"=="" (
      if not exist "%Folder%\%Create%" ECHO md "%Folder%\%Create%"
    )
  )
)
                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:

5 levels deep. Remove the echo to have it actually do the create folder.

For your example:

ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
Set StartFolder=C:
Set CreateFolder=Test_Folder

for /f "tokens=1-7 delims=\" %%a in ('dir /ad /s /b') do (
    if "%%g" NEQ "" if not exist "%%a\%%b\%%c\%%d\%%e\%%f\%%g\%CreateFolder%" echo MD "%%a\%%b\%%c\%%d\%%e\%%f\%%g\%CreateFolder%"
)

ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
Set StartFolder=C:
Set CreateFolder=Test_Folder
 
for /f "tokens=1-6 delims=\" %%a in ('dir /ad /s /b') do (
    if "%%f" NEQ "" if not exist "%%a\%%b\%%c\%%d\%%e\%%f\%CreateFolder%" echo MD "%%a\%%b\%%c\%%d\%%e\%%f\%CreateFolder%"
)

                                              

1:
2:
3:
4:
5:
6:
7:
8:

>> AmazingTech:

Didn't you mean to reference %StartFolder% in the 'dir' ?

And maybe it would be good to add a trailing \ to it?

Other than that nicely played!  ;-)

~bp

Yes. Sorry.

ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
Set StartFolder=C:
Set CreateFolder=Test_Folder
 
for /f "tokens=1-6 delims=\" %%a in ('dir "%StartFolder%\*.*" /ad /s /b') do (
    if "%%f" NEQ "" if not exist "%%a\%%b\%%c\%%d\%%e\%%f\%CreateFolder%" echo MD "%%a\%%b\%%c\%%d\%%e\%%f\%CreateFolder%"
)
                                              

1:
2:
3:
4:
5:
6:
7:
8: