Solved

Printing a VB6 Treeview

Posted on 2000-05-17
6
2,043 Views
Last Modified: 2010-02-26
I would like some pointers on how one might print the contents of a treeview control?

Better answer gets better points!!!
0
Comment
Question by:mmips
6 Comments
 
LVL 28

Accepted Solution

by:
AzraSound earned 100 total points
ID: 2818967
0
 
LVL 1

Author Comment

by:mmips
ID: 2819428
AzraSound,

That particular code snippet works if all you want is the data i.e. node text.. I would however like to print the treeview graphically...i.e. All of the file folders and the text as displayed....
0
 
LVL 28

Expert Comment

by:AzraSound
ID: 2819468
well you would have to ensure that the treeview was fully expanded.  then you would have to use some trickery to get it to print just the area you want.  see this MS article:

http://support.microsoft.com/support/kb/articles/Q85/9/78.ASP
0
Announcing the Most Valuable Experts of 2016

MVEs are more concerned with the satisfaction of those they help than with the considerable points they can earn. They are the types of people you feel privileged to call colleagues. Join us in honoring this amazing group of Experts.

 
LVL 70

Expert Comment

by:Éric Moreau
ID: 2823986
I have this code that I never tried!

Here is a new version that print treeview to a picturebox or to printer, graphicly with treelines and icons.

Put this code into a module

Option Explicit

Public Const INDENT_WIDTH = 300
Public Const ITEM_HEIGTH = 200

Private Const MAX_INDENT = 10
Private bBoudin(0 To MAX_INDENT) As Boolean

Public Sub PrintTreeview(ByRef tv As TreeView, prt As Object)
    Dim i As Integer
    Dim n As Node
     
    Debug.Assert (TypeOf prt Is PictureBox) Or (TypeOf prt Is Printer)
     
    Set n = tv.Nodes(1)
    Do
        PrintTreeviewNode tv, n, 0, prt
         
        Set n = n.Next
    Loop While Not (n Is Nothing)
     
End Sub

Private Sub PrintTreeviewNode(ByRef tv As TreeView, ByRef nd As Node, ByVal lvl As Integer, ByRef prt As Object)
    Dim i As Integer
    Dim n As Node
    Dim x0 As Single, y0 As Single
     
    x0 = 0
    y0 = prt.CurrentY
     
    'Print boudins
    For i = IIf(tv.LineStyle = tvwRootLines, 0, 1) To lvl - 1
        If bBoudin(i) Then
            prt.Line (x0 + INDENT_WIDTH \ 4, y0)-Step(0, ITEM_HEIGTH), vbBlack
        End If
        x0 = x0 + INDENT_WIDTH
    Next
     
    bBoudin(lvl) = Not (nd.Next Is Nothing)
     
    If tv.LineStyle = tvwRootLines Or lvl > 0 Then
        If nd.Next Is Nothing Then
            prt.Line (x0 + INDENT_WIDTH \ 4, y0)-Step(0, ITEM_HEIGTH \ 2), vbBlack
            prt.Line -Step(INDENT_WIDTH - INDENT_WIDTH \ 4, 0), vbBlack
        Else
            prt.Line (x0 + INDENT_WIDTH \ 4, y0)-Step(0, ITEM_HEIGTH), vbBlack
            prt.CurrentY = prt.CurrentY - ITEM_HEIGTH \ 2
            prt.Line -Step(INDENT_WIDTH - INDENT_WIDTH \ 4, 0), vbBlack
        End If
        x0 = x0 + INDENT_WIDTH
    End If
     
    If Not (tv.ImageList Is Nothing) _
        And (tv.Style And (tvwPictureText Or tvwPlusPictureText Or tvwTreelinesPictureText Or tvwTreelinesPlusMinusPictureText)) Then
        If Len(nd.Image) Then
            prt.PaintPicture tv.ImageList.ListImages.Item(nd.Image).Picture, x0, y0
        End If
        x0 = x0 + INDENT_WIDTH
    End If
     
    prt.CurrentX = x0
    prt.CurrentY = y0
    prt.Print nd.Text
     
    prt.CurrentY = y0 + ITEM_HEIGTH
     
    If nd.Children Then
        Set n = nd.Child
        Do
            PrintTreeviewNode tv, n, lvl + 1, prt
         
            Set n = n.Next
        Loop Until n Is Nothing
    End If
End Sub
0
 
LVL 1

Author Comment

by:mmips
ID: 2838317
I am splitting the points between the 2 answers...I ended up using pieces of both to accomplish what I wanted...Thanks to both of you...
0
 

Expert Comment

by:sydneyguy
ID: 26982773
Have opened up another question in relation to the above code if you have time

http://www.experts-exchange.com/Microsoft/Development/MS_Access/Q_25226584.html?fromWizard=true
0

Featured Post

Courses: Start Training Online With Pros, Today

Brush up on the basics or master the advanced techniques required to earn essential industry certifications, with Courses. Enroll in a course and start learning today. Training topics range from Android App Dev to the Xen Virtualization Platform.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Background What I'm presenting in this article is the result of 2 conditions in my work area: We have a SQL Server production environment but no development or test environment; andWe have an MS Access front end using tables in SQL Server but we a…
This article describes some techniques which will make your VBA or Visual Basic Classic code easier to understand and maintain, whether by you, your replacement, or another Experts-Exchange expert.
Show developers how to use a criteria form to limit the data that appears on an Access report. It is a common requirement that users can specify the criteria for a report at runtime. The easiest way to accomplish this is using a criteria form that a…
This lesson covers basic error handling code in Microsoft Excel using VBA. This is the first lesson in a 3-part series that uses code to loop through an Excel spreadsheet in VBA and then fix errors, taking advantage of error handling code. This l…

808 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question