Where can find the Creator Codes ...?

Hi folks,

I've spent 30 mins to locate creator and document codes at the Apple's website but still cannot find them.

Let me know if you happen to know the url from which I can download.

Thanks for your help in advance.

Elpmet

LVL 1
elpmetAsked:
Who is Participating?

[Webinar] Streamline your web hosting managementRegister Today

x
 
weedConnect With a Mentor Commented:
There isnt a list of types/creators. You have to find them via the document or app theyre attached to. I will post an applescript that you can make (make it a running app that you can drop documents on) and it will tell you the creator and type of the file. There are also several programs at www.versiontracker.com that will let you view the codes. FileBuddy is one that comes to mind. Anyway heres the applescript.


-- dropping a file(s) on a script application
-- sends an open command along with a list
-- of aliases for the dragged file(s). This
-- handler executes upon the drop.
on open filelist
      -- work through each file dragged with repeat in list form
      repeat with oneFile in filelist
            -- info for command in file commands addition
            set allInfo to info for oneFile
            -- set Boolean
            set isFolder to allInfo's folder
            -- call subroutine to extract name of file or folder
            set fileName to nameFromPath of (oneFile as string) given isFolder:isFolder
            if fileName is not "" then
                  -- assemble and display appropriate messages
                  if isFolder then
                        display dialog "“" & fileName & ¬
                              "” is a folder." buttons {"Okeedokee"} default button 1
                  else
                        set details to return & "Creator: " & ¬
                              allInfo's file creator & return & ¬
                              "File Type: " & allInfo's file type
                        display dialog "Info for “" & fileName & "”:" & details ¬
                              buttons {"Cancel", "OK"} default button 2
                        tell application "Finder"
                              display dialog "Enter the new creator for this file:" buttons {"OK"} default button 1 default answer "SIT!"
                              set creator type of file oneFile to result's text returned
                              display dialog "Enter the new type for this file:" buttons {"OK"} default button 1 default answer "SITD"
                              set file type of file oneFile to result's text returned
                        end tell
                  end if
            end if
      end repeat
end open

-- subroutine to extract file or folder name
-- from a complete path name.  Uses isFolder
-- labeled parameter and variable as Boolean switch.
on nameFromPath of thePath given isFolder:isFolder
      if thePath = "" then return ""
      -- save current settings
      set oldDelims to AppleScript's text item delimiters
      -- we need colons to take apart the path
      set AppleScript's text item delimiters to ":"
      if isFolder then
            -- don't want the last colon
            set fileName to text item -2 of thePath
      else
            -- no colon text item to worry about
            set fileName to text item -1 of thePath
      end if
      -- restore prior settings
      set AppleScript's text item delimiters to oldDelims
      return fileName
end nameFromPath
0
All Courses

From novice to tech pro — start learning today.