How can I make my VB program sleep for 5 seconds?

Hi shivermetimbers,
What exactly do you mean by 'sleep' VB is naturally interupt driven, that is it 'sleeps' until an event is fired that it is programmed to react to (form load, textbox change button click etc. etc.) Do you mean 'becomes un responsive' for 5 seconds, or does something every 5 seconds.
In either case, you need a timer.
In the first case, create a global boolean variable say IsActive
On Timer Tick, toggle it's value

in every other event check IsActive before doing anything.

If you want to do something every 5 seconds, set the timer interval to 5000 (ms) and carry out your processing in the timer tick event. N.B. It's usual to disable the timer in it's own event, and reset and enable it again at the end.

Regards .. Alan

As ADSaunders suggests say you are writing a windows service which wakes up every 30 seconds do check something if you use sleep 30000 and the operator tries to click on your systray icon the whole machine will feel like its has frozen until the sleep ends. But is you use the Delay sub, Delay 30 as described, your application will respond as soon as the icon is clicked and the user interface becomes active.  But the background task won't restart until the 30 seconds is up.

Hope this helps~)

Add a .bas  module to your project
Name it mWait.bas
Paste all the code below into it and call it in your app

wait X: where x = seconds to delay

this will allow you app to wait but not be unresponsive of cause windows to "hang"

'******************
' Wait Module code
Option Explicit

Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Const WAIT_ABANDONED& = &H80&
Private Const WAIT_ABANDONED_0& = &H80&
Private Const WAIT_FAILED& = -1&
Private Const WAIT_IO_COMPLETION& = &HC0&
Private Const WAIT_OBJECT_0& = 0
Private Const WAIT_OBJECT_1& = 1
Private Const WAIT_TIMEOUT& = &H102&

Private Const INFINITE = &HFFFF
Private Const ERROR_ALREADY_EXISTS = 183&

Private Const QS_HOTKEY& = &H80
Private Const QS_KEY& = &H1
Private Const QS_MOUSEBUTTON& = &H4
Private Const QS_MOUSEMOVE& = &H2
Private Const QS_PAINT& = &H20
Private Const QS_POSTMESSAGE& = &H8
Private Const QS_SENDMESSAGE& = &H40
Private Const QS_TIMER& = &H10
Private Const QS_MOUSE& = (QS_MOUSEMOVE _
                            Or QS_MOUSEBUTTON)
Private Const QS_INPUT& = (QS_MOUSE _
                            Or QS_KEY)
Private Const QS_ALLEVENTS& = (QS_INPUT _
                            Or QS_POSTMESSAGE _
                            Or QS_TIMER _
                            Or QS_PAINT _
                            Or QS_HOTKEY)
Private Const QS_ALLINPUT& = (QS_SENDMESSAGE _
                            Or QS_PAINT _
                            Or QS_TIMER _
                            Or QS_POSTMESSAGE _
                            Or QS_MOUSEBUTTON _
                            Or QS_MOUSEMOVE _
                            Or QS_HOTKEY _
                            Or QS_KEY)

Private Declare Function CreateWaitableTimer Lib "kernel32" _
    Alias "CreateWaitableTimerA" ( _
    ByVal lpSemaphoreAttributes As Long, _
    ByVal bManualReset As Long, _
    ByVal lpName As String) As Long
   
Private Declare Function OpenWaitableTimer Lib "kernel32" _
    Alias "OpenWaitableTimerA" ( _
    ByVal dwDesiredAccess As Long, _
    ByVal bInheritHandle As Long, _
    ByVal lpName As String) As Long
   
Private Declare Function SetWaitableTimer Lib "kernel32" ( _
    ByVal hTimer As Long, _
    lpDueTime As FILETIME, _
    ByVal lPeriod As Long, _
    ByVal pfnCompletionRoutine As Long, _
    ByVal lpArgToCompletionRoutine As Long, _
    ByVal fResume As Long) As Long
   
Private Declare Function CancelWaitableTimer Lib "kernel32" ( _
    ByVal hTimer As Long)
   
Private Declare Function CloseHandle Lib "kernel32" ( _
    ByVal hObject As Long) As Long
   
Private Declare Function WaitForSingleObject Lib "kernel32" ( _
    ByVal hHandle As Long, _
    ByVal dwMilliseconds As Long) As Long
   
Private Declare Function MsgWaitForMultipleObjects Lib "user32" ( _
    ByVal nCount As Long, _
    pHandles As Long, _
    ByVal fWaitAll As Long, _
    ByVal dwMilliseconds As Long, _
    ByVal dwWakeMask As Long) As Long

