Have Text Fade in/out

<xml>
  <textItem>
    <value>Text/Caption Goes Here</value>
    <timing>1000</timing>
  <textItem>
  ..
  ..
</xml>

Select allOpen in new window

package{
	import caurina.transitions.Tweener;
	
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.net.URLVariables;
	import flash.text.Font;
	import flash.text.TextField;
	import flash.text.TextFormat;
 
	public class SlideShowText extends Sprite{
		private var images:XMLList;
		private var texts:XMLList;
		private var delay:Number = 0;
		private var currentIndex:int = 0;
		private var loader:Loader;
		private var text:TextField;
		private var xml:XML;
		private var uloader:URLLoader;
				
		[Embed(mimeType='application/x-font', source="arial.ttf", fontName="MyArial")]
		private var uiArial:Class;
		
		public function SlideShowText(){
			uloader = new URLLoader();
			uloader.addEventListener(Event.COMPLETE,onComplete);
			uloader.load(new URLRequest("images.xml"));
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE,imageComplete);
			loader.addEventListener(IOErrorEvent.IO_ERROR,onError);
			loader.alpha = 0;
			loader.y = 15;
			text = new TextField();
			text.autoSize = "left";
			trace(Font.enumerateFonts()[0].fontName);
			var tf:TextFormat = new TextFormat("MyArial");
			text.alpha = 0;
			text.defaultTextFormat = tf;
			text.embedFonts = true;
			addChild(loader);
			addChild(text);
		}
		
		private function onComplete(e:Event):void{
			xml = new XML(uloader.data as String);
			images = xml..image;
			texts = xml..text;
			delay = Number(xml.@delay);
			initSlideShow();
		}
		private function onError(e:IOErrorEvent):void{
			trace(e.text);
		}
		private function initSlideShow():void{
			//First step - load first image and fade
			loadImage(currentIndex);
		}
		private function loadImage(index:int):void{
			var url:String = images[index].toString();
			loader.load(new URLRequest(url));
		}
		public function imageComplete(e:Event):void{
			text.text = texts[currentIndex];
			imageIn();
		}
		public function imageIn():void{
			Tweener.addTween(loader,{alpha:1.0,time:1,onComplete:textIn});
		}
		public function textIn():void{
			Tweener.addTween(text,{alpha:1.0,time:1,onComplete:textOut});
		}
		public function textOut():void{
			Tweener.addTween(text,{alpha:0.0,time:1,delay:3,onComplete:imageOut});
		}	
		public function imageOut():void{
			Tweener.addTween(loader,{alpha:0.0,time:1,onComplete:nextImage});
		}
		public function nextImage():void{
			currentIndex++;
			if(currentIndex >= images.length())currentIndex = 0;
			loadImage(currentIndex);
		}
		
		
	}
}

Select allOpen in new window

<?xml version="1.0" encoding="utf-8" ?>
<gallery delay="3000">
	<item>
		<image>images/km8030.jpg</image>
		<text>text 1</text>
	</item>
	<item>
		<image>images/bh750.jpg</image>
		<text>text 2</text>
	</item>
	<item>
		<image>images/km5050.jpg</image>
		<text>text 3</text>
	</item>
	<item>
		<image>images/bh650.jpg</image>
		<text>text 4</text>
	</item>
</gallery>

Select allOpen in new window