Solved

Clearing IE Cache Programatically

Posted on 2004-04-29
4
755 Views
Last Modified: 2013-11-13
I want to clear the internet Explorer Cache through an application, can i do this using any Windows API functions, if so how i do this?

Plz help me As soon as possible, since is ugrently required..

Regards,
Umesh Timoli.
0
Comment
Question by:timoliumesh
4 Comments
 
LVL 35

Accepted Solution

by:
[ fanpages ] earned 50 total points
ID: 10946952
Hi timoliumesh,

I'm not aware what language you are using but here's some sample code written by Andrew Baker for MS-Excel (VBA):

[http://www.vbusers.com/code/codeget.asp?ThreadID=209&PostID=1&NumReplies=0]

The following code can be used to query and delete files in the internet cache (including cookies). A demonstration routine can be found at the bottom of this post. Note, the enumerated type eCacheType is not supported in Excel 97, but can be changed to a list of Public Constants eg. Public Const eNormal = &H1&.

Option Explicit

'--------------------------Types, consts and structures
Private Const ERROR_CACHE_FIND_FAIL As Long = 0
Private Const ERROR_CACHE_FIND_SUCCESS As Long = 1
Private Const ERROR_FILE_NOT_FOUND As Long = 2
Private Const ERROR_ACCESS_DENIED As Long = 5
Private Const ERROR_INSUFFICIENT_BUFFER As Long = 122
Private Const MAX_CACHE_ENTRY_INFO_SIZE As Long = 4096

Private Const LMEM_FIXED As Long = &H0
Private Const LMEM_ZEROINIT As Long = &H40

Public Enum eCacheType
    eNormal = &H1&
    eEdited = &H8&
    eTrackOffline = &H10&
    eTrackOnline = &H20&
    eSticky = &H40&
    eSparse = &H10000
    eCookie = &H100000
    eURLHistory = &H200000
    eURLFindDefaultFilter = 0&
End Enum

Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Type INTERNET_CACHE_ENTRY_INFO
    dwStructSize As Long
    lpszSourceUrlName As Long
    lpszLocalFileName As Long
    CacheEntryType  As Long         'Type of entry returned
    dwUseCount As Long
    dwHitRate As Long
    dwSizeLow As Long
    dwSizeHigh As Long
    LastModifiedTime As FILETIME
    ExpireTime As FILETIME
    LastAccessTime As FILETIME
    LastSyncTime As FILETIME
    lpHeaderInfo As Long
    dwHeaderInfoSize As Long
    lpszFileExtension As Long
    dwExemptDelta  As Long
End Type

'--------------------------Internet Cache API
Private Declare Function FindFirstUrlCacheEntry Lib "Wininet.dll" Alias "FindFirstUrlCacheEntryA" (ByVal lpszUrlSearchPattern As String, lpFirstCacheEntryInfo As Any, lpdwFirstCacheEntryInfoBufferSize As Long) As Long
Private Declare Function FindNextUrlCacheEntry Lib "Wininet.dll" Alias "FindNextUrlCacheEntryA" (ByVal hEnumHandle As Long, lpNextCacheEntryInfo As Any, lpdwNextCacheEntryInfoBufferSize As Long) As Long
Private Declare Function FindCloseUrlCache Lib "Wininet.dll" (ByVal hEnumHandle As Long) As Long
Private Declare Function DeleteUrlCacheEntry Lib "Wininet.dll" Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long

'--------------------------Memory API
Private Declare Function LocalAlloc Lib "kernel32" (ByVal uFlags As Long, ByVal uBytes As Long) As Long
Private Declare Function LocalFree Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (pDest As Any, pSource As Any, ByVal dwLength As Long)
Private Declare Function lstrcpyA Lib "kernel32" (ByVal RetVal As String, ByVal Ptr As Long) As Long
Private Declare Function lstrlenA Lib "kernel32" (ByVal Ptr As Any) As Long


'Purpose     :  Deletes the specified internet cache file
'Inputs      :  sCacheFile              The name of the cache file
'Outputs     :  Returns True on success.
'Author      :  Andrew Baker
'Date        :  03/08/2000 19:14
'Notes       :
'Revisions   :

Function InternetDeleteCache(sCacheFile As String) As Boolean
    InternetDeleteCache = CBool(DeleteUrlCacheEntry(sCacheFile))
End Function


'Purpose     :  Returns an array of files stored in the internet cache
'Inputs      :  eFilterType             An enum which filters the files returned by their type
'Outputs     :  A one dimensional, one based, string array containing the names of the files
'Author      :  Andrew Baker
'Date        :  03/08/2000 19:14
'Notes       :
'Revisions   :

Function InternetCacheList(Optional eFilterType As eCacheType = eNormal) As Variant
    Dim ICEI As INTERNET_CACHE_ENTRY_INFO
    Dim lhFile As Long, lBufferSize As Long, lptrBuffer As Long
    Dim sCacheFile As String
    Dim asURLs() As String, lNumEntries As Long

    'Determine required buffer size
    lBufferSize = 0
    lhFile = FindFirstUrlCacheEntry(0&, ByVal 0&, lBufferSize)
   
    If (lhFile = ERROR_CACHE_FIND_FAIL) And (Err.LastDllError = ERROR_INSUFFICIENT_BUFFER) Then
   
        'Allocate memory for ICEI structure
        lptrBuffer = LocalAlloc(LMEM_FIXED, lBufferSize)
   
        If lptrBuffer Then
         
            'Set a Long pointer to the memory location
            CopyMemory ByVal lptrBuffer, lBufferSize, 4
           
            'Call first find API passing it the pointer to the allocated memory
            lhFile = FindFirstUrlCacheEntry(vbNullString, ByVal lptrBuffer, lBufferSize)        '1 = success
           
            If lhFile <> ERROR_CACHE_FIND_FAIL Then
           
                'Loop through the cache
                Do
                    'Copy data back to structure
                    CopyMemory ICEI, ByVal lptrBuffer, Len(ICEI)
               
                    If ICEI.CacheEntryType And eFilterType Then
                        sCacheFile = StrFromPtrA(ICEI.lpszSourceUrlName)
                        lNumEntries = lNumEntries + 1
                        If lNumEntries = 1 Then
                            ReDim asURLs(1 To 1)
                        Else
                            ReDim Preserve asURLs(1 To lNumEntries)
                        End If
                        asURLs(lNumEntries) = sCacheFile
                    End If
               
                    'Free memory associated with the last-retrieved file
                    Call LocalFree(lptrBuffer)
                   
                    'Call FindNextUrlCacheEntry with buffer size set to 0.
                    'Call will fail and return required buffer size.
                    lBufferSize = 0
                    Call FindNextUrlCacheEntry(lhFile, ByVal 0&, lBufferSize)
                   
                    'Allocate and assign the memory to the pointer
                    lptrBuffer = LocalAlloc(LMEM_FIXED, lBufferSize)
                    CopyMemory ByVal lptrBuffer, lBufferSize, 4&
               
                Loop While FindNextUrlCacheEntry(lhFile, ByVal lptrBuffer, lBufferSize)
           
            End If
       
        End If
   
    End If
   
    'Free memory
    Call LocalFree(lptrBuffer)
    Call FindCloseUrlCache(lhFile)
    InternetCacheList = asURLs
End Function


'Purpose     :  Converts a pointer an ansi string into a string.
'Inputs      :  lptrString                  A long pointer to a string held in memory
'Outputs     :  The string held at the specified memory address
'Author      :  Andrew Baker
'Date        :  03/08/2000 19:14
'Notes       :
'Revisions   :

Function StrFromPtrA(ByVal lptrString As Long) As String
    'Create buffer
    StrFromPtrA = String$(lstrlenA(ByVal lptrString), 0)
    'Copy memory
    Call lstrcpyA(ByVal StrFromPtrA, ByVal lptrString)
End Function


'Demonstration routine
Sub Test()
    Dim avURLs As Variant, vThisValue As Variant
   
    On Error Resume Next
    'Return an array of all internet cache files
    avURLs = InternetCacheList
    For Each vThisValue In avURLs
        'Print files
        Debug.Print CStr(vThisValue)
    Next
   
    'Return the an array of all cookies
    avURLs = InternetCacheList(eCookie)
    If MsgBox("Delete cookies?", vbQuestion + vbYesNo) = vbYes Then
        For Each vThisValue In avURLs
            'Delete cookies
            InternetDeleteCache CStr(vThisValue)
            Debug.Print "Deleted " & vThisValue
        Next
    Else
        For Each vThisValue In avURLs
            'Print cookie files
            Debug.Print vThisValue
        Next
    End If
End Sub

BFN,

fp.
0
 

Assisted Solution

by:stitch2802
stitch2802 earned 50 total points
ID: 10978799
Hi Umesh,

Try this:

// From MSDN (see:KB 815718 @ http://support.microsoft.com/default.aspx?scid=kb;en-us;815718)
     // Pointer to a GROUPID variable
     GROUPID groupId = 0;
     
     // Local variables
     DWORD cacheEntryInfoBufferSizeInitial = 0;
    DWORD cacheEntryInfoBufferSize = 0;
    int *cacheEntryInfoBuffer = 0;
    INTERNET_CACHE_ENTRY_INFOA *internetCacheEntry;
    HANDLE enumHandle = NULL;
    BOOL returnValue = false;

     // Delete the groups first.
    // Groups may not always exist on the system.
    // For more information, visit the following Microsoft Web site:
    // http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wcewinet/html/ceconwininetfunctions.asp              
    // By default, a URL does not belong to any group. Therefore, that cache may become
    // empty even when the CacheGroup APIs are not used because the existing URL does not belong to any group.              
    enumHandle = FindFirstUrlCacheGroup(0, CACHEGROUP_SEARCH_ALL, 0, 0, &groupId, 0);

     // If there are no items in the Cache, you are finished.
     if (enumHandle != NULL && ERROR_NO_MORE_ITEMS == GetLastError())
          return 0;
     
     // Loop through Cache Group, and then delete entries.
     while(1)
     {
          // Delete a particular Cache Group.
          returnValue = DeleteUrlCacheGroup(groupId, CACHEGROUP_FLAG_FLUSHURL_ONDELETE, 0);
         
          if (!returnValue && ERROR_FILE_NOT_FOUND == GetLastError())
          {    
               returnValue = FindNextUrlCacheGroup(enumHandle, &groupId, 0);
          }
         
          if (!returnValue && (ERROR_NO_MORE_ITEMS == GetLastError() || ERROR_FILE_NOT_FOUND == GetLastError()))
          {
               break;
          }
     }
     
     // Start to delete URLs that do not belong to any group.
     enumHandle = FindFirstUrlCacheEntry(NULL, 0, &cacheEntryInfoBufferSizeInitial);
     if (enumHandle != NULL && ERROR_NO_MORE_ITEMS == GetLastError())
                return 0;
     
     cacheEntryInfoBufferSize = cacheEntryInfoBufferSizeInitial;
     internetCacheEntry =  (INTERNET_CACHE_ENTRY_INFOA *)malloc(cacheEntryInfoBufferSize);
     enumHandle = FindFirstUrlCacheEntry(NULL, internetCacheEntry, &cacheEntryInfoBufferSizeInitial);
    while(1)
     {
          cacheEntryInfoBufferSizeInitial = cacheEntryInfoBufferSize;          
          returnValue = DeleteUrlCacheEntry(internetCacheEntry->lpszSourceUrlName);                    
         
          if (!returnValue)
          {    
               returnValue = FindNextUrlCacheEntry(enumHandle, internetCacheEntry, &cacheEntryInfoBufferSizeInitial);
          }
         
          DWORD dwError = GetLastError();
          if (!returnValue && ERROR_NO_MORE_ITEMS == dwError)
          {
               break;
          }              
         
          if (!returnValue && cacheEntryInfoBufferSizeInitial > cacheEntryInfoBufferSize)
          {
               cacheEntryInfoBufferSize = cacheEntryInfoBufferSizeInitial;
               internetCacheEntry =  (INTERNET_CACHE_ENTRY_INFOA *)realloc(internetCacheEntry, cacheEntryInfoBufferSize);
               returnValue = FindNextUrlCacheEntry(enumHandle, internetCacheEntry, &cacheEntryInfoBufferSizeInitial);                        
          }
     }
     
     free(internetCacheEntry);
     MessageBox("Temporary Internet Files cleared.",0, MB_OK);


HTH,
S/.
0

Featured Post

How to run any project with ease

Manage projects of all sizes how you want. Great for personal to-do lists, project milestones, team priorities and launch plans.
- Combine task lists, docs, spreadsheets, and chat in one
- View and edit from mobile/offline
- Cut down on emails

Join & Write a Comment

Suggested Solutions

In this post we will learn how to connect and configure Android Device (Smartphone etc.) with Android Studio. After that we will run a simple Hello World Program.
Although it can be difficult to imagine, someday your child will have a career of his or her own. He or she will likely start a family, buy a home and start having their own children. So, while being a kid is still extremely important, it’s also …
An introduction to basic programming syntax in Java by creating a simple program. Viewers can follow the tutorial as they create their first class in Java. Definitions and explanations about each element are given to help prepare viewers for future …
In this fourth video of the Xpdf series, we discuss and demonstrate the PDFinfo utility, which retrieves the contents of a PDF's Info Dictionary, as well as some other information, including the page count. We show how to isolate the page count in a…

762 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question

Need Help in Real-Time?

Connect with top rated Experts

23 Experts available now in Live!

Get 1:1 Help Now