picture

hello anthonyc,

I have done what you advised but I am stuck on<Set the largechange of the scroll bar = to the width (or height) of the scroll bar.  In the scrollbars change event, reposition the controls>.

say i have 20 bitmaps, i made the controll array to display them in picture2, but i can not scroll thime up/down with the Vscrool1. because i have not done that before i am confused how to tackle it. If yo give me example code for the last part that will help.

many thanks

ok:

do this:
private const mc_nPicsPerRow as integer = 4 'set to what you want

vScroll1.Min = 0
vScroll1.Max = picture2.height

private sub vScroll1_Change()
  dim pic as picturebox

  for each pic in picture1
     pic.Top = ((pic.index \ mc_nPicsPerRow) * pic.height) - vScroll1.Value
  next pic
end sub

If you have 20 pictures that is 21 pictureboxes on one form
That consumes a lot of memory and slows down you app.  Try two pictureboxs picture1 and picture2  Set the following:

picture1.visible=false
picture2.AutoRedraw=True

load your pictures one by one into picture1 and use its paintpicture method to paint them into the appropriate positions on picture2

PaintPicture will allow you to take any region of picture1 and paint it to any region of picture2 and you can even resize the region as it is painted.  Thus no matter if you have one picture or a thousand pictures you only use 2 pictureboxs.  This is much faster and consumes much less memory.  When the scroolbar is used picture2 can be cleared and then repainted with the appropriate pictures.

To save the need to access the disk everytime the scroll bar is used add a third picturebox picture3.  Paint all the thumbnails into picture3 instead of picture2. And then paint the appropriate regions of picture3.image to picture2.  Make sure picture3.AutoRedraw=true and picture3.visible=false.

moterk, Hi.. can u give a samll example code, i was confused to follow this. but i agree when i display 150 picture i have to wait 2 minutes to display them..

thanks

The following form definition contains contains all you need to pull off a thumbnail viewer.  A folder path is sent to it via the command line then it creates a collection of all BMP, JPG, and GIF files'filenames.  Then from that collection, it loads each picture into picture1, paints a thumbnail of it to picture3, and stores that thumbnail into another collection.  Then the thumbnail collection paints thumbnails 25 at a time to picture2.  You flip through pages
of thumbnails in picture2 using the scroll bar.  You may not notice much if any improvement in loading time.  That is not where the time savings is.  But when you switch pages you do not have to show, hide, and/or move 25 picture boxes.  Which takes quite a bit of time.  This just paints thumbnails from the collection.  Page transitions seem
instantanious.  Since you are using 3 pictureboxes and two collections no matter how many pictures you have, you are saving a lot or memory resources. I can load 8 pages (200 thumbnails) in about 1 minute on my machine.  This is a little different then what I discribed earlier but it uses the same ideas.


VERSION 5.00
Begin VB.Form Form1
   BorderStyle     =   1  'Fixed Single
   Caption         =   "ThumbNail Viewer"
   ClientHeight    =   3465
   ClientLeft      =   1050
   ClientTop       =   1470
   ClientWidth     =   9315
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   3465
   ScaleWidth      =   9315
   Begin VB.PictureBox Picture3
      Appearance      =   0  'Flat
      AutoRedraw      =   -1  'True
      BorderStyle     =   0  'None
      ForeColor       =   &H80000008&
      Height          =   990
      Left            =   2475
      ScaleHeight     =   990
      ScaleWidth      =   1035
      TabIndex        =   3
      Top             =   1005
      Width           =   1035
   End
   Begin VB.VScrollBar VScroll1
      Height          =   3375
      Left            =   9030
      Max             =   1
      Min             =   1
      TabIndex        =   2
      Top             =   45
      Value           =   1
      Width           =   270
   End
   Begin VB.PictureBox Picture1
      AutoSize        =   -1  'True
      Height          =   1320
      Left            =   585
      ScaleHeight     =   1260
      ScaleWidth      =   1245
      TabIndex        =   0
      Top             =   645
      Visible         =   0   'False
      Width           =   1305
   End
   Begin VB.PictureBox Picture2
      AutoRedraw      =   -1  'True
      Height          =   3375
      Left            =   30
      ScaleHeight     =   3315
      ScaleWidth      =   8940
      TabIndex        =   1
      Top             =   30
      Width           =   9000
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Private PictureFiles As Collection
Private PictureThumbs As Collection
Private OneThumb As StdPicture
Private CurPicture As String
Const PicsPerRow = 5  'Fit 25 thumbnails in picture2 at a time
Const PicsPerCol = 5

