Solved

Getting the server time from a networked Attendance System...

Posted on 2004-03-23
6
305 Views
Last Modified: 2011-09-20
I am currently developing an attendance system that is connected to a server through the network.. I connect to the server by just indicating the IP address of the server in the .ini file of the attendance system..

Currently, I just use the time of the terminal used for the attendance system but this should not be the case.

How can I be able to get the server time as default time for my attendance system??

I am using Visual Basic 6.0 with MySQL as my database...
0
Comment
Question by:m_denise
6 Comments
 
LVL 5

Accepted Solution

by:
jrocnuck earned 24 total points
ID: 10664828
0
 
LVL 3

Assisted Solution

by:pamboo
pamboo earned 23 total points
ID: 10665091
The below query will return u the current servertime in SQL server 2000.

SELECT ServerTime=convert(varchar, GETDATE(), 108)

- Rajan
0
 
LVL 2

Assisted Solution

by:Ivan_Skrinjaric
Ivan_Skrinjaric earned 23 total points
ID: 10670866
Put this in standard BAS module :

option Explicit

private Declare Function NetRemoteTOD Lib "Netapi32.dll" ( _
    tServer as Any, pBuffer as Long) as Long

private Type SYSTEMTIME
    wYear as Integer
    wMonth as Integer
    wDayOfWeek as Integer
    wDay as Integer
    wHour as Integer
    wMinute as Integer
    wSecond as Integer
    wMilliseconds as Integer
End Type

private Type TIME_ZONE_INFORMATION
    Bias as Long
    StandardName(32) as Integer
    StandardDate as SYSTEMTIME
    StandardBias as Long
    DaylightName(32) as Integer
    DaylightDate as SYSTEMTIME
    DaylightBias as Long
End Type

private Declare Function GetTimeZoneInformation Lib "kernel32" _
        (lpTimeZoneInformation as TIME_ZONE_INFORMATION) as Long

private Declare Function NetApiBufferFree Lib "Netapi32.dll" _
        (byval lpBuffer as Long) as Long

private Type TIME_OF_DAY_INFO
    tod_elapsedt as Long
    tod_msecs as Long
    tod_hours as Long
    tod_mins as Long
    tod_secs as Long
    tod_hunds as Long
    tod_timezone as Long
    tod_tinterval as Long
    tod_day as Long
    tod_month as Long
    tod_year as Long
    tod_weekday as Long
End Type

private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
        (Destination as Any, Source as Any, byval Length as Long)

public Function getRemoteTOD(byval strServer as string) as date
   
    Dim result as date
    Dim lRet as Long
    Dim tod as TIME_OF_DAY_INFO
    Dim lpbuff as Long
    Dim tServer() as Byte

    tServer = strServer & vbNullChar
    lRet = NetRemoteTOD(tServer(0), lpbuff)

    If lRet = 0 then
        CopyMemory tod, byval lpbuff, len(tod)
        NetApiBufferFree lpbuff
        result = DateSerial(tod.tod_year, tod.tod_month, _
                            tod.tod_day) + _
        TimeSerial(tod.tod_hours, tod.tod_mins - tod.tod_timezone, _
                   tod.tod_secs)
        getRemoteTOD = result
    else
        Err.Raise Number:=vbObjectError + 1001, _
        Description:="cannot get remote TOD"
    End If

End Function


Call it something like this:

private Sub Command1_Click()
    Dim d as date

    d = GetRemoteTOD("server name or IP address")
    MsgBox d
End Sub

0
 
LVL 1

Expert Comment

by:fcisler
ID: 10708082
Ivan's code looks good, i know i wrote an app a little while back to set the time server and automatically re-sync. If you'd like it let me know
0

Featured Post

Is Your Active Directory as Secure as You Think?

More than 75% of all records are compromised because of the loss or theft of a privileged credential. Experts have been exploring Active Directory infrastructure to identify key threats and establish best practices for keeping data safe. Attend this month’s webinar to learn more.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Suggested Solutions

A short article about a problem I had getting the GPS LocationListener working.
If you’re thinking to yourself “That description sounds a lot like two people doing the work that one could accomplish,” you’re not alone.
With the power of JIRA, there's an unlimited number of ways you can customize it, use it and benefit from it. With that in mind, there's bound to be things that I wasn't able to cover in this course. With this summary we'll look at some places to go…
In this seventh video of the Xpdf series, we discuss and demonstrate the PDFfonts utility, which lists all the fonts used in a PDF file. It does this via a command line interface, making it suitable for use in programs, scripts, batch files — any pl…

920 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question

Need Help in Real-Time?

Connect with top rated Experts

13 Experts available now in Live!

Get 1:1 Help Now