Solved

Backup Quickbook data to a web site via FTP

Posted on 2006-07-04
4
639 Views
Last Modified: 2013-11-29
This is somewhat of a two-part question, although the important part is the FTP question.

I want to backup QuickBooks data to a web site (or most likely a passworded sub-folder of the web site).

Can anyone recommend an FTP program where I could put an icon on a desktop, have someone click it, and that program automatically ftp the program from the computer to the web site? (Or another very, very easy way, as the person having to do the backup is not very computer literate at all).

And related to the above, is there any difference between the QuickBooks data file that you work on, and the file created when you go to QuickBooks's menu and click on "back up company."

On the second part, based on my experience, I say it is the same file, but someone else is trying to tell me the files are actually different. And it also matters as to where the FTP program will get the data to transfer and the number of steps the person doing the backup will have to go through.


Thanks,

Jay Banks



0
Comment
Question by:usurper_ii
  • 2
  • 2
4 Comments
 
LVL 2

Author Comment

by:usurper_ii
ID: 17038327
Reading my question, let be be a little clearer:

automatically ftp the program from the computer to the web site?

That part should actually read:

automatically ftp the QuickBooks data file from the computer to the web site?

Sorry.

Usurper_ii
0
 
LVL 95

Expert Comment

by:Lee W, MVP
ID: 17038351
I'm not sure the difference between files, but I see problem in backing up either via FTP.

Now, keep in mind that FTP is an UNENCRYPTED protocol and though unlikely, it would be possible for someone to steal the file by sniffing the line.  I would strongly recommend compressing the file with a good encryption/compression program.  At the least, zip it with a password.

Then for the FTP part, you can just write a script and ftp the file with that.  And why make the user do it - setup a scheduled task so it happens automatically.  The built in FTP program is easily scriptable.
0
 
LVL 95

Accepted Solution

by:
Lee W, MVP earned 250 total points
ID: 17038410
Here's a sample script:
-------------------8<--------------------
@echo off
setlocal
Set QuickBooksPath=x:\quickbooks
set mm=%date:~4,2%
set dd=%date:~7,2%
set yyyy=%date:~-4%
set hh=%time:~0,2%
set min=%time:~3,2%
if "%hh%" == " 0" Set hh=0%hh:~-1%
if "%hh%" == " 1" Set hh=0%hh:~-1%
if "%hh%" == " 2" Set hh=0%hh:~-1%
if "%hh%" == " 3" Set hh=0%hh:~-1%
if "%hh%" == " 4" Set hh=0%hh:~-1%
if "%hh%" == " 5" Set hh=0%hh:~-1%
if "%hh%" == " 6" Set hh=0%hh:~-1%
if "%hh%" == " 7" Set hh=0%hh:~-1%
if "%hh%" == " 8" Set hh=0%hh:~-1%
if "%hh%" == " 9" Set hh=0%hh:~-1%
set filename=%yyyy%%mm%%dd%.%hh%%min%.zip
Echo Executing at %time% on %date%  >> %temp%\remote.log
Echo. >> %temp%\remote.log
cd /d %QuickBooksPath%
echo zip -9 "%temp%\%filename%" "MyCompany.QBW" >> %temp%\remote.log
zip -9 "%temp%\%filename%" "MyCompany.QBW" >> %temp%\remote.log 2>>&1
If Exist "%temp%\remote.scr" del "%temp%\remote.scr"
echo username>>"%temp%\remote.scr"
echo password>>"%temp%\remote.scr"
echo cd /path/to/upload/file/to>>"%temp%\remote.scr"
echo lcd %temp%>>"%temp%\remote.scr"
echo bin>>"%temp%\remote.scr"
echo put %filename%>>"%temp%\remote.scr"
echo bye>>"%temp%\remote.scr"
cd /d %temp%
Echo  FTP Started uploading at: %time%
ftp -s:remote.scr ftp.site.com > NUL
Echo FTP Finished uploading at: %time%
If Exist "%filename%" del "%filename%"
gbmail -v -to myemail@MyCompanycorp.com -file %temp%\remote.log -from myotheremail@MyCompanycorp.com -s MyCompany-Remote-Backup -h my.smtp.server
If Exist "%temp%\remote.*" del "%temp%\remote.*"
cd %temp%
endlocal
-------------------8<--------------------
Note: this script would use a command line utility, gbmail, to email you a log of what happened.  In addition, it would use the free InfoZip command line zipping program (which does NOT have encryption abilities) to zip the file.  You should really consider using another program that is scriptable to zip and encrypt the file.
0
 
LVL 2

Author Comment

by:usurper_ii
ID: 17050629
I don't know if it is just me or what, but the first few times I ran this, it acted kind of flaky. The main thing I noticed is that it doesn't seem to log all of the things the script file is telling it to log in the log file.

That being said, however, I did manage to adapt it to a registered version of WinZip with the command line add-on that supports both password protected zip files and encryption from the command line.

Right now, I have the gbmail part commented out, but I downloaded gbmail and will play with that part later.

So far, even though I had to put a lot of time into getting it to work the way I wanted, it does seem to do what I asked for...and I can already think of useful things I can do with this script.

So I must say *thanks* for the help and I will accept your answer.

As a side note, many years ago, back when I used to have a WildCat BBS, I used to have a batch file that could zip files up by date. I lost the script over the years and never could figure out how I did it. I have been doing it now with a little DOS program I found somewhere. I'm happy to have my hands back on script that will do it straight from a batch file without having to call on another program.

Usurper_ii

0

Featured Post

Why You Should Analyze Threat Actor TTPs

After years of analyzing threat actor behavior, it’s become clear that at any given time there are specific tactics, techniques, and procedures (TTPs) that are particularly prevalent. By analyzing and understanding these TTPs, you can dramatically enhance your security program.

Join & Write a Comment

Suggested Solutions

Configuring network clients can be a chore, especially if there are a large number of them or a lot of itinerant users.  DHCP dynamically manages this process, much to the relief of users and administrators alike!
Let’s list some of the technologies that enable smooth teleworking. 
After creating this article (http://www.experts-exchange.com/articles/23699/Setup-Mikrotik-routers-with-OSPF.html), I decided to make a video (no audio) to show you how to configure the routers and run some trace routes and pings between the 7 sites…
This video gives you a great overview about bandwidth monitoring with SNMP and WMI with our network monitoring solution PRTG Network Monitor (https://www.paessler.com/prtg). If you're looking for how to monitor bandwidth using netflow or packet s…

707 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question

Need Help in Real-Time?

Connect with top rated Experts

19 Experts available now in Live!

Get 1:1 Help Now