UserControl And Friend functions.

<<(ByRef ctrl As MyControl)>>
But what do I pass for this parameter? I tried MyControl, but I get a "ByRef arguement type mismatch.

I also tried (in the .bas module):
Dim uCtrl As MyControl
But then recalled that I need to set it to something. So I tried to add:
Set uCtrl = MyControl
Didn't work.

If I am understanding correctly, I need an object in the .bas module that references the usercontrol, correct? I'm guessing I'm right, but how do I set up this object?

For the ctrl parameter, if you are calling the function in the .bas module from within the UserControl, which is the most likely case, you woul dpass the Me statement. If you are not familiar with this, look it up in VB help. The Me statement provides you with a reference to the object which is the parent to the function which contains this code. For instance...

-This function, located in the .bas module, will utilize a reference to the UserControl, which will be called MyControl.

Public Function TestInBas(ByRef ctrl As MyControl) As Boolean
    'This function is in the .bas module. It will return true if the object passed is a
    'MyControl object. The "If TypeOf... Is... " statement tests an object (remember that
    'controls are objects too) and determines if it is a specified type of object.
   
    If TypeOf ctrl Is MyControl Then
        TestInBas = True
    Else
        TestInBas = False
    End If
End Function


-And this function is located in the .ctl file, known in the project as MyControl. It is a Friend function which passes a reference to it's parent object to the .bas module function.

Friend Function TestInUserControl() As Boolean
    'This function will call the TestInBas function and pass a reference to
    'itself as the parameter. Notice the Me statement passes a reference to
    'this control to the called function in the .bas module.
   
    TestInUserControl = TestInBas(Me)
End Function

Now, about declaring a new instance of the UserControl in your .bas module, don't. Your .bas module should only be receiving references to the UserControl, not creating new instances of it.

There is also a slightly more elegant way to handle this. If the .bas module will often times need to reference the UserControl, you *can* add properties to .bad modules. Because the bas moduel is considered loaded into memory as soon as the program starts, you can assign a reference to the UserControl right during initialization and then the .bas module would not have to include a paramater for the UserControl reference in every .bas module function.
Here's an example:

-This declaration would belong in the General Declarations sectionof the .bas module.

'Declared variable to store a reference to the UserControl.
Private ctlParent As MyControl


-This pair of property get/set procedures will make it possible to assign a reference to a MyControl object to the .bas module.

Public Property Get ParentControl() As MyControl
   
    'This returns a reference to the currently referenced MyControl object. If no object
    'has been assigned to this property yet, it will return a value of Nothing.
    Set ParentControl = ctlParent
End Property

Public Property Set ParentControl(ByRef Parent As MyControl)
   
    'This assigns a MyControl reference which will be stored in the .bas module. This reference
    'will reflect any and all changes made in the referenced object.
    Set ctlParent = Parent
End Property


-Now, in the UserControl's Initialization event procedure, we can assign a reference to the UserControl.

Private Sub UserControl_Initialize()

    'This assigns a reference to this UserControl. Notice that the .bas module
    'doe snot have to be included to qualify the property Set call.
    Set ParentControl = Me
   
    'This syntax would be considered more bullet-proof.
    Set MyMod.ParentControl = Me
End Sub


-Now, you should always clean up any and all object references you make. When the UserControl terminates, the reference to the UserControl in the .bas module should be released. However, just to be sure, we will perform housekeeping when the UserControl terminates.

Private Sub UserControl_Terminate()
   
    'This sets the reference control to Nothing. This means that it does
    'not reference any valid objects whatsoever.
    Set MyMod.ParentControl = Nothing
End Sub

-Now, with that change in place, here's how a revised version of TestInBas would look.

Public Function TestInBas() As Boolean
    'Notice that this tests the variable stored in the .ba smodule to determine if it is a
    'UserControl of type MyControl. Notice also that no parameter had to be passed.
   
    If TypeOf ctlParent Is MyControl Then
        TestInBas = True
    Else
        TestInBas = False
    End If
End Function

-And with that, we also have a slightly revised version of TestInUserControl:

Friend Function TestInUserControl() As Boolean
    'Notice that no reference had ot be passed ot the TestInBas function.
    'This should return true always since the reference was made as soon
    'as this control loaded.
   
    TestInUserControl = TestInBas
End Function



I hope this helps you out. Ask if you have any questions about any of this.

Great! I've got the functions/subs/etc. part working now. I do notice that I can't use this method to access controls in the usercontrol. I guess that to use controls, I pass them the same way I passed the usercontrol itself? Something like:

Sub UserControl_Init.....

Set basParent = Me
Set OtherControl = Text1
etc.
etc.

End Sub

While you could use property Get/Set procedures in your .bas module to store references to other controls on the UserControl, a better idea would be to expose these controls as Friend properties of the UserControl. If you had a Textbox called txtTest, you could make it available to other modules in the project with a Friend Property Get procedure located in the UserControl:

Friend Property Get MyTextBox() As TextBox
    'This exposes the text box located on the UserControl.
   
    Set MyTextBox = txtTest
End Property


Now, in the .bas module we could have these functions which will access the MyTextBox property of the referenced parent control:

Public Function GetText() As String
    'This function will return the text that is currently in the textbox
    'called txtTest that is placed on UserControl MyControl.
   
    GetText = ctlParent.MyTextBox.Text
End Function

Public Sub WriteText(NewText As String)
    'Notice that we can assign this text string to the tetxbox, even though
    'only a Property Get procedure has been written to expose the textbox.
    'This is because we ar enot tryign to replace the textbox itself, we
    'are only manipulating the properties and methods of the textbox which
    'is referenced by the MyTextBox property.
   
    ctlParent.MyTextBox.Text = NewText
End Sub

Here you can see that the UserControl is capable of providing any objects it needs (be it other classes or controls) as Friend property procedures. This way, you still only have the one object reference to assign in the beginning and destroy in the end. Everything's neat and clean and the code stays where it should. Let me know if you need to know any more on this.

While you could use property Get/Set procedures in your .bas module to store references to other controls on the UserControl, a better idea would be to expose these controls as Friend properties of the UserControl. If you had a Textbox called txtTest, you could make it available to other modules in the project with a Friend Property Get procedure located in the UserControl:

Friend Property Get MyTextBox() As TextBox
    'This exposes the text box located on the UserControl.
   
    Set MyTextBox = txtTest
End Property


Now, in the .bas module we could have these functions which will access the MyTextBox property of the referenced parent control:

Public Function GetText() As String
    'This function will return the text that is currently in the textbox
    'called txtTest that is placed on UserControl MyControl.
   
    GetText = ctlParent.MyTextBox.Text
End Function

Public Sub WriteText(NewText As String)
    'Notice that we can assign this text string to the tetxbox, even though
    'only a Property Get procedure has been written to expose the textbox.
    'This is because we ar enot tryign to replace the textbox itself, we
    'are only manipulating the properties and methods of the textbox which
    'is referenced by the MyTextBox property.
   
    ctlParent.MyTextBox.Text = NewText
End Sub

Here you can see that the UserControl is capable of providing any objects it needs (be it other classes or controls) as Friend property procedures. This way, you still only have the one object reference to assign in the beginning and destroy in the end. Everything's neat and clean and the code stays where it should. Let me know if you need to know any more on this.

That probably covers everything. It'll be tonight before I can test again, though. I'll get back to you then...

(If you're wondering about the odd point value, I went browsing through some old PAQs. That left my point value "untidy" so I upped it a couple to even it back out.)