Open and Search a .txt file ( VB6.0 )

'===============================================================
'CKRFindInFile Module
'
Option Explicit
'Always use the "explicit" option in any module.....
'we want the compiler to force us to define all
'variable types (avoids errors in finished product)
 
Public Function CKRFindInFile(cFile As String, cStart As String, _
                     cEnd As String) As String()
  'This function (made public so any module in a project will be able to
  'use it) searches a text file from first line to last and returns an
  'array of strings found in the file.
  'The strings start with a certain "Starting characters" and end with
  'certain "ending characters" as passed to the function.
  
  'Parameters: cFile: The name of the file (including path).
  '                   If the File does not exist, this function will
  '                   simply return an empty array (i.e.no values)
  '            cStart: The starting characters of the string
  '            cEnd  : The ending characters of the string
                      
  
  'Define a few things
  Dim nFile As Integer       'A file "handle" for the text file we are opening
  Dim cLine As String        'Variable storing the value of the last line read
  Dim nFind1 As Integer      'The starting position of the "starting characters" within the line
  Dim nFind2 As Integer      'The starting position of the "ending characters" within the line
  Dim nLen As Integer        'The length of the found string (calculated from nFind1 and nFind2)
  Dim FindInFile() As String 'A temporary array holding the values found (no size assigned yet)
  
  'Initialize the array
  'You can "redemsion" (make bigger/smaller) an array which was defined
  'with NO array size as per the Dim statement for FindInFile()
  ReDim FindInFile(0)
  
  'Only open and read in a file if it exists (of course)
  'Refer to the function "FileExists" found in this project
  If FileExists(cFile) Then
    'Open the file for reading only
    nFile = FreeFile
    Open cFile For Input As #nFile
    
    'Read in the first line
    Line Input #nFile, cLine
    
    'Until the end of the file, do the following
    Do While Not EOF(nFile)
      'Find the position of the "starting with" text
      nFind1 = InStr(cLine, cStart)
      
      'If we find the starting text
      If nFind1 > 0 Then
        'find the ending text in the same line starting at the end of the "starting text"
        nFind2 = InStr(nFind1 + Len(cStart) + 1, cLine, cEnd)
        
        'If we find the ending text too (and the ending text occurs after the starting text)
        If nFind2 > nFind1 Then
          'add the found string to our array
          'We retain previous values in the array by using the option "Preserve"
          'so first of all expand the array by 1 element if it already has a value
          If UBound(FindInFile) > 0 Then
            ReDim Preserve FindInFile(UBound(FindInFile) + 1)
          End If
          
          'calculate the length of the found string
          nLen = nFind2 - nFind1 + Len(cEnd)
          
          'store the value in the last element of the array
          FindInFile(UBound(FindInFile)) = _
                 Mid$(cLine, nFind1, nLen)
        End If
        'we must search the rest the string after any occurrence,
        
        If nLen > 0 Then
          'so pick up the resst of the line, starting at the end of the
          'string just found.
          cLine = Mid$(cLine, nLen)
        Else
          'If no string was found, just read in another line!
          Line Input #nFile, cLine
        End If
      Else
        'No starting text found, so read in another line
        Line Input #nFile, cLine
      End If
    Loop
  End If
  'Store the entire array into the return value of the function
  CKRFindInFile = FindInFile
End Function
 
Public Function FileExists(cFile As String) As Boolean
  Dim fs As Object
  Set fs = CreateObject("Scripting.FileSystemObject")
  FileExists = fs.FileExists(cFile)
End Function
 
 
 
'=========================================================================
'CKRFileDirectory Module
'
'force declarations to ensure optimized code
Option Explicit
 
'this function returns the directory in which a file exists
'(i.e. strips out the file name itself.)
 
'Note: The file does NOT have to necessarily exist!
 
'-------------------------------------------------------------------------------------------------
'Parameters:        cFile as String             - Destination directory
'Return Value:      CKRFileDirectory as string  - name of directory in which file exists
'-------------------------------------------------------------------------------------------------
 
Public Function CKRFileDirectory(cFile As String) As String
 
Dim cDir     As String
 
Dim nAt      As Integer
Dim fs As Object
Set fs = CreateObject("Scripting.FileSystemObject")
CKRFileDirectory = fs.GetparentFoldername(cFile) + "\"
 
End Function
 
'==========================================================================
' The Max function module
Option Explicit
 
Public Function Max(nVal1 As Variant, nVal2 As Variant) As Variant
'This function returns the maximum of two items being compared
 
If nVal1 > nVal2 Then
  Max = nVal1
Else
  Max = nVal2
End If
 
End Function

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102:
103:
104:
105:
106:
107:
108:
109:
110:
111:
112:
113:
114:
115:
116:
117:
118:
119:
120:
121:
122:
123:
124:
125:
126:
127:
128:
129:
130:
131:
132:
133:
134:
135:
136:
137:
138:
139:
140:
141: