Solved

List of IP addresses of computers connected with my computer....

Posted on 2003-12-06
5
214 Views
Last Modified: 2010-05-01
Hi guyz,

I m developing an application for net sending in VB.. I m using netsend dos command to achieve this...

What i want .. the list of all computers connected with the one on which application is installed..
i.e just like network neighbourhood...but i want IP addresses of those machines only...

I m able to get the domains available on the network using ADS reference...
but i want list of IP addresses of computers connected..

Could u pleaes help me..?

thanks,
Kamlesh A.

0
Comment
Question by:kamlesh_agrawal
  • 3
5 Comments
 
LVL 24

Expert Comment

by:R_Rajesh
ID: 9888095
Hi Kamlesh,

Try this:
(replace cvgroup with your workgroup or domain)

Set myobj = GetObject("WinNT://cvgroup")
myobj.Filter = Array("computer")
For Each co In myobj
MsgBox co.Name
Next


Rajesh
0
 
LVL 24

Accepted Solution

by:
R_Rajesh earned 150 total points
ID: 9888171
give this a try:


------------------------------------
Private Const WS_VERSION_REQD = &H101
Private Const WS_VERSION_MAJOR = WS_VERSION_REQD \ &H100 And &HFF&
Private Const WS_VERSION_MINOR = WS_VERSION_REQD And &HFF&
Private Const MIN_SOCKETS_REQD = 1
Private Const SOCKET_ERROR = -1
Private Const WSADescription_Len = 256
Private Const WSASYS_Status_Len = 128
Private Type HOSTENT
hName As Long
hAliases As Long
hAddrType As Integer
hLength As Integer
hAddrList As Long
End Type
Private Type WSADATA
wversion As Integer
wHighVersion As Integer
szDescription(0 To WSADescription_Len) As Byte
szSystemStatus(0 To WSASYS_Status_Len) As Byte
iMaxSockets As Integer
iMaxUdpDg As Integer
lpszVendorInfo As Long
End Type
Private Declare Function WSAGetLastError Lib "WSOCK32.DLL" () As Long
Private Declare Function WSAStartup Lib "WSOCK32.DLL" (ByVal wVersionRequired As Integer, lpWSAData As WSADATA) As Long
Private Declare Function WSACleanup Lib "WSOCK32.DLL" () As Long
Private Declare Function gethostname Lib "WSOCK32.DLL" (ByVal hostname$, ByVal HostLen As Long) As Long
Private Declare Function gethostbyname Lib "WSOCK32.DLL" (ByVal hostname$) As Long
Private Declare Sub RtlMoveMemory Lib "KERNEL32" (hpvDest As Any, ByVal hpvSource&, ByVal cbCopy&)

Function hibyte(ByVal wParam As Integer)
hibyte = wParam \ &H100 And &HFF&
End Function

Function lobyte(ByVal wParam As Integer)
lobyte = wParam And &HFF&
End Function

Private Function LocalHostName() As String
Dim hostname As String * 256
If gethostname(hostname, 256) = SOCKET_ERROR Then
LocalHostName = "<Error>"
Else
LocalHostName = Trim$(hostname)
End If
End Function

Private Sub InitializeSockets()
Dim WSAD As WSADATA
Dim iReturn As Integer
Dim sLowByte As String, sHighByte As String, sMsg As String
iReturn = WSAStartup(WS_VERSION_REQD, WSAD)
If iReturn <> 0 Then
MsgBox "Winsock.dll is not responding."
End
End If
If lobyte(WSAD.wversion) < WS_VERSION_MAJOR Or (lobyte(WSAD.wversion) = _
WS_VERSION_MAJOR And hibyte(WSAD.wversion) < WS_VERSION_MINOR) Then
sHighByte = Trim$(Str$(hibyte(WSAD.wversion)))
sLowByte = Trim$(Str$(lobyte(WSAD.wversion)))
sMsg = "Windows Sockets version " & sLowByte & "." & sHighByte
sMsg = sMsg & " is not supported by winsock.dll "
MsgBox sMsg
End
End If
If WSAD.iMaxSockets < MIN_SOCKETS_REQD Then
sMsg = "This application requires a minimum of "
sMsg = sMsg & Trim$(Str$(MIN_SOCKETS_REQD)) & " supported sockets."
MsgBox sMsg
End
End If
End Sub

