Problem with AddPortEx API call in VBA (Access) vs. VB

I have a weird problem. I use the following code to change the port to which a particular printer is attached:

    Private Type PORT_INFO_1
      pPortName As String
    End Type
   
    Private Type PRINTER_DEFAULTS
      pDatatype     As String
      pDevMode      As Long
      DesiredAccess As Long
    End Type
   
    Private Const STANDARD_RIGHTS_REQUIRED = &HF0000
    Private Const PRINTER_ACCESS_USE = &H8
    Private Const PRINTER_ACCESS_ADMINISTER = &H4
    Private Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED Or _
                                        PRINTER_ACCESS_ADMINISTER Or _
                                        PRINTER_ACCESS_USE)
    Private Const ERROR_INSUFFICIENT_BUFFER = 122
   
    Private Declare Function AddPortEx _
      Lib "winspool.drv" _
      Alias "AddPortExA" ( _
      ByVal pName As String, _
      ByVal pLevel As Long, _
      lpBuffer As Any, _
      ByVal pMonitorName As String) As Long
    Private Declare Function ClosePrinter _
      Lib "winspool.drv" ( _
      ByVal hPrinter As Long) As Long
    Private Declare Function GetPrinter _
      Lib "winspool.drv" _
      Alias "GetPrinterA" ( _
      ByVal hPrinter As Long, _
      ByVal Level As Long, _
      pPrinter As Long, _
      ByVal cbBuf As Long, _
      pcbNeeded As Long) As Long
    Private Declare Function lstrcpy _
      Lib "kernel32" _
      Alias "lstrcpyA" ( _
      ByVal lpString1 As Long, _
      ByVal lpString2 As String) As Long
    Private Declare Function OpenPrinter _
      Lib "winspool.drv" _
      Alias "OpenPrinterA" ( _
      ByVal pPrinterName As String, _
      phPrinter As Long, _
      pDefault As PRINTER_DEFAULTS) As Long
    Private Declare Function SetPrinter _
      Lib "winspool.drv" _
      Alias "SetPrinterA" ( _
      ByVal hPrinter As Long, _
      ByVal Level As Long, _
      pPrinter As Long, _
      ByVal Command As Long) As Long
   
    Public Function SetPrinterPort(pstrPrinterName As String, _
                                   pstrPortName As String) As Boolean
   
      Dim pi1        As PORT_INFO_1
      Dim fRet       As Boolean
      Dim alngBuf()  As Long
      Dim pdDefaults As PRINTER_DEFAULTS
      Dim lngHPrntr  As Long
      Dim lngNeeded  As Long
     
      pi1.pPortName = pstrPortName
      fRet = AddPortEx(vbNullString, 1, pi1, "Local Port")
     
      ReDim alngBuf(1)
     
      pdDefaults.DesiredAccess = PRINTER_ALL_ACCESS
      pdDefaults.pDatatype = "RAW"
      pdDefaults.pDevMode = 0
     
      If OpenPrinter(pstrPrinterName, lngHPrntr, pdDefaults) = 0 Then
        Exit Function
      End If
     
      GetPrinter lngHPrntr, 2, alngBuf(0), 0, lngNeeded
      If Err.LastDllError <> ERROR_INSUFFICIENT_BUFFER Then
        ClosePrinter lngHPrntr
        Exit Function
      End If
     
      ReDim alngBuf((lngNeeded \ 4) + (Len(pstrPortName) \ 2) + 2)
      If GetPrinter(lngHPrntr, 2, alngBuf(0), lngNeeded, lngNeeded) = 0 Then
        ClosePrinter lngHPrntr
        Exit Function
      End If
     
      lstrcpy VarPtr(alngBuf((lngNeeded \ 4) + 1)), pstrPortName
      alngBuf(3) = VarPtr(alngBuf((lngNeeded \ 4) + 1))
     
      If SetPrinter(lngHPrntr, 2, alngBuf(0), 0) = 0 Then
        ClosePrinter lngHPrntr
        Exit Function
      End If
     
      ClosePrinter lngHPrntr
     
      SetPrinterPort = True
   
    End Function

When that exact code is in a standard module in a VB6 project, it works perfectly. When I put that exact code into a standard module in Access 2002 (XP) on the very same machine, it does not work. The AddPortEx() call does not add the port, so the call to SetPrinter() fails. I am completely stumped. I know that there are some differences between VB and VBA, but I didn't think it would affect API calls. Is there something that has to be different about the Declare in VB vs. VBA? Any tips you can give me would be most appreciated!

TIA,

Jeff