Public Sub Wait(lNumberOfSeconds As Long)
    Dim ft As FILETIME
    Dim lBusy As Long
    Dim lRet As Long
    Dim dblDelay As Double
    Dim dblDelayLow As Double
    Dim dblUnits As Double
    Dim hTimer As Long
   
    hTimer = CreateWaitableTimer(0, True, App.EXEName & "Timer")
   
    If Err.LastDllError = ERROR_ALREADY_EXISTS Then
        ' If the timer already exists, it does not hurt to open it
        ' as long as the person who is trying to open it has the
        ' proper access rights.
    Else
        ft.dwLowDateTime = -1
        ft.dwHighDateTime = -1
        lRet = SetWaitableTimer(hTimer, ft, 0, 0, 0, 0)
    End If
   
    ' Convert the Units to nanoseconds.
    dblUnits = CDbl(&H10000) * CDbl(&H10000)
    dblDelay = CDbl(lNumberOfSeconds) * 1000 * 10000
   
    ' By setting the high/low time to a negative number, it tells
    ' the Wait (in SetWaitableTimer) to use an offset time as
    ' opposed to a hardcoded time. If it were positive, it would
    ' try to convert the value to GMT.
    ft.dwHighDateTime = -CLng(dblDelay / dblUnits) - 1
    dblDelayLow = -dblUnits * (dblDelay / dblUnits - _
        Fix(dblDelay / dblUnits))
   
    If dblDelayLow < CDbl(&H80000000) Then
        ' &H80000000 is MAX_LONG, so you are just making sure
        ' that you don't overflow when you try to stick it into
        ' the FILETIME structure.
        dblDelayLow = dblUnits + dblDelayLow
    End If
   
    ft.dwLowDateTime = CLng(dblDelayLow)
    lRet = SetWaitableTimer(hTimer, ft, 0, 0, 0, False)
   
    Do
        ' QS_ALLINPUT means that MsgWaitForMultipleObjects will
        ' return every time the thread in which it is running gets
        ' a message. If you wanted to handle messages in here you could,
        ' but by calling Doevents you are letting DefWindowProc
        ' do its normal windows message handling---Like DDE, etc.
        lBusy = MsgWaitForMultipleObjects(1, hTimer, False, _
            INFINITE, QS_ALLINPUT&)
        DoEvents
    Loop Until lBusy = WAIT_OBJECT_0
   
    ' Close the handles when you are done with them.
    CloseHandle hTimer

End Sub


I am not sure where the code came from originally but it works great!
dan

HEY DANNYMAC!
Thanks for this code!

I've been looking for something like this for years!

'We Need One CommandButton and A Regular Form :

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub cmdSleep_Click()
    Me.Caption = "Rabia Need the system to sleep 5 sec."
    'Sleep for 5000 ms
    Sleep 5000
    Me.Caption = ""
End Sub
Private Sub Form_Load()
    Me.Caption = ""
    cmdSleep.Caption = "Sleeping ..."
End Sub

'Code By : Rabia Abu-Hanna
'Nazareth - Israel

Hi inthedark, i used ur code and it worked. but i have another problem now

i want the program while waiting for like 10 seconds, if a user event is found, say a click of a button, then the program will resume from delay and do wotever it has to do after, how do i do that? thx!!

I have included the following in my asp page ...

Delay 5

Sub Delay(pdblSeconds As Double)

' delay for x secodns
' this sub used very little CPU resouces

Const OneSecond As Double = 1#/(1440# * 60#)

Dim dblWaitUntil As Date
dblWaitUntil = Now + OneSecond * pdblSeconds
Do Until Now>dblWaitUntil
    Sleep 100
    DoEvents ' Allow windows message to be processed
Loop

End Sub

I get the following error, and have not been able to resolve it.  If you can help please do...

Microsoft VBScript compilation  error '800a03ee'

Expected ')'

/admin/DBMaint/DBDel2.asp, line 45

Sub Delay(pdblSeconds As Double)
----------------------^

I tried DANNYMAC's code, I need such a routine badly.
Unfortunately it goes into an infinate loop.

I called it as follows:
Dim PauseTime As Long
PauseTime = 4
Wait (PauseTime)

but it just loops in the routine
    Do
        ' QS_ALLINPUT means that MsgWaitForMultipleObjects will
        ' return every time the thread in which it is running gets
        ' a message. If you wanted to handle messages in here you could,
        ' but by calling Doevents you are letting DefWindowProc
        ' do its normal windows message handling---Like DDE, etc.
        lBusy = MsgWaitForMultipleObjects(1, hTimer, False, _
            INFINITE, QS_ALLINPUT&)
        DoEvents
    Loop Until lBusy = WAIT_OBJECT_0

Is there a parameter I could change to make it finite?

mengqing

To stop events being processed by your app set the Enable property to False (on any active forms) before calling the Delay sub.  Remember to set it True again after the Delay code completes (and in the case of an error occuring) or the user gets stuck.

HELL YEA! WAIT COMMAND IS AWSOME!

This will fix so many problems of mine.  :)) Thanks  DANNYMAC!  This isn't even my question thread but I think it helped me the most, lol.

Wait stinks... This is by far the best "Pause" function Ive seen...


Private Declare Function GetTickCount Lib "kernel32" () As Long

Public Sub Pause(Seconds As Single)
   
  Dim T As Single
  Dim T2 As Single
  Dim Num As Single
 
  Num = Seconds * 1000
 
  T = GetTickCount()
  T2 = GetTickCount()
 
  Do Until T2 - T >= Num
    T2 = GetTickCount()
    DoEvents
  Loop
   
End Sub