Dynamic text into text field

-- THIS IS A PARENT SCRIPT --
 
property objXML, boolValid
property arrNews -- array to hold news item text
property pTimeout -- timeout object to swap news items every 10 seconds
property iNumberNewsItems -- number of news items found
property iCount -- count of which news item we are currently on
 
on new me, strXMLFilePath, objTarg
  boolValid = false
  arrNews = []
  pTimeout = void
  iCount = 0
  objXML = newObject ("XML")
  objXML.ignoreWhite = true
  setCallback (objXML, "onLoad", #XMLLoadComplete, me)
  objXML.load (strXMLFilePath)
  return me
end
 
on dispose me
  if ilk(pTimeout) = #timeout then
    pTimeout.forget()
    pTimeout = void
  end if
end
 
on XMLLoadComplete me
  boolValid = not voidP (objXML.xmlDecl)
  me.mXMLCompleted ()
end
 
on mXMLCompleted me
  if boolValid then
    -- loop through xml object looking for 'item' nodes
    repeat with node = 0 to objXML.firstChild.childNodes.length -1
      if objXML.firstChild.childNodes[node].nodeName = "item" then
        -- loop through 'item' node looking for 'description' nodes
        repeat with subNode = 0 to objXML.firstChild.childNodes[node].childNodes.length -1
          if objXML.firstChild.childNodes[node].childNodes[subNode].nodeName = "description" then
            -- add 'description' text to our array
            arrNews.add(objXML.firstChild.childNodes[node].childNodes[subNode].firstChild.toString())
          end if
        end repeat        
      end if
    end repeat
    iNumberNewsItems = arrNews.count
    -- if we have news...
    if iNumberNewsItems > 0 then
      -- display the first news item
      iCount = iCount + 1
      sprite("newsText").member.text = arrNews[iCount]
      -- set up the timeout object to display the news        
      pTimeout = timeout().new("swapNews", 10000, #swapNews, me)
    end if
  end if
end
 
on swapNews(me)
  iCount = iCount + 1
  if iCount > iNumberNewsItems then
    iCount = 1
  end if  
  sprite("newsText").member.text = arrNews[iCount]
end