asked on

Cannot disable wireless networking

I have an IBM Thinkpad running windows XP and use different wireless hot spots as I travel. Normally as a safety precaution, I disable to wireless when it is not in use. (guess that is a valid action) However recenly I have been unable to disasble wireless from the task bar and get this error. "It is not possible to disable the connection at this time. The connection may be using one or more protocols that do not support plug and play, or it may have been initiated by another user or the system account"

I need help in disabling as well as have a question about where I can learn about wireless security and safety.

Thanks

mikeleebrla

have you tried disabling the NIC at the OS level? You do this by rightclicking "my network places" on your desktop and choose properties. Then you will see a list of all your NICs. Rightclick on the one you want to disable and choose "disable". What you see in the taskbar could just be the software that comes with your NIC, depending on how you have your desktop set up.

bd1saul

ASKER

That does not work. I tried again just to make sure and I get the same error and the wireless does not disable.

mikeleebrla

ok,,, in that case what you are seeing in the taskbar is the "icon" that is put there by the OS rather than software from the NIC manufacture so you are in effect doing the same thing when you attempt to disable it in the taskbar or in "my network places". I would remove the NIC drivers and reinstall them since it appears that something is currupt with them.

ASKER CERTIFIED SOLUTION

purplepomegranite

membership

This solution is only available to members.

To access this solution, you must be a member of Experts Exchange.

Start Free Trial

bd1saul

ASKER

Although restarting the computer has not worked, the shortcut key did work. It worked too well because I was on the wireless network when I tried it and it booted me off... :-) The IBM software did the trick.

gdrost_2000

that still doesn't solve your original problem. I've tried this and it worked.

try this script (and the other solutions if this does not work) from : http://www.neowin.net/forum/lofiversion/index.php/t348866.html

It has been tested on SP1 and SP2 Windows XP Pro systems, should work fine for Home as well.

Copy between --START-- and --END-- then just paste into a file and name it fixdb.bat

--START--

@echo off
:: Batch file that tries to remedy error # 800710D9
:: "Unable to read from or write to the database".
:: Author: Torgeir Bakken
:: Date: 2004-08-30

cls
echo This batch file will now try to remedy the error 0x800710D9.
echo To abort and not run it now, hold down Ctrl and press C.
echo Otherwise press the space bar to continue.
pause

:: Stop the Cryptographic service
%SystemRoot%\System32\net.exe stop CryptSvc

:: Rename all log files in the %SystemRoot%\Security folder
FOR %%a in (%SystemRoot%\Security\*.log) DO move /y %%a %%a.old

:: Rename the %SystemRoot%\System32\CatRoot2 folder
move /y %SystemRoot%\System32\CatRoot2 %SystemRoot%\System32\CatRoot2old

IF not exist %SystemRoot%\System32\CatRoot2 GOTO CONT01

:: In case the folder rename failed because of locked files
:: rename all log files in the %SystemRoot%\System32\CatRoot2 folder
FOR %%a in (%SystemRoot%\System32\CatRoot2\*.log) DO move /y %%a %%a.old
SET catroot2locked=True

:CONT01
cls
echo.
echo Please wait, this might take some time...

:: Unregister DLL files that are associated with Cryptographic Services
CD /D %SystemRoot%\System32
start /wait regsvr32.exe /s /u softpub.dll
start /wait regsvr32.exe /s /u wintrust.dll
start /wait regsvr32.exe /s /u initpki.dll
start /wait regsvr32.exe /s /u dssenh.dll
start /wait regsvr32.exe /s /u rsaenh.dll
start /wait regsvr32.exe /s /u gpkcsp.dll
start /wait regsvr32.exe /s /u sccbase.dll
start /wait regsvr32.exe /s /u slbcsp.dll
start /wait regsvr32.exe /s /u cryptdlg.dll

:: Reregister DLL files that are associated with Cryptographic Services
start /wait regsvr32.exe /s softpub.dll
start /wait regsvr32.exe /s wintrust.dll
start /wait regsvr32.exe /s initpki.dll
start /wait regsvr32.exe /s dssenh.dll
start /wait regsvr32.exe /s rsaenh.dll
start /wait regsvr32.exe /s gpkcsp.dll
start /wait regsvr32.exe /s sccbase.dll
start /wait regsvr32.exe /s slbcsp.dll
start /wait regsvr32.exe /s cryptdlg.dll

:: Configure and start the Cryptographic service
%SystemRoot%\system32\sc.exe config CryptSvc start= auto
:: Start the Cryptographic Service
%SystemRoot%\system32\net.exe start CryptSvc
cls

echo.
If "%catroot2locked%"=="True" GOTO CONT02
echo Finished, please reboot the computer and then try to install SP2 again...

GOTO END
:CONT02
echo Please run the batch file again with a newly restarted computer...
echo (but if it is newly restarted, just do a reboot and then try
echo to install SP2 again)...
GOTO END

:END
echo.
pause

--END--