Want to win a PS4? Go Premium and enter to win our High-Tech Treats giveaway. Enter to Win

x
?
Solved

ERROR CODES

Posted on 1998-10-28
4
Medium Priority
?
177 Views
Last Modified: 2010-04-30
Does anybody know where I can look up API error codes?
I am mostly interested in the ones dealing with
sockets and drive mapping.
0
Comment
Question by:cybergirl
[X]
Welcome to Experts Exchange

Add your voice to the tech community where 5M+ people just like you are talking about what matters.

  • Help others & share knowledge
  • Earn cash & points
  • Learn & ask questions
4 Comments
 
LVL 1

Expert Comment

by:ajmendes
ID: 1442157
Hi,
I have a text file that have an plenty of error codes.
If you want it, tell me your e-mail to send it to you. If you find what you want then i post this comment as an answer, OK?

Bye.
0
 
LVL 6

Expert Comment

by:clifABB
ID: 1442158
Here is a list of error codes at the Microsoft site:
http://premium.microsoft.com/msdn/library/sdkdoc/errlist_9rqr.htm

I've been having a bit of trouble getting in, so I'll post this as a comment.  If you get in and it's what you want, let me know and I'll repost as an answer.
0
 
LVL 14

Accepted Solution

by:
waty earned 200 total points
ID: 1442159
Here is the part of a new addins I am writing. It will display the API error message for any API error number
' #VBIDEUtils#************************************************************
' * Programmer Name  : Waty Thierry
' * Web Site         : www.geocities.com/ResearchTriangle/6311/
' * E-Mail           : waty.thierry@usa.net
' * Date             : 12/10/1998
' * Time             : 20:20
' * Module Name      : APIError_Module
' * Module Filename  : APIError.bas
' **********************************************************************
' * Comments         :
' * Used to get error messages directly from the
' *   system instead of hard-coding them
' *
' *
' **********************************************************************

Option Explicit

Private Const FORMAT_MESSAGE_FROM_SYSTEM = &H1000
Private Const FORMAT_MESSAGE_IGNORE_INSERTS = &H200

Private Declare Function FormatMessage Lib "kernel32" Alias _
      "FormatMessageA" _
      (ByVal dwFlags As Long, lpSource As Any, _
      ByVal dwMessageId As Long, _
      ByVal dwLanguageId As Long, _
      ByVal lpBuffer As String, _
      ByVal nSize As Long, _
      Arguments As Long) As Long

' *** Status Codes
Public Const INVALID_HANDLE_VALUE = -1&
Public Const ERROR_SUCCESS = 0&

Public Function ReturnAPIError(ErrorCode As Long) As String
   ' #VBIDEUtils#************************************************************
   ' * Programmer Name  : Waty Thierry
   ' * Web Site         : www.geocities.com/ResearchTriangle/6311/
   ' * E-Mail           : waty.thierry@usa.net
   ' * Date             : 12/10/1998
   ' * Time             : 20:21
   ' * Module Name      : APIError_Module
   ' * Module Filename  : APIError.bas
   ' * Procedure Name   : ReturnAPIError
   ' * Parameters       :
   ' *                    ErrorCode As Long
   ' **********************************************************************
   ' * Comments         :
   ' * Takes an API error number, and returns
   ' * a descriptive text string of the error
   ' *
   ' **********************************************************************

   Dim sBuffer    As String

   ' *** Allocate the string, then get the system to
   ' *** tell us the error message associated with
   ' *** this error number
   
   sBuffer = String(256, 0)
   FormatMessage FORMAT_MESSAGE_FROM_SYSTEM Or FORMAT_MESSAGE_IGNORE_INSERTS, 0&, ErrorCode, 0&, sBuffer, Len(sBuffer), 0&

   ' *** Strip the last null, then the last CrLf pair if it exists
   
   sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
   If Right$(sBuffer, 2) = Chr$(13) & Chr$(10) Then
      sBuffer = Mid$(sBuffer, 1, Len(sBuffer) - 2)
   End If

   ReturnAPIError = sBuffer

End Function

Public Sub APIError()
   ' #VBIDEUtils#************************************************************
   ' * Programmer Name  : Waty Thierry
   ' * Web Site         : www.geocities.com/ResearchTriangle/6311/
   ' * E-Mail           : waty.thierry@usa.net
   ' * Date             : 12/10/1998
   ' * Time             : 20:35
   ' * Module Name      : APIError_Module
   ' * Module Filename  : APIError.bas
   ' * Procedure Name   : APIError
   ' * Parameters       :
   ' **********************************************************************
   ' * Comments         :
   ' * Takes an API error number, and returns
   ' * a descriptive text string of the error
   ' *
   ' **********************************************************************

   Dim sError        As String
   
   On Error GoTo ERROR_APIError
   
   sError = InputBox("Enter the error number", "Returns API error")
   
   If IsNumeric(sError) = False Then Exit Sub
   
   MsgBox ReturnAPIError(CLng(sError)), vbInformation + vbOKOnly, "Error n°" & sError
   
   Exit Sub
   
ERROR_APIError:
   MsgBox "Error n°" & sError & vbCrLf & " Invalid error number" & vbCrLf & "You have to give another one", vbCritical + vbOKOnly, "Error n°" & sError
   
End Sub

0
 

Author Comment

by:cybergirl
ID: 1442160
Thanks for the code waty, it worked great.
0

Featured Post

Free Tool: Subnet Calculator

The subnet calculator helps you design networks by taking an IP address and network mask and returning information such as network, broadcast address, and host range.

One of a set of tools we're offering as a way of saying thank you for being a part of the community.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Enums (shorthand for ‘enumerations’) are not often used by programmers but they can be quite valuable when they are.  What are they? An Enum is just a type of variable like a string or an Integer, but in this case one that you create that contains…
This article describes how to use a set of graphical playing cards to create a Draw Poker game in Excel or VB6.
Get people started with the process of using Access VBA to control Excel using automation, Microsoft Access can control other applications. An example is the ability to programmatically talk to Excel. Using automation, an Access application can laun…
This lesson covers basic error handling code in Microsoft Excel using VBA. This is the first lesson in a 3-part series that uses code to loop through an Excel spreadsheet in VBA and then fix errors, taking advantage of error handling code. This l…
Suggested Courses

604 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question