How do I uninstall eTrust on all cleints without maunually visiting each machine?

We are looking at doing this for about 400 machines.  This is my 3rd week on the job and do not quit understand all the jargon. I will relay any helpful comments to my boss...Just told him your response, He said "Thats what i was thinking of", now we just have to find out how to do that.
Thank you for your quick attention
gregg

Below is a batch file I use to deploy my hardware inventory scripts to multiple machines. The concept is basically the same as what you were looking to do, roll out a scheduled task where the command to run is sitting on a server somewhere. The primary utility I used for doing this is jt.exe.
http://windowsitpro.com/article/articleid/73941/jsi-tip-2621-microsoft-task-scheduler-command-line-utility.html

This script takes a text file with a list of systems (systems.txt in this case) and creates the task on each machine listed. The task is set to run as a domain account that also has local admin rights on each PC (this would be required for what you want as well). Several log files are written based on the results from each PC:

Off.txt - List of systems that were not reachable
Exists.txt - Systems that already had the task
Log.txt - Detailed log of the task creation for each system
Error.txt - List of systems that had an error (non-zero errorlevel returned on jt.exe)
Done.txt - List of systems completed successfully (0 errorlevel returned)

If you use this script you'll obviously need to modify it for your needs. The job creation line also sets the task to run at startup in addition to the time specified, so you probably wouldn't want that.

@echo off
rem Set configuration options here:
rem UNC path to Inventory.bat (with the backslash on the end)
set varPath=\\Server\Inventory\

rem User that the scan will run under (Don't use quotes on user names with spaces)
set varUser=DOMAIN\LocalAdminUser

rem Password for above account
set varPassword=password

rem Time the task will run at (24-hour clock, task will also run at startup)
set varTime=12:30


for /f %%a in (Systems.txt) do call :doit %%a
echo Done!
pause
goto :eof

:doit
set varError=No

echo %1 - %date% %time%
echo %1>>Log.txt
echo %date% %time%>>Log.txt
echo.>>Log.txt


ping -n 2 %1|find "TTL"
if not %errorlevel%==0 (
      echo %1>>Off.txt
      echo System is unreachable and most likely off.>>Log.txt
      goto :end
)

net view \\%1 1>nul 2>&1
if not %errorlevel%==0 (
      echo %1>>Off.txt
      echo System is unreachable and most likely off.>>Log.txt
      goto :end
)


if exist "\\%1\admin$\Tasks\Hardware Inventory.job" (
      echo %1>>Exists.txt
      echo Already done.>>Log.txt
      goto :end
)


jt /sm \\%1 /snj "Hardware Inventory.job" /sj ApplicationName="%varPath%\Inventory.bat" WorkingDirectory="%varPath%" MaxRunTime=3600000 /ctj Disabled=0 StartTime=%varTime% StartDate=11/25/2003 type=DAILY typearguments=1 /ctj Type=ATSTARTUP Disabled=0 /sc "%varUser%" %varPassword% /svj>>Log.txt 2>>&1
if not %errorlevel%==0 set varError=Yes
echo.>>Log.txt


if "%varError%"=="Yes" (
      echo %1>>Error.txt
) else (
      echo %1>>Done.txt
)


:end
echo *******************************************************>>Log.txt




This should help you set the groundwork for what you want to do

Thanks,

AllKnowing1

And of course, using GPO's is the best way to do it.

Thank You very much for the detailed answer. Unfortunatly I have to go to school so I can not test this until tomorrow. At that time I will be sure to let you know if it worked.
Again Thanks again for you time
-gregg

Did the said solution work?