Go Premium for a chance to win a PS4. Enter to Win

x
?
Solved

strtok function

Posted on 1998-07-09
8
Medium Priority
?
1,072 Views
Last Modified: 2010-05-18
I would like a function to do the same as the strtok function under C.  It should take a variable number of tokens (characters, could all be in one string just like strtok) to tokenize on.   Each token should be a string.

eg:

' Tokenize based on command ',' and space ' '
strtok("Have      a  nice,     day", " ,")

This should break the above string into :
"Have"
"a"
"nice"
"day"

Thanks for any help
Guava
0
Comment
Question by:guava070998
  • 3
  • 3
  • 2
8 Comments
 
LVL 6

Accepted Solution

by:
anthonyc earned 160 total points
ID: 1465345
'************************************************************
'Date:    06/08/1998
'Author:  Anthony Cornetto
'Input:
'  strResult()<String>:  Array where results are returned
'  strWorking<String>:   String to parse
'  strDelimiter<String>: Delimiter
'Output:
'  <None>
'Purpose: Goes through string, separating it by the delimiter, and
'         Returning the elements in an array.
'************************************************************
Public Sub SeparateString(strResult() As String, strWorking As String, strDelimiter As String)
    'The separated strings are placed into an array.
   
    Dim lngLastLoc As Long
    Dim lngDelimLoc As Long
    Dim lngFieldCount As Long
    Dim intI As Integer
   
    'clean out string
    ReDim strResult(0 To 0) As String
   
    If strWorking <> "" Then
        'initialize last location to 0
        lngLastLoc = 1
        lngFieldCount = 0
        lngDelimLoc = InStr(lngLastLoc, strWorking, strDelimiter)
       
        'Continue until no more delimiters are found
        Do Until lngDelimLoc = 0
            'Set array size
            If lngFieldCount > 0 Then
                ReDim Preserve strResult(0 To lngFieldCount) As String
            End If
           
            'Set string and locations to find next delim
            strResult(lngFieldCount) = Mid$(strWorking, lngLastLoc, lngDelimLoc - lngLastLoc)
            lngLastLoc = lngDelimLoc + Len(strDelimiter)
            lngDelimLoc = InStr(lngLastLoc, strWorking, strDelimiter)
            lngFieldCount = lngFieldCount + 1
        Loop
       
        'add last field (after delim)
        If lngFieldCount > 0 Then
            ReDim Preserve strResult(0 To lngFieldCount) As String
        End If
        strResult(lngFieldCount) = Mid$(strWorking, lngLastLoc)
    End If
End Sub

0
 
LVL 4

Expert Comment

by:tomook
ID: 1465346
anthonyc, that really does not mimic strtok. Here is one that does, including using static variables.

' Tokenize a string like 'strtok' in C std lib
' Does not modify source string like strtok.
Function StrTok(Seps As String, Optional SourceString As Variant) As String
    Static LocalString As String
    Static LocalCounter As Long     ' Substitutes for pointer into string
    Dim lCnt1 As Long

    If Not (IsMissing(SourceString)) Then
        LocalString = SourceString
        LocalCounter = 1    ' Must start at first char.
    End If
   
    ' If we start on a separator, skip all seps found.
    While (LocalCounter <= Len(LocalString)) And (InStr(Seps, Mid$(LocalString, LocalCounter, 1))) <> 0
        LocalCounter = LocalCounter + 1
    Wend
   
    '
    lCnt1 = LocalCounter
   
    ' Count until separators found.
    While (lCnt1 <= Len(LocalString)) And (InStr(Seps, Mid$(LocalString, lCnt1, 1)) = 0)
        lCnt1 = lCnt1 + 1
    Wend
       
    StrTok = Mid$(LocalString, LocalCounter, lCnt1 - LocalCounter)
   
    ' LocalCounter must point to next char to examine
    LocalCounter = lCnt1 + 1
End Function

0
 
LVL 6

Expert Comment

by:anthonyc
ID: 1465347
Yeah, you are right.. It's an enhanced version.  You get all of the tokens returned in 1 pass, in 1 array.
0
Concerto's Cloud Advisory Services

Want to avoid the missteps to gaining all the benefits of the cloud? Learn more about the different assessment options from our Cloud Advisory team.

 
LVL 4

Expert Comment

by:tomook
ID: 1465348
Yeah, I noticed that. I guess it depends on what you are looking for. In writing VB parsers, I usually need to change the separators so I use the version I posted.
0
 

Author Comment

by:guava070998
ID: 1465349
Hi, thanks for the quick replies.  I will try this out as soon as possible and get back to you both on if either suits what I happen to need.

Thanks again,
guava
0
 

Author Comment

by:guava070998
ID: 1465350
Hi, I tried both, both work, and I like both....so, what do we do about the points here?  Technically the second example mimics strtok more, which I asked for...but the first code actually require me to do a wee less work....

How would you both feel about getting this question archived, my points returned, and I ask two 40 point questions, one for each of you, just to pick up the points? (ie: you would just have to offically answer the question, now actual work involved since you answered this one).

Does that sound good, or should I just decide which code does my job better and answer?

guava
0
 
LVL 6

Expert Comment

by:anthonyc
ID: 1465351
guava,

Anything is fine with me
0
 
LVL 4

Expert Comment

by:tomook
ID: 1465352
I am easy.
0

Featured Post

Free Tool: SSL Checker

Scans your site and returns information about your SSL implementation and certificate. Helpful for debugging and validating your SSL configuration.

One of a set of tools we are providing to everyone as a way of saying thank you for being a part of the community.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

When designing a form there are several BorderStyles to choose from, all of which can be classified as either 'Fixed' or 'Sizable' and I'd guess that 'Fixed Single' or one of the other fixed types is the most popular choice. I assume it's the most p…
This article describes how to use a set of graphical playing cards to create a Draw Poker game in Excel or VB6.
Get people started with the utilization of class modules. Class modules can be a powerful tool in Microsoft Access. They allow you to create self-contained objects that encapsulate functionality. They can easily hide the complexity of a process from…
This lesson covers basic error handling code in Microsoft Excel using VBA. This is the first lesson in a 3-part series that uses code to loop through an Excel spreadsheet in VBA and then fix errors, taking advantage of error handling code. This l…
Suggested Courses

824 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question