Modify a text file with Windows Batch or VB Script

Option Explicit
'should always use this option in VB6 code to force
'strict typing of variables
 
Private Sub main()
  'This program will accept a filename from the command line
  'and then process the file according to ceratin criteria in the function
  ' "Processline", writing the reformatted text lines in the input file
  'back out to the file. Note! The input file name is retained, but the original contents
  'are over-written!
  
  Dim cCommand As String 'variable to hold command line
  
  cCommand = Command     'obtain a value in the command line passed to the program
  
  '*** NOTE! The next program line is for testing purposes!
  'Alter the value as required to point to a test file.
  'Comment out the next line when running this program in production!
  cCommand = "C:\file-example.txt"
  
  If Len(cCommand) > 0 Then
    ChangeFile cCommand  ' a filename was supplied so let's process it
  Else
    MsgBox "Syntax: ChangeFile <filename>"
  End If
  End
End Sub
 
Private Sub ChangeFile(cInFile As String)
  ' A routine to change the contenets of a file (cInFile) according
  ' certain criteria stipulated in the function "ProcessLine"
  
  Dim nInFile As Integer     'Pointer to the file being read in
  Dim nOutFile As Integer    'Pointer to the file being written to
  Dim cOutFile As String     'Name of the file (temporary) being written to
  Dim cLine As String        'Variable to hold value of latest line read in from cInFile
  Dim nLines As Long         'Variable to keep track of number of lines processed
  Dim Processing As Boolean  'Control variable determing whether EOF has been reached
  
  If FileExists(cInFile) Then
    If FileSize(cInFile) > 0 Then   'an empty file should not be processed
      nInFile = FreeFile
      Open cInFile For Input As #nInFile
      nOutFile = FreeFile
      cOutFile = TempFile()
      Open cOutFile For Output As #nOutFile
      Processing = True
      Do While Processing
        Line Input #nInFile, cLine
        nLines = nLines + 1
        ProcessLine cLine, nOutFile
        Processing = (Not EOF(nInFile))
      Loop
      Close #nInFile
      Close #nOutFile
      Kill cInFile
      Name cOutFile As cInFile
      MsgBox cInFile + " processed: " + CStr(nLines) + " lines"
    Else
      MsgBox cInFile + " is empty!"
    End If
  Else
    MsgBox "File does not exists: " + cInFile
  End If
End Sub
Private Sub ProcessLine(cLine As String, nOutFile As Integer)
  ' A process to manipulate a line (cLine) according to certain criteria and then
  ' write the reformatted line to a file.
  ' "nOutFile" is a pointer to the output file whic has been previously opened for output
  
  Dim cToken() As String      'an array to hold original sections of the line being processed
  Dim cToken2(4) As String    ' a temprary array used for "token-swapping"
  Dim nToken As Integer       'a control variable to reference each token in the line
  cToken = Split(cLine, "|")  'obtain each token from the line, seperator being "pipe" symbol
  ShiftTokens cToken          'shift the tokens one place to the right (makes referencing easier
                              'since cToken is zero based array
  cLine = ""                  'reinitialize value of the current line
  For nToken = 1 To UBound(cToken) - 1  'rebuild the line according to criteria
    Select Case nToken
      Case 1, 3, 4, 7, 8, 9, 11
      Case Else
        cLine = cLine + cToken(nToken) + "|"
    End Select
  Next
  cLine = cLine + cToken(UBound(cToken))
  MsgBox "Step 1: " + cLine
  
  cToken = Split(cLine, "|")  'obtain each token from the newly defined line, seperator being "pipe" symbol
  ShiftTokens cToken          'again shift the tokens one place to the right (makes referencing easier
  cToken2(1) = cToken(1)      'do some token "swapping"
  cToken2(2) = cToken(4)
  cToken2(3) = cToken(2)
  cToken2(4) = cToken(3)
  cLine = ""                 'reinitialize value of the current line
  
  For nToken = 1 To UBound(cToken) - 1 'rebuild the line accorfing to criteria
    Select Case nToken
       Case 1, 3, 4
         cLine = cLine + cToken2(nToken) + "|"  'adding "swapped" tokens
       Case 2
         cLine = cLine + cToken2(nToken) + "_"  'adding swapped tokens 2 and 3 with a joining underscore
       Case Else
         cLine = cLine + cToken(nToken) + "|"  'adding unswapped tokens
     End Select
  Next
  cLine = cLine + cToken(UBound(cToken))
  MsgBox "Steps 2 and 3: " + cLine
  cLine = Replace(cLine, "|", vbTab)    'replace all pipe characters in the line with a Tab
  MsgBox "Step 4: " + cLine
  cLine = Replace$(cLine, Chr(34), "")  'remove all double quotes from Line
  MsgBox "Step 5: " + cLine
  Print #nOutFile, cLine                'write the line out to the output file
End Sub
 
Private Function ShiftTokens(cToken() As String) As String()
  'shift all tokens 1 place to the right
  '(makes reading this code a lot easier)
  'since "Option Base 1" cannot be applied
  'to arrays not dimensioned in their
  'original "Dim" statement
  Dim nToken As Integer
  ReDim Preserve cToken(UBound(cToken) + 1)
  For nToken = UBound(cToken) To 1 Step -1
    cToken(nToken) = cToken(nToken - 1)
  Next
End Function
Public Function TempFile(Optional cDir As String, Optional cExt As String) As String
Dim nRand As Integer
Dim cRand As String
If Len(Trim(cDir)) = 0 Then
  cDir = "c:\"
End If
If Len(Trim(cExt)) = 0 Then
  cExt = ".txt"
