XSL: Date/Month format display and sorting

Here is the first level of grouping
It uses muenchian grouping

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:myCompany="http://www.mycompany.com">
    <xsl:output omit-xml-declaration="yes"  media-type="text/xml" indent="yes"/>
    <xsl:key name="it-yr" match="item" use="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
    <xsl:template match="/rss">
        <xsl:for-each select="channel/item[generate-id() = generate-id(key('it-yr', substring-after(substring-after(myCompany:shortDate, '/'), '/'))[1])]">
            <xsl:sort select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
            <h1><xsl:value-of select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/></h1>
            <div class="date"><xsl:value-of select="myCompany:shortDate"/>
            </div>
            <div class="headline">
                <xsl:element name="a">
                    <xsl:attribute name="href">
                        <xsl:value-of select="link"/>
                    </xsl:attribute>
                    <xsl:attribute name="title">
                        <xsl:value-of select="description"/>
                    </xsl:attribute>
                    <xsl:if test="contains(substring(myCompany:shortDate,1,2), '/')">
                        M-There is a slash in the month
                    </xsl:if>
                   
                    <br /><xsl:if test="contains(substring(myCompany:shortDate,3,2), '/')">
                        D-There is a slash in the day
                    </xsl:if>
                </xsl:element>
            </div>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Here is the full grouping

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:myCompany="http://www.mycompany.com">
    <xsl:output omit-xml-declaration="yes"  media-type="text/xml" indent="yes"/>
    <xsl:key name="it-yr" match="item" use="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
    <xsl:key name="it-mm" match="item" use="substring-before(myCompany:shortDate, '/')"/>
    <xsl:template match="/rss">
        <xsl:for-each select="channel/item[generate-id() = generate-id(key('it-yr', substring-after(substring-after(myCompany:shortDate, '/'), '/'))[1])]">
            <xsl:sort select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
            <xsl:variable name="yr"><xsl:value-of select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/></xsl:variable>
            <h1><xsl:value-of select="$yr"/></h1>
           
            <xsl:for-each select="key('it-yr', $yr)[generate-id() = generate-id(key('it-mm', substring-before(myCompany:shortDate, '/') )[substring-after(substring-after(myCompany:shortDate, '/'), '/') = $yr][1])]">
                <xsl:sort select="substring-before(myCompany:shortDate, '/')" data-type="number"/>
                <xsl:variable name="mm" select="substring-before(myCompany:shortDate, '/')"></xsl:variable>
                <h2><xsl:value-of select="$mm"/></h2>
                <xsl:for-each select="key('it-yr', $yr)[substring-before(myCompany:shortDate, '/') = $mm]">
                    <xsl:sort select="substring-before(substring-after(myCompany:shortDate, '/'), '/')"/>
                <div class="date">
                    <xsl:value-of select="myCompany:shortDate"/>
                </div>
                <div class="headline">
                    <xsl:element name="a">
                        <xsl:attribute name="href">
                            <xsl:value-of select="link"/>
                        </xsl:attribute>
                        <xsl:attribute name="title">
                            <xsl:value-of select="description"/>
                        </xsl:attribute>
                        <xsl:value-of select="link"/>
                    </xsl:element>
                </div>
                    </xsl:for-each>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

This seems complex at first, since you have to deal with these substring chains for getting the correct part from the datestring
furthermore you have nested muenchian
muenchian is explained very well here

http://www.jenitennison.com/xslt/grouping/muenchian.html

good luck

Geert

note that you will have to bend the stylesheet to your HTML wishes
add the hr, and put thedates in title fields as pleased

FANTASTIC! This is perfect!

1 more question.

How can the month be displayed based on the numeric value:

For example:

4 = April
10 = October

April

4/6/1999     http://www.mycompany.com/topics/releases/200

2006

October

10/20/2006  http://www.mycompany.com/topics/releases/2007102502.p

