How to determine whether other languages have been installed in "Regional Options"

'This codewill enumerate what languages are installed(LCID)

'Form Code
Option Explicit

Dim WithEvents cEnumLCID As clsEnumLCID

Private Sub cEnumLCID_EnumLocales(ByVal LCID As Long)
   List1.AddItem Hex$(LCID) & vbTab & LCID & vbTab & _
                 pfGLI(LCID, LOCALE_SABBREVLANGNAME) & vbTab & _
                 pfGLI(LCID, LOCALE_SLANGUAGE)
End Sub

Private Sub cmdLoadLocales_Click()

   Dim LCID             As Long
   Set cEnumLCID = New clsEnumLCID
   'get the user's current default ID
   LCID = GetSystemDefaultLCID()

   'show the current localized name of language
   Text1.Text = pfGLI(LCID, LOCALE_SLANGUAGE) & vbTab & _
      pfGLI(LCID, LOCALE_SABBREVLANGNAME)

   LocaleCount = 0
   List1.Clear
   List1.AddItem "Installed Locales:"
   List1.AddItem "Hex" & vbTab & "Dec" & vbTab & "Abv" & vbTab & "Language"
   List1.AddItem "---" & vbTab & "---" & vbTab & "---" & vbTab & "--------"
   cEnumLCID.EnumInstalledLocales
   lblInstalled.Caption = LocaleCount & " Installed"
   Set cEnumLCID = Nothing
End Sub

Private Sub Form_Unload(Cancel As Integer)
   Set cEnumLCID = Nothing
End Sub

'Module Code (modEnumLCID)
Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright ©1996-2004 VBnet, Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Distribution: You can freely use this code in your own
'               applications, but you may not reproduce
'               or publish this code on any web site,
'               online service, or distribute as source
'               on any media without express permission.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Const LOCALE_SLANGUAGE       As Long = &H2  'localized name of language
Public Const LOCALE_SABBREVLANGNAME As Long = &H3  'abbreviated language name
Public Const LCID_INSTALLED         As Long = &H1  'installed locale ids
Public Const LCID_SUPPORTED         As Long = &H2  'supported locale ids
Public Const LCID_ALTERNATE_SORTS   As Long = &H4  'alternate sort locale ids
Public Const VER_PLATFORM_WIN32_NT  As Long = 2

Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Public Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long
Public Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (lpVersionInformation As OSVERSIONINFO) As Long
Public Declare Function GetLocaleInfoA Lib "kernel32" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
Public Declare Function GetLocaleInfoW Lib "kernel32" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
Public Declare Function GetUserDefaultLCID Lib "kernel32" () As Long

Public Declare Function EnumSystemLocales Lib "kernel32" Alias "EnumSystemLocalesA" (ByVal lpLocaleEnumProc As Long, ByVal dwFlags As Long) As Long

Public Type OSVERSIONINFO
   dwOSVersionInfoSize  As Long
   dwMajorVersion       As Long
   dwMinorVersion       As Long
   dwBuildNumber        As Long
   dwPlatformId         As Long
   szCSDVersion         As String * 128 ' Maintenance string
End Type

Private Buffer       As String * 255
Private m_lObj       As Long
Public LocaleCount   As Long

Public Function EnumSystemLocalesProc(lpLocaleString As Long) As Long

  'application-defined callback function for EnumSystemLocales

   Dim pos As Integer
   Dim dwLocaleDec As Long
   Dim dwLocaleHex As String
   Dim sLocaleName As String
   Dim sLocaleAbbrev As String
     
  'pad a string to hold the format
   dwLocaleHex = Space$(32)
   
  'copy the string pointed to by the return value
   CopyMemory ByVal dwLocaleHex, lpLocaleString, ByVal Len(dwLocaleHex)
   
   dwLocaleHex = Right$(StripNull(dwLocaleHex), 4)
   dwLocaleDec = CLng("&H" & dwLocaleHex)
   'sLocaleName = pfGLI(dwLocaleDec, LOCALE_SLANGUAGE)
   'sLocaleAbbrev = pfGLI(dwLocaleDec, LOCALE_SABBREVLANGNAME)
   LocaleCount = LocaleCount + 1
   theCtrl.fReturnLocale dwLocaleDec
   'frmEnumLCID.List1.AddItem "   " & dwLocaleHex & vbTab & _
                               dwLocaleDec & vbTab & _
                               sLocaleAbbrev & vbTab & _
                               sLocaleName
   
  'and return 1 to continue enumeration
   EnumSystemLocalesProc = 1
   
End Function

Public Property Let theCtrl(ByVal nCtrl As clsEnumLCID)
   m_lObj = ObjPtr(nCtrl)
End Property

Public Property Get theCtrl() As clsEnumLCID
   Dim ct As clsEnumLCID
   If (m_lObj <> 0) Then
      CopyMemory ct, m_lObj, 4
      Set theCtrl = ct
      CopyMemory ct, 0&, 4
   End If
End Property

Public Function pfGLI(ByVal m_LocaleLCID As Long, ByVal reqInfo As Long) As String
   If IsNT Then
      GetLocaleInfoW m_LocaleLCID, reqInfo, Buffer, 255
      pfGLI = StripNull(StrConv(Buffer, vbFromUnicode))
   Else
      GetLocaleInfoA m_LocaleLCID, reqInfo, Buffer, 255
      pfGLI = StripNull(Buffer)
   End If
End Function

Public Function IsNT() As Boolean
   Dim udtVer           As OSVERSIONINFO

   On Error Resume Next
   udtVer.dwOSVersionInfoSize = Len(udtVer)
   If GetVersionEx(udtVer) Then
      If udtVer.dwPlatformId = VER_PLATFORM_WIN32_NT Then
         IsNT = True
      End If
   End If
End Function

Public Function StripNull(ByVal StrIn As String) As String
   Dim nul              As Long
   nul = InStr(StrIn, vbNullChar)
   Select Case nul
      Case Is > 1
         StripNull = Left$(StrIn, nul - 1)
      Case 1
         StripNull = ""
      Case 0
         StripNull = Trim$(StrIn)
   End Select
End Function


Public Function pfMAKELCID(PLang As Long, SLang As Long) As Long
   Dim tX               As Long
   tX = SLang * 2 ^ 10
   tX = tX Or PLang
   pfMAKELCID = tX
End Function

Public Function pfPrimaryLang(ByVal LCID As Long) As Long
   pfPrimaryLang = LCID Mod 1024
End Function

Public Function pfSecondaryLang(ByVal LCID As Long) As Long
   pfSecondaryLang = LCID \ 2 ^ 10
End Function

'Class code (clsEnumLCID)
Option Explicit

Public Event EnumLocales(ByVal LCID As Long)

Public Sub EnumInstalledLocales()
   EnumSystemLocales AddressOf EnumSystemLocalesProc, LCID_INSTALLED
End Sub

Public Sub EnumSupportedLocales()
   EnumSystemLocales AddressOf EnumSystemLocalesProc, LCID_SUPPORTED
End Sub

Public Function fReturnLocale(ByVal LCID As Long)
   RaiseEvent EnumLocales(LCID)
End Function

Private Sub Class_Initialize()
   theCtrl = Me
End Sub