Solved

NumLock

Posted on 2004-04-05
16
862 Views
Last Modified: 2012-06-21
I have a problem with some computers.
The Num Lock keeps turning off.

I don't know what is causing this ( if you could give me an idea that would be great)

to solve this problem i have put this code into a program that is always running

Sub TurnNumLockOn()
      Dim o As OSVERSIONINFO
      Dim NumLockState As Boolean
      Dim ScrollLockState As Boolean
      Dim CapsLockState As Boolean

      o.dwOSVersionInfoSize = Len(o)
      GetVersionEx o
      Dim keys(0 To 255) As Byte
      GetKeyboardState keys(0)

      ' NumLock handling:
      NumLockState = keys(VK_NUMLOCK)
      If NumLockState <> True Then    'Turn numlock on
        If o.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS Then  '=== Win95/98

          keys(VK_NUMLOCK) = 1
          SetKeyboardState keys(0)
        ElseIf o.dwPlatformId = VER_PLATFORM_WIN32_NT Then   '=== WinNT
        'Simulate Key Press
          keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0
        'Simulate Key Release
          keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY _
             Or KEYEVENTF_KEYUP, 0



        End If
      End If
End Sub


basically what it does is check the operating system.
if it is 95/98 it turns num lock on

if nt/win2000/xp it simulates keystrokes to turn it on. the problem seems to be that when it checks to see if num lock is on it finds it isn't (even when it is) and runs the code which actually turns it off.

The code runs every 10 seconds and what is happening is that the num lock comes on then 10 seconds later goes off the on and so on...

this has only been a problem on nt/win2000/xp as i have not had a chance to test it on 98.

the problem seems to be with the code
NumLockState = keys(VK_NUMLOCK)
If NumLockState <> True Then    'Turn numlock on







0
Comment
Question by:Eamon
[X]
Welcome to Experts Exchange

Add your voice to the tech community where 5M+ people just like you are talking about what matters.

  • Help others & share knowledge
  • Earn cash & points
  • Learn & ask questions
  • 5
  • 4
  • 2
  • +3
16 Comments
 
LVL 6

Expert Comment

by:mmusante
ID: 10756037
>     Dim o As OSVERSIONINFO    
What component do I need to compile?
0
 
LVL 6

Expert Comment

by:mmusante
ID: 10756046
What about turning numlock on without testing its state?
0
 
LVL 1

Author Comment

