Is there i way to get the HWND ID of a running EXE without knowing the Application Title?

Here is a sample with added InstanceToWnd.
Take the parts you need and adapt it:

Private Const GW_HWNDNEXT = 2
Private Const GWL_HWNDPARENT = (-8)

Private Const PROCESS_QUERY_INFORMATION = 1024
Private Const PROCESS_VM_READ = 16
Private Const MAX_PATH = 260

Private Const GWL_EXSTYLE = (-20)
Private Const WS_EX_TOOLWINDOW = &H80


Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" ( _
    ByVal hwnd As Long, ByVal nIndex As Long) As Long

Private Declare Function GetWindow Lib "user32" ( _
    ByVal hwnd As Long, ByVal wCmd As Long) As Long
   
Private Declare Function IsWindowVisible Lib "user32" ( _
    ByVal hwnd As Long) As Long

Private Declare Function GetWindowThreadProcessId Lib "user32" ( _
    ByVal hwnd As Long, lpdwProcessId As Long) As Long

Private Declare Function GetParent Lib "user32" ( _
    ByVal hwnd As Long) As Long

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As Long, ByVal lpWindowName As Long) As Long

Private Declare Function CloseHandle Lib "Kernel32.dll" _
   (ByVal Handle As Long) As Long

Private Declare Function OpenProcess Lib "Kernel32.dll" _
  (ByVal dwDesiredAccessas As Long, ByVal bInheritHandle As Long, _
      ByVal dwProcId As Long) As Long

Private Declare Function EnumProcesses Lib "psapi.dll" _
   (ByRef lpidProcess As Long, ByVal cb As Long, _
      ByRef cbNeeded As Long) As Long

Private Declare Function GetModuleFileNameExA Lib "psapi.dll" _
   (ByVal hProcess As Long, ByVal hModule As Long, _
      ByVal ModuleName As String, ByVal nSize As Long) As Long

Private Declare Function EnumProcessModules Lib "psapi.dll" _
   (ByVal hProcess As Long, ByRef lphModule As Long, _
      ByVal cb As Long, ByRef cbNeeded As Long) As Long

Private Type PROCESSENTRY32
   dwSize As Long
   cntUsage As Long
   th32ProcessID As Long           ' This process
   th32DefaultHeapID As Long
   th32ModuleID As Long            ' Associated exe
   cntThreads As Long
   th32ParentProcessID As Long     ' This process's parent process
   pcPriClassBase As Long          ' Base priority of process threads
   dwFlags As Long
   szExeFile As String * 260       ' MAX_PATH
End Type

Private Sub Command1_Click()
    Dim cb As Long
    Dim cbNeeded As Long
    Dim NumElements As Long
    Dim ProcessIDs() As Long
    Dim cbNeeded2 As Long
    Dim Modules(1 To 200) As Long
    Dim lRet As Long
    Dim ModuleName As String
    Dim nSize As Long
    Dim hProcess As Long
    Dim i As Long
   
    List1.Clear
    'Get the array containing the process id's for each process object
    cb = 8
    cbNeeded = 96
    Do While cb <= cbNeeded
        cb = cb * 2
        ReDim ProcessIDs(cb / 4) As Long
        lRet = EnumProcesses(ProcessIDs(1), cb, cbNeeded)
    Loop
    NumElements = cbNeeded / 4

    For i = 1 To NumElements
        'Get a handle to the Process
        hProcess = OpenProcess(PROCESS_QUERY_INFORMATION _
           Or PROCESS_VM_READ, 0, ProcessIDs(i))
        'Got a Process handle
        If hProcess <> 0 Then
            'Get an array of the module handles for the specified
            'process
            lRet = EnumProcessModules(hProcess, Modules(1), 200, _
               cbNeeded2)
            'If the Module Array is retrieved, Get the ModuleFileName
            If lRet <> 0 Then
                ModuleName = Space(MAX_PATH)
                nSize = 500
                lRet = GetModuleFileNameExA(hProcess, Modules(1), _
                   ModuleName, nSize)
                List1.AddItem Left(ModuleName, lRet)
            End If
        End If
        'Close the handle to the process
        lRet = CloseHandle(hProcess)
    Next
End Sub

Private Function InstanceToWnd(ByVal target_pid As Long) As Collection
    Dim test_hwnd As Long
    Dim test_pid As Long
    Dim test_thread_id As Long
    Dim ProcesshWnds As New Collection
    '
    'Get the first window handle.
    '
    test_hwnd = FindWindow(ByVal 0&, ByVal 0&)
    '
    Do While test_hwnd <> 0 'Loop until we find the target or we run out of windows.
        If GetParent(test_hwnd) = 0 Then 'See if this window has a parent. If not, it is a top-level window.
            test_thread_id = GetWindowThreadProcessId(test_hwnd, test_pid)
            If test_pid = target_pid Then 'See if the top-level window has the target instance handle.
                If IsTask(test_hwnd) Then
                    Call ProcesshWnds.Add(test_hwnd) 'This is the target.
                End If
            End If
        End If
        test_hwnd = GetWindow(test_hwnd, GW_HWNDNEXT) 'Examine the next window.
    Loop
    '
    Set InstanceToWnd = ProcesshWnds
    '
End Function

Private Function IsTask(ByVal hwnd As Long) As Boolean
    Dim hWndOwner As Long
    '
    If IsWindowVisible(hwnd) Then
        If GetParent(hwnd) = 0 Then 'Can't have Parent.
            'Can't have Owner *except* in the case where owner has WS_EX_TOOLWINDOW StyleEx bit set.
            'This is how VB apps (and others?) operate.
            hWndOwner = GetWindowLong(hwnd, GWL_HWNDPARENT)
            If (hWndOwner = 0) Or IsToolWindow(hWndOwner) Then
                If Not IsToolWindow(hwnd) Then 'Must not be Toolwindow.
                    IsTask = True 'We have a winner!
                End If
            End If
        End If
    End If
    '
End Function

Private Function IsToolWindow(ByVal hwnd As Long) As Boolean
    IsToolWindow = ((GetWindowLong(hwnd, GWL_EXSTYLE) And WS_EX_TOOLWINDOW) = WS_EX_TOOLWINDOW) 'Check for toolwindow style bit.
End Function