Sub LoadThumbNails(tnPath As String)
    Dim ftype As VbFileAttribute
   
    MaxHeight = Picture2.Height / PicsPerCol
    MaxWidth = Picture2.Width / PicsPerRow
   
    Set PictureFiles = New Collection
   
    ftype = vbArchive + vbHidden + vbNormal + vbReadOnly
    PicFile$ = Dir(tnPath & "*.bmp", ftype)
    Do Until PicFile$ = ""
        PictureFiles.Add tnPath & PicFile$
        PicFile$ = Dir
    Loop
    PicFile$ = Dir(tnPath & "*.gif", ftype)
    Do Until PicFile$ = ""
        PictureFiles.Add tnPath & PicFile$
        PicFile$ = Dir
    Loop
    PicFile$ = Dir(tnPath & "*.jpg", ftype)
    Do Until PicFile$ = ""
        PictureFiles.Add tnPath & PicFile$
        PicFile$ = Dir
    Loop
   
    Set PictureThumbs = New Collection
   
    PicsPerPage = PicsPerRow * PicsPerCol
    TotalPages% = Int(PictureFiles.Count / PicsPerPage)
    If (PictureFiles.Count Mod PicsPerPage) > 0 Then TotalPages% = TotalPages% + 1
    VScroll1.Max = TotalPages%
    If TotalPages% = 1 Then VScroll1.Enabled = False
    For i% = 1 To PictureFiles.Count
        Picture1.Picture = LoadPicture(PictureFiles.Item(i%)) 'Picture1.AutoSize=True
        SourceWidth = Picture1.Width
        SourceHeight = Picture1.Height
        wratio = MaxWidth / SourceWidth
        hratio = MaxHeight / SourceHeight
        tempratio = wratio: If hratio < tempratio Then tempratio = hratio
        DestWidth = SourceWidth * tempratio
        DestHeight = SourceHeight * tempratio
        Picture3.Width = DestWidth
        Picture3.Height = DestHeight
        SourceX = 0
        SorceY = 0
        DestX = 0
        DestY = 0
        Picture3.PaintPicture Picture1.Picture, DestX, DestY, DestWidth, DestHeight, SourceX, SourceY, SourceWidth, SourceHeight, vbSrcCopy
        Set OneThumb = Picture3.Image
        PictureThumbs.Add OneThumb
        Set OneThumb = Nothing
        Picture3.Cls
    Next i%
    Picture3.Visible = False
End Sub
Sub PaintPage(pnum As Integer)
    Picture2.Cls
    PicsPerPage% = PicsPerCol * PicsPerRow
    MaxWidth = Picture2.Width / PicsPerRow
    MaxHeight = Picture2.Height / PicsPerCol
    StartPic% = ((pnum - 1) * PicsPerPage%) + 1
    EndPic% = StartPic% + PicsPerPage% - 1
    If StartPic% > PictureThumbs.Count Then Exit Sub 'Page requested does not exist
    If EndPic% > PictureThumbs.Count Then EndPic% = PictureThumbs.Count 'Last Page
    For i% = StartPic% To EndPic%
        ThumbNum% = i% - StartPic%
        PicRow% = Int(ThumbNum% / PicsPerRow)
        PicCol% = ThumbNum% - (PicRow% * PicsPerRow)
        Set OneThumb = PictureThumbs.Item(i%)
        SourceWidth = Picture2.ScaleX(OneThumb.Width)
        SourceHeight = Picture2.ScaleY(OneThumb.Height)
        DestWidth = SourceWidth
        DestHeight = SourceHeight
        SourceX = 0
        SorceY = 0
        DestX = (PicCol% * MaxWidth) + ((MaxWidth - SourceWidth) / 2)
        DestY = (PicRow% * MaxHeight) + ((MaxHeight - SourceHeight) / 2)
        Picture2.PaintPicture OneThumb, DestX, DestY, DestWidth, DestHeight, SourceX, SourceY, SourceWidth, SourceHeight, vbSrcCopy
        Set OneThumb = Nothing
    Next i%
End Sub


Private Sub Form_Load()
    xpath$ = Command$
    If Right(xpath$, 1) <> "\" Then xpath$ = xpath$ + "\"
    LoadThumbNails xpath$
    PaintPage 1
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Set PictureFiles = Nothing
    Set PictureThumbs = Nothing
    Set OneThumb = Nothing
End Sub


Private Sub Picture2_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If CurPicture = "" Then Exit Sub
    'Clicked on Thumbnail for image with filename CurPicture so open in image processor
    ShellLine$ = "C:\WINDOWS\KODAKIMG.EXE " + CurPicture
    xx = Shell(ShellLine$, vbNormalFocus)
End Sub

Private Sub Picture2_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    SpanX% = Int(X * PicsPerRow / Picture2.Width)
    SpanY% = Int(Y * PicsPerCol / Picture2.Height)
    ThumbNum% = (SpanY% * PicsPerRow) + SpanX%
    PictureNum% = ThumbNum% + (((VScroll1.Value - 1) * PicsPerRow * PicsPerCol) + 1)
    If PictureFiles.Count >= PictureNum% Then
        CurPicture = PictureFiles.Item(PictureNum%)
        Picture2.ToolTipText = CurPicture
    Else
        CurPicture = ""
        Picture2.ToolTipText = ""
    End If
End Sub


Private Sub VScroll1_Change()
    PaintPage VScroll1.Value
End Sub