by:Eamon
ID: 10756099
' Declare Type for API call:
      Private Type OSVERSIONINFO
        dwOSVersionInfoSize As Long
        dwMajorVersion As Long
        dwMinorVersion As Long
        dwBuildNumber As Long
        dwPlatformId As Long
        szCSDVersion As String * 128   '  Maintenance string for PSS usage
      End Type

      ' API declarations:

      Private Declare Function GetVersionEx Lib "kernel32" _
         Alias "GetVersionExA" _
         (lpVersionInformation As OSVERSIONINFO) As Long

      Private Declare Sub keybd_event Lib "user32" _
         (ByVal bVk As Byte, _
          ByVal bScan As Byte, _
          ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

      Private Declare Function GetKeyboardState Lib "user32" _
         (pbKeyState As Byte) As Long

      Private Declare Function SetKeyboardState Lib "user32" _
         (lppbKeyState As Byte) As Long

      ' Constant declarations:
      Const VK_NUMLOCK = &H90
      Const VK_SCROLL = &H91
      Const VK_CAPITAL = &H14
      Const KEYEVENTF_EXTENDEDKEY = &H1
      Const KEYEVENTF_KEYUP = &H2
      Const VER_PLATFORM_WIN32_NT = 2
      Const VER_PLATFORM_WIN32_WINDOWS = 1
0
Creating Instructional Tutorials  

For Any Use & On Any Platform

Contextual Guidance at the moment of need helps your employees/users adopt software o& achieve even the most complex tasks instantly. Boost knowledge retention, software adoption & employee engagement with easy solution.

 
LVL 1

Author Comment

by:Eamon
ID: 10756106
turning on would probably work for the 98 computer but not for the NT

It doesn't just turn it on it sends the keyspress

so firts time you press the key it turns it on next time you press it turns it off.


I am going to check what happens if i run the 98 code on an xp computer just to see what happens its a long shot though.
0
 
LVL 1

Author Comment

by:Eamon
ID: 10756134
well that was interesting.

i ran the 98 code on an xp computer.
the code ran through ok put had no effect.

the next time it ran
NumLockState = keys(VK_NUMLOCK)

returned true meaning it thought num lock was on and so did not run again.

my problem seems to be finding out if num lock is on.
Can anyone tell me how I do this in nt/win2000/xp

0
 
LVL 26

Expert Comment

by:EDDYKT
ID: 10756613
0
 
LVL 26

Expert Comment

by:EDDYKT
ID: 10756619
ie

keybd_event VK_NUMLOCK, MapVirtualKey(VK_NUMLOCK, 0), 0, 0
keybd_event VK_NUMLOCK, MapVirtualKey(VK_NUMLOCK, 0), 2, 0
0
 
LVL 6

Expert Comment

by:mmusante
ID: 10756759
Tried on my W2000 but it works fine ...
0
 
LVL 6

Expert Comment

by:mmusante
ID: 10756788
It seems that 'NumLockState = keys(VK_NUMLOCK)' return always true on the machines where your routine doesn't work ...

Try making a little test program that displays the result of 'NumLockState = keys(VK_NUMLOCK)' and use it on machines where you see the problem
0
 
LVL 6

Expert Comment

by:___XXX_X_XXX___
ID: 10757772
Are you try GetKeyState API instead of GetKeyboardState ?

The GetKeyState function retrieves the status of the specified virtual key. The status specifies whether the key is up, down, or toggled (on, off ¾ alternating each time the key is pressed).
Return Values

If the function succeeds, the return value specifies the status of the given virtual key. If the high-order bit is 1, the key is down; otherwise, it is up. If the low-order bit is 1, the key is toggled. A key, such as the CAPS LOCK key, is toggled if it is turned on. The key is off and untoggled if the low-order bit is 0. A toggle key's indicator light (if any) on the keyboard will be on when the key is toggled, and off when the key is untoggled
0
 
LVL 28

Accepted Solution

by:
Ark earned 300 total points
ID: 10762000
Private Declare Function GetKeyState Lib "user32" (ByVal vKey As Long) As Integer
Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Sub Command1_Click()
   Static bVal As Boolean
   bVal = Not bVal
   SetNumState bVal
End Sub

Private Function IsNumOn() As Boolean
   IsNumOn = IsBitSet(GetKeyState(vbKeyNumlock), 0)
End Function

Private Sub SetNumState(Optional ByVal bOn As Boolean = True)
  If IsNumOn <> bOn Then
     keybd_event vbKeyNumlock, &H45, 1, 0
     keybd_event vbKeyNumlock, &H45, 3, 0
  End If
End Sub

Private Function IsBitSet(iBitString As Long, ByVal lBitNo As Integer) As Boolean
    If lBitNo = 31 Then
        IsBitSet = iBitString < 0
    Else
        IsBitSet = iBitString And (2 ^ lBitNo)
    End If
End Function
0
 
LVL 17

Expert Comment

by:zzzzzooc
ID: 10762163
Does the above work fine for you if you click Command1 multiple times in a row, Ark? It seems to not recognize the state of the key correctly for me (XP).

The below works for me in XP ("And 1" strips everything but the lowest bits from the return value)..


Form1:
===========

Private Declare Function GetKeyState Lib "user32" (ByVal vKey As Long) As Integer
Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Const KEYEVENTF_KEYUP = &H2
Private Sub Form_Load()
    Timer1.Interval = 1000
    Timer1.Enabled = True
End Sub
Private Sub Timer1_Timer()
    If (GetKeyState(vbKeyNumlock) And 1) <> 1 Then
        Call keybd_event(vbKeyNumlock, 0, 0, 0)
        Call keybd_event(vbKeyNumlock, 0, KEYEVENTF_KEYUP, 0)
    End If
End Sub

0
 
LVL 28

Expert Comment

by:Ark
ID: 10762184
It works for me (XP too)
IsBitSet is my sub from one of the old apps, actually I check lowest bit (0), so
iBitString And (2 ^ lBitNo) equivalent to iBitString And 1 '(2^0 = 1)
0
 
LVL 17

Expert Comment

by:zzzzzooc
ID: 10762243
[backspaces post]

Oops, didn't notice the bVal being static... thought it'd always return True. Meh @ overlooking things
0
 
LVL 1

Author Comment

by:Eamon
ID: 10772988
I have left out some information about the program which i did not think was important but now know is.
This program runs in the task bar. To see what was going on i put a textbox on the form and set it to the value of NumLockState.

I ran the program - i let it run for a while in the taskbar - it started turning on the numlock then off then on....

I then maximized the form so i could see what was going on.

And what do you know it started working perfectly.

I tried many other tests and the same results. It would not work properly while in the taskbar but once you brought up the form it started working properly.

Can anyone explain this.


it also seems to work fine in the taskbar when you open the project and run it but if you run the exe it does not.

I can email an example of it if anyone wants to have a look.
0
 
LVL 1

Author Comment

by:Eamon
ID: 10773059
Ark I used your code and it seemed to work fine thanks alot.
I will accept you answer but I just want to keep the question open a bit longer to see if there are any more comments.

Thanks to everone who helped.
0

Featured Post

Online Training Solution

Drastically shorten your training time with WalkMe's advanced online training solution that Guides your trainees to action. Forget about retraining and skyrocket knowledge retention rates.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Suggested Solutions

Title # Comments Views Activity
Problem to With line 4 75
Advice in Xamarin 21 109
how to Classify of email (pdf attachments) 7 50
add criteria to query in VB, Access 2003 2 32
If you have ever used Microsoft Word then you know that it has a good spell checker and it may have occurred to you that the ability to check spelling might be a nice piece of functionality to add to certain applications of yours. Well the code that…
When designing a form there are several BorderStyles to choose from, all of which can be classified as either 'Fixed' or 'Sizable' and I'd guess that 'Fixed Single' or one of the other fixed types is the most popular choice. I assume it's the most p…
Get people started with the utilization of class modules. Class modules can be a powerful tool in Microsoft Access. They allow you to create self-contained objects that encapsulate functionality. They can easily hide the complexity of a process from…
This lesson covers basic error handling code in Microsoft Excel using VBA. This is the first lesson in a 3-part series that uses code to loop through an Excel spreadsheet in VBA and then fix errors, taking advantage of error handling code. This l…

733 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question