Deleting an unknown number of folders in c:\temp

@jkratzer
That was too easy mate... way too easy. I think he wants you to cycle through each of the computer names in computers.txt and then do what you suggested inside the loop... (perhaps use a for loop). Have another go mate.

This batch file will do it for you. Note that you need to have Full Admin rights on the computers listed in the text file and the firewall should be off on those machines.

This script will create a batch file called "DelAll.bat" which you have to run yourself. The reason for that is I didn't want to you run it without checking the 2nd batch file to make sure it is deleting what you want it to delete.

@echo off
setlocal EnableDelayedExpansion
echo @echo off >delall.bat
 
for /F "delims=," %%T IN (computers.txt) do (
 set cname=%%T
 
 for /f "tokens=*" %%i in ('dir /b /ad \\!cname!\c$\temp\ses*') do (echo rd /s /q \\!cname!\c$\temp\%%i >>delall.bat)
)
                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:

for a visual solution, please try the following:


@echo off
for /f %%a in (computers.txt) do (
   set /p .=%%a<nul
   for /f "tokens=*" %%b in ('dir /ad /b "\\%%a\c$\temp\ses*"') do (
      set /p .=.<nul
      rmdir /s /q "\\%%a\c$\temp\%%b"
   )
   echo.
)

The exclamation mark is used for a feature called Delayed Expansion (switched on with setlocal EnableDelayedExpansion). It allows for variables to be changed in the same code block or line, and is replaced when executing.
A block is built by the parenthesis (). If you use

setlocal EnableDelayedExpansion
set x=0
for %%A in (1 2 3 4) do (
 set x=%%A
 echo %x%
 echo !x!
)
You will see the difference. The first echo will output 0 in each loop, while the second echo counts up.

Why? Because the whole part in () is parsed as a single line, and %x% is replaced when parsed, not executed. !x! is replaced when executed.

The ! works very much like the % for referencing variables.  The difference being that the % referenced variables are resolved one time when the statement containing them is read by the batch processor.  On the other hand, the ! referenced variables are resolved everytime that line of code is executed.

This all assumes that "setlocal EnableDelayedExpansion" has been specified, to enable this feature.

The way I think about it is the ! references are a bit more real time, so if a variable is set in any kind of a loop, the best way to reference is typically with the ! format.  This assures that the value you get is the updated value.

A little more info on this can be found in by doing "HELP SET" at the command line.

You may also find this link useful to better understand.

http://batcheero.blogspot.com/2007/06/how-to-enabledelayedexpansion.html

~bp