That is most easily done using a lookup table
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:myCompany="http://www.mycompany.com"
    xmlns:map="internal" exclude-result-prefixes="map">
    <xsl:output omit-xml-declaration="yes"  media-type="text/xml" indent="yes"/>
    <xsl:key name="it-yr" match="item" use="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
    <xsl:key name="it-mm" match="item" use="substring-before(myCompany:shortDate, '/')"/>
    <xsl:template match="/rss">
        <xsl:for-each select="channel/item[generate-id() = generate-id(key('it-yr', substring-after(substring-after(myCompany:shortDate, '/'), '/'))[1])]">
            <xsl:sort select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
            <xsl:variable name="yr"><xsl:value-of select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/></xsl:variable>
            <h1><xsl:value-of select="$yr"/></h1>
           
            <xsl:for-each select="key('it-yr', $yr)[generate-id() = generate-id(key('it-mm', substring-before(myCompany:shortDate, '/') )[substring-after(substring-after(myCompany:shortDate, '/'), '/') = $yr][1])]">
                <xsl:sort select="substring-before(myCompany:shortDate, '/')" data-type="number"/>
                <xsl:variable name="mm" select="substring-before(myCompany:shortDate, '/')"></xsl:variable>
                <h2><xsl:value-of select="document('')//map:month[@no = $mm]/@name"/></h2>
                <xsl:for-each select="key('it-yr', $yr)[substring-before(myCompany:shortDate, '/') = $mm]">
                    <xsl:sort select="substring-before(substring-after(myCompany:shortDate, '/'), '/')"/>
                <div class="date">
                    <xsl:value-of select="myCompany:shortDate"/>
                </div>
                <div class="headline">
                    <xsl:element name="a">
                        <xsl:attribute name="href">
                            <xsl:value-of select="link"/>
                        </xsl:attribute>
                        <xsl:attribute name="title">
                            <xsl:value-of select="description"/>
                        </xsl:attribute>
                        <xsl:value-of select="link"/>
                    </xsl:element>
                </div>
                    </xsl:for-each>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
   
    <map:months>
        <map:month no="1" name="January"/>
        <map:month no="2" name="February"/>
        <map:month no="3" name="March"/>
        <map:month no="4" name="April"/>
        <map:month no="5" name="May"/>
        <map:month no="6" name="June"/>
        <map:month no="7" name="July"/>
        <map:month no="8" name="August"/>
        <map:month no="9" name="September"/>
        <map:month no="10" name="October"/>
        <map:month no="11" name="November"/>
        <map:month no="12" name="December"/>
    </map:months>
</xsl:stylesheet>

document('') points to the stylesheet itself
and there you have a lookup table in the map namespace

just make sure that yourprocessor has document('') active,
most of them do but some require explicit ctivation

Oh ok, That looks good, but I did this and it worked fine too (see snippet).

What do you think?

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:myCompany="http://www.mycompany.com">
    <xsl:output omit-xml-declaration="yes"  media-type="text/xml" indent="yes"/>
    <xsl:key name="it-yr" match="item" use="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
    <xsl:key name="it-mm" match="item" use="substring-before(myCompany:shortDate, '/')"/>
    <xsl:template match="/rss">
        <xsl:for-each select="channel/item[generate-id() = generate-id(key('it-yr', substring-after(substring-after(myCompany:shortDate, '/'), '/'))[1])]">
            <xsl:sort select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/>
            <xsl:variable name="yr"><xsl:value-of select="substring-after(substring-after(myCompany:shortDate, '/'), '/')"/></xsl:variable>
            <h2><xsl:value-of select="$yr"/></h2>
           <hr />
            <xsl:for-each select="key('it-yr', $yr)[generate-id() = generate-id(key('it-mm', substring-before(myCompany:shortDate, '/') )[substring-after(substring-after(myCompany:shortDate, '/'), '/') = $yr][1])]">
                <xsl:sort select="substring-before(myCompany:shortDate, '/')" data-type="number"/>
                <xsl:variable name="mm" select="substring-before(myCompany:shortDate, '/')"></xsl:variable>
                <h4>
<!-- Added this -->
		    <xsl:choose>
		    	<xsl:when test="$mm = '1'">January</xsl:when>
			<xsl:when test="$mm = '2'">February</xsl:when>
			<xsl:when test="$mm = '3'">March</xsl:when>
			<xsl:when test="$mm = '4'">April</xsl:when>
			<xsl:when test="$mm = '5'">May</xsl:when>
			<xsl:when test="$mm = '6'">June</xsl:when>
			<xsl:when test="$mm = '7'">July</xsl:when>
			<xsl:when test="$mm = '8'">August</xsl:when>
			<xsl:when test="$mm = '9'">September</xsl:when>
			<xsl:when test="$mm = '10'">October</xsl:when>
			<xsl:when test="$mm = '11'">November</xsl:when>
			<xsl:when test="$mm = '12'">December</xsl:when>
		    </xsl:choose>
<!-- End here -->
		</h4>
                <xsl:for-each select="key('it-yr', $yr)[substring-before(myCompany:shortDate, '/') = $mm]">
                    <xsl:sort select="substring-before(substring-after(myCompany:shortDate, '/'), '/')"/>
                <div class="date">
                    <xsl:value-of select="myCompany:shortDate"/>
                </div>
                <div class="headline">
                    <xsl:element name="a">
                        <xsl:attribute name="href">
                            <xsl:value-of select="link"/>
                        </xsl:attribute>
                        <xsl:attribute name="title">
                            <xsl:value-of select="description"/>
                        </xsl:attribute>
                        <xsl:value-of select="link"/>
                    </xsl:element>
                </div>
                    </xsl:for-each>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

                                              

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:

