Robocopy exit codes

If it helps, here is the error checking part of one of my standard robocopy scripts which has been running for a few years at one site:

echo Copying Opera backup files from %source% to %dest%
echo %DATE% %TIME% - Started copy of backup files from %SERVER% >> %LOGFILE%

ROBOCOPY "%source%" "%dest%" %filespec% %options%

REM Errorlevel 1 = Sucessful copy, 2 is extra filed needed deleting, 3 = both
REM so Errorlevel 4 is another error
if errorlevel 4 goto error
if errorlevel 3 goto OKCopyAndDel
if errorlevel 2 goto OKDelete
if errorlevel 1 goto OKCopy
if errorlevel 0 goto OKNothing

:OKCopyAndDel
  net send %ErrorPC% "%DATE% %TIME% Backup copy to DC02 OK - Copied & Deleted"
  echo %DATE% %TIME% - Backup Operation Successful from %SERVER% >> %LOGFILE%

goto end

:OKDelete
  net send %ErrorPC% "%DATE% %TIME% Backup copy to DC02 OK - Deleted Only"
  echo %DATE% %TIME% - Backup Operation Successful from %SERVER% >> %LOGFILE%

goto end

:OKCopy
  net send %ErrorPC% "%DATE% %TIME% Backup copy to DC02 OK - Copied only"
  echo %DATE% %TIME% - Backup Operation Successful from %SERVER% >> %LOGFILE%

goto end

:OKNothing
  net send %ErrorPC% "%DATE% %TIME% Backup copy to DC02 OK - Nothing to do"
  echo %DATE% %TIME% - Backup Operation Successful from %SERVER% >> %LOGFILE%

goto end
:error
  echo %DATE% %TIME% - Backup Operation Failed with copy of backup files from %SERVER% >> %LOGFILE%
  net send %ErrorPC% "%DATE% %TIME% Backup database copy to DC02 has reported an error"
  net send %Erroruser% "%DATE% %TIME% Backup database copy to DC02 has reported an error"
goto end

:end

echo. >> %LOGFILE%
echo ----------------------------------------------------------- >> %LOGFILE%

robocopy's return codes are a bitmap.
They are described in detail in the file "robocopy.doc" in the installation folder, Page 33:
Hex Bit Value      Decimal Value      Meaning If Set
0x10      16      Serious error. Robocopy did not copy any files. This is either a usage error or an error due to insufficient access privileges on the source or destination directories.
0x08      8      Some files or directories could not be copied (copy errors occurred and the retry limit was exceeded). Check these errors further.
0x04      4      Some Mismatched files or directories were detected. Examine the output log. Housekeeping is probably necessary.
0x02      2      Some Extra files or directories were detected. Examine the output log. Some housekeeping may be needed.
0x01      1      One or more files were copied successfully (that is, new files have arrived).
0x00      0      No errors occurred, and no copying was done. The source and destination directory trees are completely synchronized.