moving cursor at the beginning of the selection

In response to pkmnfrk, I must keep the current cursor position and I must select all the remaining matching text while the user is typing. It has the effect to complete the text until the combobox shows the item that the user wants. The user is also free to use the dropdown list to choose an item, with the first matching one selected.

Example :

|
L|andry, Bernard
Le|brun, Antoine
Lem|aire, Alphonse
Lemi|eux, Franc
Lemir|e, Claude
Lemire|, Claude
Lemire,| Claude
Lemire, |Claude
Lemire, J|ean

Where | represents the cursor while the user is typing in the combobox.

Ok, A disclaimer first... This is a disgusting method, I don't really like it, but I couldn't find anything else.
What would be really nice is if the SelLength property could be set to a negative value, but alas, it cant.

Personally, I'd leave it as you've got it...

    Combo1.SelStart = CursorPos
    Combo1.SelLength = Len(Combo1.Text)

But if you really want the cursor at the start of the selection, you could do something like this...

    Combo1.SetFocus
    Combo1.SelStart = Len(Combo1.Text)
    For i = 1 To (Len(Combo1.Text) - CursorPos)
        SendKeys "+{LEFT}"
    Next i

Essentially what this does is put the cursor at the end of the text and sends the <Shift>+<Left Arrow> keys enough times to select the remaining text.

Like I said, Disgusting!
Anyway, Good Luck.

Actually, Just noticed something....

Instead of the for loop, do this:

SendKeys "+{LEFT " & (Len(Combo1.Text) - CursorPos) & "}"

So the string you send to the SendKeys function will be something like "+{LEFT 3}" which says send <Shift>+<Left> 3 times.

Still kind of disgusting, but much better than a for loop...

Thanks Bandy. It's a good idea to select the text by function keys. I'll do it by sending key messages directly to the control. I will avoid the use of SetFocus and SendKeys.

I'd be interested in seeing your final solution... what messages you pass, etc...  

I don't like sendkeys either, and I'm always trying to learn more about message passing etc.

Private Declare Function apiGetKeyboardState Lib "user32" Alias "GetKeyboardState" (ByRef pbKeyState As Byte) As Long
Private Declare Function apiSetKeyboardState Lib "user32" Alias "SetKeyboardState" (ByRef lppbKeyState As Byte) As Long

Private Declare Function apiSendMessageLng Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function apiSendMessageStr Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
  Private Const CB_FINDSTRING As Long = &H14C&
  Private Const WM_KEYDOWN As Long = &H100&
    Private Const VK_END As Long = &H23&
    Private Const VK_HOME As Long = &H24&
    Private Const VK_SHIFT As Long = &H10&
    Private Const VK_RIGHT As Long = &H27&

Public Sub SearchCombo(ByRef ComboboxObject As VB.ComboBox)
  Dim lngSelStart As Long
  Dim strSearchText As String
  Dim lngListIndex As Long
  Dim lngHwnd As Long
 
  Dim abytKeys(0 To 255) As Byte
  Dim bytPrevState As Byte
 
  With ComboboxObject
    lngSelStart = .SelStart
    strSearchText = Left$(.Text, lngSelStart)
    lngHwnd = .hwnd
   
    lngListIndex = apiSendMessageStr(lngHwnd, CB_FINDSTRING, .ListIndex, strSearchText)
    .ListIndex = lngListIndex
   
    If lngListIndex <> -1 Then
      apiGetKeyboardState abytKeys(0)
      bytPrevState = abytKeys(VK_SHIFT)
      abytKeys(VK_SHIFT) = 0
      apiSetKeyboardState abytKeys(0)
      apiSendMessageLng lngHwnd, WM_KEYDOWN, VK_END, 0&
      abytKeys(VK_SHIFT) = 128
      apiSetKeyboardState abytKeys(0)
      apiSendMessageLng lngHwnd, WM_KEYDOWN, VK_HOME, 0&
      While lngSelStart > 0&
        apiSendMessageLng lngHwnd, WM_KEYDOWN, VK_RIGHT, 0&
        lngSelStart = lngSelStart - 1&
      Wend
      abytKeys(VK_SHIFT) = bytPrevState
      apiSetKeyboardState abytKeys(0)
    End If
  End With
End Sub

Hi popsickle,
This old question (QID 20570834) needs to be finalized -- accept an answer, split points, or get a refund.  Please see http://www.cityofangels.com/Experts/Closing.htm for information and options.

All,
The cleanup ping was selected erroneously as the answer to this question.  You have 1 week to provide feedback on how this question should properly be finalized.

popsickle,
Please do not ever accept the cleanup ping as an answer.  It is more work for the moderators of this site.  The instructions provided gave you all the options for closing the question out and selecting the cleanup ping answer was not among them.  Thanks.

SpideyMod
Community Support Moderator @Experts Exchange

The credits will go to Bandy