That will also work fine
The lookup is nicer, since you pull the lookup table outside the code
and it is a bit more XPath like, less procedural
but I would not worry about style at this point in time

Hi Gertrone,

One last question.

Is there a way to only display a specific year but in the same format?

For Example, only display all links for 2006?

Hi Gertrone,

Thanks for your help thus far.

Is there a way to display the description instead of the URL in the results?

For Example:

THIS
<description>My Company announced that its board of directors increased its size from 10 to 12 members with the election today of Frick and Frack.</description>

INSTEAD OF THIS
<guid>http://www.mycompany.com/topics/releases/2007102502.php</guid>

Thanks.

Never mind,

I just changed this:

</xsl:attribute>
                        <xsl:value-of select="link"/>
                    </xsl:element>

to this:

</xsl:attribute>
                        <xsl:value-of select="description"/>
                    </xsl:element>

Hi Gertone:

Sorry for the delay.

How could I feed the year into the stylesheet as a parameter?
Would it need to be fed in through another stylesheet or could I feed it in through another scripting language like php or asp?

Thanks.

since the parameter is global in the stylesheet
  <xsl:param name="global-year">2007</xsl:param>
you can pass a value in from outside

this happens when you call the processor to execute this stylesheet on an XML document.
It all depends on how you do that...
it could be PHP or ASP, JSP, Java
it could as well be from the commandline, or javascript in a browser

tell me how you run the stylesheet now, and I can help you with the next step

cheers

Geert

Hi Gertrone,

Thanks for all of your assistance so far.

Basically the XSL is being run through an ASP page.

There is an include file that transforms the xsl (see below)

set xml = Server.CreateObject("Microsoft.XMLDOM")
xml.async = false
xml.load(Server.MapPath("myXML.xml"))

set MyFILE = Server.CreateObject("Microsoft.XMLDOM")
MyFILE.async = false
MyFILE.load(Server.MapPath(myXSL))


Response.Write(xml.transformNode(MyFILE))

and then the page that actually displays the XSL output is just a variable that prints the XSL (see below)

<%myXSL = "DisplayNews.xsl"%>

So if you know of a way to pass the parameter in, then that would be helpful!

Thanks.

Hi Gertrone,

Do you have any suggestions related to my last post on how to pass the year in as a parameter?

Thanks for your help thus far!  :)

The object you are using is outdated, you should use msxml4 or msxml6 (recommended) instead of msxml3 in "old" mode
I copied from one of my files, so the variable names are different

Set oXML = Server.CreateObject("MSXML2.DOMDocument.6.0")
Set oXSL = Server.CreateObject("Msxml2.FreeThreadedDOMDocument.6.0")

(you could use 4.0, or 3.0, but I don't recommend the 3.0, make sure you got the latest msxml installed)

Since you need a Template processor for passing parameters, you need the XSLT to be free threaded
You also need to declare a template processor

Set oTmpl= Server.CreateObject("Msxml2.XSLTemplate.6.0")

Then you can pass the parameter

oTmpl.stylesheet = oXSL
Set oProc= oTmpl.createProcessor()
oProc.input = oXML
oProc.addParameter "global-year","2007"
oProc.output = Response
oProc.transform()

Hope this helps

Geert

Hi Gertone,

I am able to load the XML using the new parser (version 6) but when i try to use this code to display the xsl:

Set oXSL = Server.CreateObject("Msxml2.FreeThreadedDOMDocument.6.0")
Set oTmpl= Server.CreateObject("Msxml2.XSLTemplate.6.0")
oTmpl.stylesheet = oXSL
Set oProc= oTmpl.createProcessor()
oProc.input = oXML
oProc.addParameter "global-year","2007"
oProc.output = Response
oProc.transform()

I get this error:

msxml6.dll error '80004005'

The stylesheet does not contain a document element. The stylesheet may be empty, or it may not be a well-formed XML document.

it is on this line:

oTmpl.stylesheet = oXSL

If I try to load the XSL file like below

oXSL.load(Server.MapPath(strXSL))
oTmpl.stylesheet = oXSL

Then a bunch of weird characters are displayed like this:

ÿþ<ýhý2ý ýxýmýlýnýsý:ýfýoý=ý"ýhýtýtýpý:ý/ý/ýwýwýwý.ýwý

any ideas on this?

Hi Gertrone,

Thanks so much for your time and patience. You were very helpful.

Gertrone was very helpful.