Private Sub CleanupSockets()
Dim lReturn As Long
lReturn = WSACleanup()
If lReturn <> 0 Then
MsgBox "Socket error " & Trim$(Str$(lReturn)) & " occurred in Cleanup "
End
End If
End Sub

Private Function IPAddressFromHostName(ByVal hostname As String) As String
Dim hostent_addr As Long
Dim host As HOSTENT
Dim hostip_addr As Long
Dim temp_ip_address() As Byte
Dim i As Integer
Dim ip_address As String
Dim result As String
hostent_addr = gethostbyname(hostname)
If hostent_addr = 0 Then
IPAddressFromHostName = "<error>"
Exit Function
End If
RtlMoveMemory host, hostent_addr, LenB(host)
RtlMoveMemory hostip_addr, host.hAddrList, 4
Do
ReDim temp_ip_address(1 To host.hLength)
RtlMoveMemory temp_ip_address(1), hostip_addr, host.hLength
For i = 1 To host.hLength
ip_address = ip_address & temp_ip_address(i) & "."
Next
ip_address = Mid$(ip_address, 1, Len(ip_address) - 1)
result = result & ip_address & vbCrLf
ip_address = ""
host.hAddrList = host.hAddrList + LenB(host.hAddrList)
RtlMoveMemory hostip_addr, host.hAddrList, 4
Loop While (hostip_addr <> 0)
If Len(result) > 0 Then result = Left$(result, Len(result) - Len(vbCrLf))
IPAddressFromHostName = result
End Function

Private Sub Form_Load()
InitializeSockets
Set myobj = GetObject("WinNT://cvgroup")
myobj.Filter = Array("computer")
For Each co In myobj
MsgBox co.Name & vbTab & IPAddressFromHostName(co.Name)
Next
End Sub

Private Sub Form_Unload(Cancel As Integer)
CleanupSockets
End Sub
----------------------------------------------
0
 
LVL 2

Author Comment

by:kamlesh_agrawal
ID: 9891707
Thanks Rajesh,

I m getting the computer name alongwith its IPaddresses...

but i m facing a small problem is that i have 5 domains under which 3-4 computers are there..

but the program is identifying all 5 domains.. but when it goes to bring computer list under each domain... it is bringing for last 3 only ...i checked in network neighbourhood all domains are having 5-6 computers

my code is --


Private Sub Form_Load()
   Dim GlobalName
    Dim MyDomain
    Set GlobalName = GetObject("WinNT:")
    For Each MyDomain In GlobalName
         MsgBox "DOMAIN==>" & MyDomain.name
         Call GetComputers(MyDomain.name)
    Next
End Sub


Private Sub GetComputers(name As String)
    Dim oDomain
    Dim ocomputer
    Set oDomain = GetObject("WinNT://" & name)
    oDomain.Filter = Array("Computer")
    For Each ocomputer In oDomain
        MsgBox "Computer in Domain -- > " & ocomputer.name
    Next


End Sub

thanks
kamlesh A.
0
 
LVL 24

Expert Comment

by:R_Rajesh
ID: 10400157
Hi Kamlesh, sorry i couldn't be of more help :(

Rajesh
0

Featured Post

How to run any project with ease

Manage projects of all sizes how you want. Great for personal to-do lists, project milestones, team priorities and launch plans.
- Combine task lists, docs, spreadsheets, and chat in one
- View and edit from mobile/offline
- Cut down on emails

Join & Write a Comment

Introduction I needed to skip over some file processing within a For...Next loop in some old production code and wished that VB (classic) had a statement that would drop down to the end of the current iteration, bypassing the statements that were c…
This article describes some techniques which will make your VBA or Visual Basic Classic code easier to understand and maintain, whether by you, your replacement, or another Experts-Exchange expert.
Get people started with the process of using Access VBA to control Outlook using automation, Microsoft Access can control other applications. An example is the ability to programmatically talk to Microsoft Outlook. Using automation, an Access applic…
This lesson covers basic error handling code in Microsoft Excel using VBA. This is the first lesson in a 3-part series that uses code to loop through an Excel spreadsheet in VBA and then fix errors, taking advantage of error handling code. This l…

758 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question

Need Help in Real-Time?

Connect with top rated Experts

22 Experts available now in Live!

Get 1:1 Help Now