Convert Dollars Amount Into Words

@ChrisFretwell  - The function work great up to Hundred Thousand.  I have to make some minor modification to get it to works up to Hundred Billion the way I envision it.

I know you said no point, but you're the one leading me to get to the answer is as good as helping me accomplished the solution.  So the points are all your, thank you very much @ChrisFretwell.

Darn it, I'm too slow!  

I just finished a version using two functions (a subfunc handled 1-999 since that is common to all amount levels: billions, millions, thousands, etc.).

@ScottPletcher - I wouldn't mind to learn more than one way to accomplish this task at all.  How about 250 points to see your logic?

Works for me.

I, too, have seen this Q posted before and finally had time to work on it :-).  As a side benefit, function is customized to what you indicated as your desired output.

Sample invocation:

SELECT dbo.numberToWords(123456789123.45)
SELECT dbo.numberToWords(0.00)



-- sub-function (/ "worker" function)

CREATE FUNCTION dbo.Number999ToWords (
      @amount INT
)
RETURNS VARCHAR(36)
AS
BEGIN --FUNCTION

IF @amount = 0
      RETURN ''

DECLARE @result VARCHAR(36)
SET @result = ''

IF @amount > 99
BEGIN
      SET @result = @result + RTRIM(SUBSTRING('One  Two  ThreeFour Five Six  SevenEightNine',
                  ((@amount / 100) - 1) * 5 + 1, 5)) + ' Hundred '
      SET @amount = @amount % 100
END --IF

IF @amount BETWEEN 11 AND 19
BEGIN
      SET @result = @result + RTRIM(SUBSTRING(
            'Eleven   Twelve   Thirteen Fourteen Fifteen  Sixteen  SeventeenEighteen Nineteen',
            ((@amount - 10) - 1) * 9 + 1, 9))
END --IF
ELSE
BEGIN
      IF @amount > 9
            SET @result = @result + RTRIM(SUBSTRING(
                  'Ten    Twenty Thirty Forty  Fifty  Sixty  SeventyEighty Ninety',
                  ((@amount / 10) - 1) * 7 + 1, 7))
      IF @amount % 10 <> 0
      BEGIN
            IF @amount > 9
                  SET @result = @result + '-'
            SET @result = @result + RTRIM(SUBSTRING('One  Two  ThreeFour Five Six  SevenEightNine',
                  ((@amount % 10) - 1) * 5 + 1, 5))
      END --IF
END --ELSE
RETURN RTRIM(@result)
END --FUNCTION



-- main function

CREATE FUNCTION dbo.NumberToWords (
      @amount DECIMAL(14, 2)
)
RETURNS VARCHAR(150)
AS
BEGIN --FUNCTION

DECLARE @result VARCHAR(150)
SET @result = ''

IF @amount < 1.00
      SET @result = 'Zero'

IF @amount > 999999999
BEGIN
      SET @result = @result + dbo.Number999ToWords(@amount / 1000000000) + ' Billion '
      SET @amount = @amount - (FLOOR(@amount / 1000000000) * 1000000000)
END --IF

IF @amount > 999999
BEGIN
      SET @result = @result + dbo.Number999ToWords(@amount / 1000000) + ' Million '
      SET @amount = @amount - (FLOOR(@amount / 1000000) * 1000000)
END --IF

IF @amount > 999
BEGIN
      SET @result = @result + dbo.Number999ToWords(@amount / 1000) + ' Thousand '
      SET @amount = @amount - (FLOOR(@amount / 1000) * 1000)
END --IF

SET @result = @result + dbo.Number999ToWords(@amount) + ' '
SET @amount = @amount - FLOOR(@amount)

SET @result = @result + 'and ' + RIGHT('0' + CAST(CAST(@amount * 100 AS SMALLINT) AS VARCHAR(2)), 2) + '/100 Dollars '

RETURN @result
END --FUNCTION

I have to admit I couldn't tell if I got errors from the other function (the linked-to code).  Did I feed the value in in the wrong format?

SELECT dbo.no2word('123456789')

Result:
Twelve Crore Thirty Four Lack Fifty Six Thousand Seven Hundred Eighty Nine

??

@ScottPletcher - you're absolutely right!  

SELECT dbo.no2word('123456789') function actually returned that result which was why I have to make modification to get it to work.  Anyway, your function works wonder!  I can feed decimal and get the result as expected.  

I'll post points for you shortly. Nice code @ScottPletcher!