End If
Do While True
  nRand = Random(1000)
  cRand = CStr(nRand)
  If Right(cDir, 1) <> "\" Then
    cDir = cDir + "\"
  End If
  TempFile = cDir + "Temp" + cRand + cExt
  If Not FileExists(TempFile) Then
    Exit Do
  End If
Loop
End Function
 
 
 
Public Function Random(nUpper As Integer, Optional nLower As Integer) As Integer
Randomize
Random = -1
Do While Random < nLower
  Random = Int(nUpper * Rnd) + 1
Loop
End Function
 
Public Function FileExists(FileName As String) As Boolean
Dim fs As Object
Set fs = CreateObject("Scripting.FileSystemObject")
FileExists = fs.FileExists(FileName)
End Function
 
Function FileSize(cFile As String) As Long
Dim objFile As Variant
Dim fs
On Error GoTo nofile
FileSize = 0
Set fs = CreateObject("Scripting.FileSystemObject")
Set objFile = fs.GetFile(cFile)
FileSize = objFile.Size
nofile:
End Function
                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102:
103:
104:
105:
106:
107:
108:
109:
110:
111:
112:
113:
114:
115:
116:
117:
118:
119:
120:
121:
122:
123:
124:
125:
126:
127:
128:
129:
130:
131:
132:
133:
134:
135:
136:
137:
138:
139:
140:
141:
142:
143:
144:
145:
146:
147:
148:
149:
150:
151:
152:
153:
154:
155:
156:
157:
158:
159:
160:
161:
162:
163:
164:
165:
166:
167:
168:
169:
170:
171:
172:
173:
174:

File = "FileName.txt"
Output = "Filename3.txt"
 
Const ForWriting = 2
 
Set fso = CreateObject("Scripting.FileSystemObject")
 
Set InFile = fso.OpenTextFile(File)
Set OutFile = fso.CreateTextFile(Output, ForWriting)
 
Do While Not InFile.AtEndOfStream
    Row = Split(Replace(InFile.ReadLine, Chr(34), ""), "|")
    OutFile.WriteLine Row(1) + vbTab + Row(9) + "_" + Row(4) + vbTab + Row(5) + vbTab + Row(11) + vbTab + Row(12) + vbTab + Row(13) + vbTab + Row(14) + vbTab + Row(15) + vbTab + Row(16) + vbTab + Row(17) + vbTab + Row(18) + vbTab + Row(19) + vbTab + Row(20) + vbTab + Row(21) + vbTab + Row(22)
Loop
 
InFile.Close
OutFile.Close

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:

Set File=Filename.txt
Set Output=Filename2.txt
 
for /f "tokens=2,5,6,10,11-22 delims=|" %%a in (%file%) do (
    @echo %%~a	%%~d_%%~b	%%~c	%%~e	%%~f	%%~g	%%~h	%%~i	%%~j	%%~k	%%~l	%%~m	%%~n	%%~o	%%~p
)>"%Output%"

                                              

1:
2:
3:
4:
5:
6:

Private Sub ChangeFile(cInFile As String)
  ' A routine to change the contenets of a file (cInFile) according
  ' certain criteria stipulated in the function "ProcessLine"
  
  Dim nInFile As Integer     'Pointer to the file being read in
  Dim nOutFile As Integer    'Pointer to the file being written to
  Dim cOutFile As String     'Name of the file (temporary) being written to
  Dim cLine As String        'Variable to hold value of latest line read in from cInFile
  Dim nLines As Long         'Variable to keep track of number of lines processed
  Dim Processing As Boolean  'Control variable determing whether EOF has been reached
  Dim bSuccess As Boolean    'Switch to note whether conversion was successful
  
  If FileExists(cInFile) Then
    If FileSize(cInFile) > 0 Then   'an empty file should not be processed
      nInFile = FreeFile
      Open cInFile For Input As #nInFile
      nOutFile = FreeFile
      cOutFile = TempFile()
      Open cOutFile For Output As #nOutFile
      Processing = True
      bSuccess = True 'assume all will go well!
      Do While Processing
        Line Input #nInFile, cLine
        If InStr(cLine, "|") > 0 Then
          nLines = nLines + 1
          ProcessLine cLine, nOutFile
          Processing = (Not EOF(nInFile))
        Else
          bSuccess = False
          Processing = False
          MsgBox "Input file not in expected format: " + cInFile
        End If
      Loop
      Close #nInFile
      Close #nOutFile
      If bSuccess Then
        Kill cInFile
        Name cOutFile As cInFile
        MsgBox cInFile + " processed: " + CStr(nLines) + " lines"
      Else
        Kill cOutFile
      End If
    Else
      MsgBox cInFile + " is empty!"
    End If
  Else
    MsgBox "File does not exists: " + cInFile
  End If
End Sub

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:

Set File=cfm_extract.txt
Set Output=2008_Budget_Final.txt
(for /f "tokens=2,5,6,10,11-22 delims=|" %%a in (%file%) do (
    echo %%~a   %%~d_%%~b   %%~c   %%~e   %%~f   %%~g   %%~h   %%~i   %%~j   %%~k   %%~l   %%~m   %%~n   %%~o   %%~p
))>"%Output%"

                                              

1:
2:
3:
4:
5:

@echo off
setlocal enabledelayedexpansion
 
(for /f "tokens=2,5,6,10,12-14,16-18,21-23,25-27 delims=|" %%a in (cfm_extract.txt) do (
   set col6=%%~f
   echo %%~a   %%~d_%%~b   %%~c  %%~e  20!col6:~-2!   %%~g  %%~h  %%~i  %%~j  %%~k  %%~l  %%~m  %%~n  %%~o  %%~p>>"%Output%"
))>2008_Budget_Final.txt
                                              

1:
2:
3:
4:
5:
6:
7: