How to register tlb files

I think that this was one of the things that was not included with VS 6 Professional. You needed the Enterprise edition, which comes with a type lib registry program.  The problem is when you want to deploy remote com+ objects, each client needs the tlb, or you have to install & register the dll on each client pc.  But I did find some source code that did the trick.

After compile use like this:

RegTLIB c:\myfolder\MyDLL.DLL

or Unreg like this:

RegTLIB MyDLL.DLL /U




I hope this works for you too:~)


----------------------RegTLIB.bas
Option Explicit


Private Type GUID
    Data1 As Long
    Data2 As Integer
    Data3 As Integer
    Data4(0 To 7) As Byte
End Type
Private Enum eSYSKIND
   SYS_WIN16 = 0&
   SYS_WIN32 = 1&
   SYS_MAC = 2&
End Enum

Private Declare Function LoadTypeLib Lib "oleaut32.dll" ( _
    pFileName As Byte, pptlib As Object) As Long
Private Declare Function RegisterTypeLib Lib "oleaut32.dll" ( _
    ByVal ptlib As Object, szFullPath As Byte, _
    szHelpFile As Byte) As Long
Private Declare Function UnRegisterTypeLib Lib "oleaut32.dll" ( _
      libID As GUID, _
      ByVal wVerMajor As Integer, _
      ByVal wVerMinor As Integer, _
      ByVal lCID As Long, _
      ByVal tSysKind As eSYSKIND _
   ) As Long
Private Declare Function CLSIDFromString Lib "ole32.dll" (lpsz As Byte, pclsid As GUID) As Long

Sub Main()

Dim cmd$
Dim opt$

cmd = Command

If Len(cmd) = 0 Or InStr(cmd, "/?") Or InStr(cmd, "-?") > 0 Then
    opt = "REGTLB Command Line Options" + vbCrLf + vbCrLf
    opt$ = opt + "To register: REGTLB YourDLL.DLL" + vbCrLf
    opt$ = opt + "To unregister: REGTLB YourDLL.DLL /U"
    MsgBox opt$, vbInformation, "REGTLB"
    End
End If

Dim HF As New zHandy

Dim UnReg As Boolean
UnReg = InStr(UCase(cmd), "/U") = 0
cmd = Trim(HF.LeftPart(cmd, "/"))
Dim ok
ok = Not RegTypelib(cmd, UnReg)

If Not ok Then
        ' place message here
End If

End Sub

Public Function RegTypelib(sLib As String, ByVal bState As Boolean) As Long

Dim suLib() As Byte
Dim errOK As Long
Dim tlb As Object
   If bState Then
      ' Basic automatically translates strings to Unicode Byte arrays
      ' but doesn't null-terminate, so you must do it yourself
      suLib = sLib & vbNullChar
      ' Pass first byte of array
      errOK = LoadTypeLib(suLib(0), tlb)
      If errOK = 0 Then
         errOK = RegisterTypeLib(tlb, suLib(0), 0)
         
      End If
      RegTypelib = errOK
   Else
      Dim cTLI As TypeLibInfo
      Dim tGUID As GUID, sCLSID As String
      Dim iMajor As Integer, iMinor As Integer
      Dim lCID As Long

      Set cTLI = TLI.TypeLibInfoFromFile(sLib)
      sCLSID = cTLI.GUID
      iMajor = cTLI.MajorVersion
      iMinor = cTLI.MinorVersion
      lCID = cTLI.lCID
      Set cTLI = Nothing
     
      suLib = sCLSID & vbNullChar
      errOK = CLSIDFromString(suLib(0), tGUID)
      If errOK = 0 Then
         errOK = UnRegisterTypeLib(tGUID, iMajor, iMinor, lCID, SYS_WIN32)
         RegTypelib = errOK
      End If
     
   End If
   
End Function

--------------------------zHandy.cls
Option Explicit

' Handy Functions
'
Dim dummy

Dim ErrorMessage As String
Dim ErrorNumber  As Long

Public Function RightPart(WholeString, FindString) As String

' Find the right part of a string
' A$=RightPart("ABC-EFG","-") ' returns "EFG"

Dim pos As Long

pos = InStr(1, WholeString, FindString, vbTextCompare)
If pos = 0 Then
    RightPart = ""
ElseIf pos = Len(WholeString) Then
    RightPart = ""
Else
    RightPart = Mid$(WholeString, pos + Len(FindString))
End If

End Function

Public Function ReadFile(filename As String) As Variant
' Reads a whole file into a string
' string contains ERROR if file not found or error

Dim wlfn As Long

wlfn = FreeFile
On Error Resume Next
If Len(Dir(filename)) > 0 Then
    If Err.Number Then
        ReadFile = Null
        ErrorNumber = Err.Number
        ErrorMessage = Err.Description
        Exit Function
    End If
    Open filename For Input Shared As #wlfn
    ReadFile = Input(LOF(wlfn), wlfn)
    Close wlfn
Else
    ReadFile = Null
    ErrorNumber = Err.Number
    ErrorMessage = Err.Description
End If

End Function
Public Function LeftPart(WholeString, FindString) As String

' Find the left part of a string
' A$=LeftPart("ABC-EFG","-") ' returns "ABC"

Dim pos As Long

pos = InStr(1, WholeString, FindString, vbTextCompare)
If pos = 0 Then
    LeftPart = WholeString
ElseIf pos = 1 Then
    LeftPart = ""
Else
    LeftPart = Left$(WholeString, pos - 1)
End If

End Function


Public Function WriteFileOK(filename As String, DataString) As Boolean

' saves DataString to a file FileName
' returns True if OK

Dim wlfn As Long

wlfn = FreeFile
On Error Resume Next
Err.Clear
WriteFileOK = False
Open filename For Output As #wlfn
If Err.Number <> 0 Then
    ErrorMessage = Err.Description
    ErrorNumber = Err.Number
    Exit Function
End If
Print #wlfn, DataString;
Close wlfn
If Err.Number <> 0 Then
    Exit Function
End If
WriteFileOK = True

End Function

I made a small application to register and unregister type libraries.  The code is in C++, though.  This is the URL:

http://www.developerfusion.com/show/3359/