Printing Flex Grid

Multiple possibilities
1)
Public Sub MSFlexGridPrint(gridQuery As Control)
   ' *** Print MSFlexGrid

   Dim I          As Integer
   Dim J          As Integer
   Dim PTab       As Integer

   For I = 1 To gridQuery.Rows - 1
      PTab = 20 'Set the first tab value
      'This checks to see if a page break is needed

      If Printer.CurrentY + Printer.TextHeight(gridQuery.Text) > Printer.ScaleHeight - 600 Then
         Printer.NewPage
      End If

      gridQuery.Row = I 'Set the active row

      For J = 0 To gridQuery.Cols - 1
         gridQuery.Col = J 'Set the current column
         
         'Send the field to the print line and add the tab.
         'Notice the semicolon at the end of the line.

         Printer.Print Trim$(gridQuery.Text); Tab(PTab);

         PTab = PTab + 20 'Increment the tab value
      Next

      'After each column has printed to the print line

      'a Printer.Print statement without a semicolon will
      'will send the line to the printer and start a new
      'one.
      Printer.Print
 Next

End Sub  

2)
MSFlexigrid1.TextMatrix(1,1) - this gives the content in the first row, first column. Likewise, when you put in a For Loop u can get the content in each cell. Further, for each row of data, you can append to a string and pass it to the printer object.

(Eg):

For Ctr = 1 to MSFlexigrid1.Rows - 1
 strcontent = MSFlexigrid1.TextMatrix(Ctr,1)
 strcontent = strcontent & MSFlexigrid1.TextMatrix(ctr,2)

' where 1 & 2 are the columns. Like wise you can continue to build the string for each row & finally print.

printer.print strcontent

Next

4) Export to an invisible excel and print
try this out!!

Public Sub FlexGrid_To_Excel(TheFlexgrid As MSFlexGrid, _
TheRows As Integer, TheCols As Integer, mode As Integer)
 
Dim objXL As New Excel.Application
Dim wbXL As New Excel.Workbook
Dim wsXL As New Excel.Worksheet
Dim intRow As Integer
Dim intCol As Integer

On Error Resume Next

' open Excel
If mode = 1 Then
  objXL.Visible = True
Else
  objXL.Visible = False
End If
Set wbXL = objXL.Workbooks.Add
Set wsXL = objXL.ActiveSheet

' this is to fill the worksheet
For intRow = 1 To TheRows
  For intCol = 1 To TheCols
      With TheFlexgrid
          wsXL.Cells(intRow, intCol).Value = _
             .TextMatrix(intRow - 1, intCol - 1) & " "
             wsXL.Columns(intCol).AutoFit
      End With
  Next
Next
If mode = 2 Then
  wsXL.PrintOut
End If
End Sub

5)
Here's a quick way to print a MSFlexGrid control's contents:
    Printer.PaintPicture MSFlexGrid_Name.Picture, 0, 0
  Printer.EndDoc

And if you want it to be the full length of the printer page add this before those two statements:
    Dim old_width as Integer
  MSFlexGrid_Name.width=printer.width

and this at the end:
     MSFlexGrid_Name.width=old_width