Link to home
Start Free TrialLog in
Avatar of AJKConcepts
AJKConcepts

asked on

VB6 Program Appears Frozen While Running

Hi all,

I seem to have the same problem with every VB6 app I write. While it is running through the loops of database code, the program appears frozen and I have to wait till it finishes. I have tried DoEvents, but it doesn't work. I have a text field that updates after each record is written and I just want to be able to see the textfield while the program is running. Is this not possible? Here is a snippet of code below, but it's actually doing this anytime any of my programs have any sort of loop. What am I missing? I've tried putting in a progress bar, and that doesn't work either.

DoEvents
        While Not EOF(1)
            Line Input #1, inputString
            tempArray = Split(inputString, vbTab)
             If UBound(tempArray) > 0 Then
                taxID = Replace(tempArray(2), "'", "")
                    If tempArray(10) <> "''" Then
                        faxNumber = Replace(tempArray(10), "'", "")
                        SQLstring = "UPDATE tblProvider SET FAX = '" & faxNumber & "' WHERE taxID = " & taxID
                        dbConnection.dbConnection.Execute SQLstring, , adExecuteNoRecords
                        frmMain.txtResult.Text = frmMain.txtResult.Text & "record " & taxID & " updated" & vbCrLf
                        frmMain.txtResult.Refresh
                    End If
                Else
                    '---write to the log file
                    objTxtStream.Write inputString & vbCrLf
                End If
        Wend
Avatar of zorvek (Kevin Jones)
zorvek (Kevin Jones)
Flag of United States of America image

The best way to pause code execution is to provide a mechanism that gives the parent application such as Excel or Word opportunities to handle events as well as other operating system tasks. The routine below provides both and allows a pause of as little as a hundredth of a second.

Note that the declaration of the Sleep API function has to be placed above all other routines in the module.

[Begin Code Segment]

Public Declare Sub Sleep Lib "kernel32" (ByVal Milliseconds As Long)

Public Sub Pause( _
      ByVal Seconds As Single, _
      Optional ByVal PreventVBEvents As Boolean _
   )

' Pauses for the number of seconds specified. Seconds can be specified down to
' 1/100 of a second. The Windows Sleep routine is called during each cycle to
' give other applications time because, while DoEvents does the same, it does
' not wait and hence the VB loop code consumes more CPU cycles.

   Const MaxSystemSleepInterval = 25 ' milliseconds
   Const MinSystemSleepInterval = 1 ' milliseconds
   
   Dim ResumeTime As Double
   Dim Factor As Long
   Dim SleepDuration As Double
   
   Factor = CLng(24) * 60 * 60
   
   ResumeTime = Int(Now) + (Timer + Seconds) / Factor
   
   Do
      SleepDuration = (ResumeTime - (Int(Now) + Timer / Factor)) * Factor * 1000
      If SleepDuration > MaxSystemSleepInterval Then SleepDuration = MaxSystemSleepInterval
      If SleepDuration < MinSystemSleepInterval Then SleepDuration = MinSystemSleepInterval
      Sleep SleepDuration
      If Not PreventVBEvents Then DoEvents
   Loop Until Int(Now) + Timer / Factor >= ResumeTime
   
End Sub

[End Code Segment]

The DoEvents call is used to give the managed environment such as Excel or Word opportunities to handle events and do other work. But DoEvents only works within the managed environment and can still consume a considerable amount of resources without some other throttling mechanism. By also using the Windows Sleep API call the Windows operating system is given an opportunity to let other processes run. And, since the code is doing nothing but waiting, it is the appropriate thing to do.

Often the task involves waiting for an asynchronous task to complete such as a web query. To use the above routine while waiting for such a task to compete, two time durations are needed: the total amount of time to wait until it can be assumed that a failure has occurred in the other task, and the amount of time to wait between checks that the other task has completed. Determining how long to wait until giving up requires consideration of the longest possible time that the task could reasonably take and how long the user is willing to wait for that task to complete - wait too long and the user gets frustrated, don't wait long enough and the risk increases of falsely assuming an error occurred when it didn't. This duration is the more difficult to determine of the two. The second time, the duration between checks for completion, is easier to determine. This duration should be long enough to not consume unnecessary CPU cycles doing the check, but short enough to respond quickly when the status of the asynchronous task changes. A duration of between a quarter of a second and one second is usually reasonable. The sample code below illustrates how to wait for an asynchronous task to complete that usually finishes in less than 10 seconds.

   Dim TimeoutTime As Date
   TimeoutTime = Now() + TimeSerial(0, 0, 30) ' Allow 30 seconds for the asynchronous task to complete before assuming it failed
   Do While Now() < TimeoutTime And Not IsTaskComplete
      Pause 0.5 ' Pause half a second to allow the ashyncronous task (and the rest of the environment) to do work
   Loop

The above example uses a function named IsTaskComplete to determine if the asynchronous task completed. The function can do anything such as checking if a cell changed, checking if a control's property is set, or checking if a file exists.

Other techniques for pausing code execution and the problems with each are listed below. These should all be avoided in any well-designed application.

Wait Method (VBA only):

   Application.Wait Now + Time(0, 0, 10)

The Wait method suspends all application activity and may prevent other operations from getting processing time while Wait is in effect. However, background processes such as printing and recalculation continue. The net effect of pausing using the Wait method is to shut down the application (e.g. Excel) event handling and slow or stop other applications. This method does not allow any fractional seconds to be used.

Windows Sleep:

   Public Declare Sub Sleep Lib "kernel32" (ByVal Milliseconds As Long)
   Sleep 10000

Using the Sleep Windows API call is system friendly by allowing all other processes to get processing time but it effectively shuts down the parent application.

DoEvents Loop

   Do
      DoEvents
   Loop Until Now > TimeoutTime

Performing a DoEvents loop to pause gives the parent application a chance to handle events but, because there is no pause between DoEvents calls, virtually all available processing time is dedicated to the loop and nothing else which means this is not a good way to pause code execution. This method does not allow any fractional seconds to be used.

Basic Loop without DoEvents

   Do
   Loop Until Now > TimeoutTime

A tight loop without a DoEvents call effectively brings the workstation to a halt until the loop exits. This is the worst technique to pause code execution. This method does not allow any fractional seconds to be used.

There are other, more sophisticated, techniques that monitor event queues and other system resources but the net result is the same as a simple loop with both a DoEvents and a Sleep. As long as some other throttling mechanism is used such as the Windows Sleep function, DoEvents will consume very little resources as all it does is look for any pending events and then either process those events or return immediately to the caller.

Kevin
ASKER CERTIFIED SOLUTION
Avatar of zorvek (Kevin Jones)
zorvek (Kevin Jones)
Flag of United States of America image

Link to home
membership
This solution is only available to members.
To access this solution, you must be a member of Experts Exchange.
Start Free Trial
A small pause INSIDE the loop may still be warranted as this prevents the loop from ramping CPU usage up to 100%...

* So you need both:

-->   DoEvents to allow the app to process its message queue and remain responsive...including the ability to paint itself.
-->   Sleep() to throttle it back and not use 100% CPU cycles.  We're talking a small interval like 50 milliseconds.

Neither should be called for every iteration of the loop though.  You can either call them every XXX iterations or use a timing mechanism to call it every YYY milliseconds using methods no unlike the code above.


Idle_Mind's suggestion is good....it is a golden rule

When erever you start coding a Do or a For loopAs soon as you type the Do/For line you always put a doevents in the loop

Do Until Question=Answer
   ' then you start coding here
   DoEvents
Loop

Same for Do While and For Next loops, make it a habit.

zorvek: posted some good ideas and some bad ideas

This code is excellent and will use very very little CPU time about one second of CPU time very week on a continuous process..

Dim TimeoutTime As Date
   TimeoutTime = Now() + TimeSerial(0, 0, 30) ' Allow 30 seconds for the asynchronous task to complete before assuming it failed
   Do While Now() < TimeoutTime And Not IsTaskComplete
      Pause 0.5 ' Pause half a second to allow the ashyncronous task (and the rest of the environment) to do work
   Loop

But NEVER use Sleep for more then one second becuase if Windows decides to send you application a system message, the whole of windows will hand until the end og the sleep period.  Although Sleep is supposed to halt if there is a message I have seen examples where it does not.

1) Create a new project
2) add command1 to the form
3) pase the following code
4) hit run
5) click on sleep, then try to minimize the form

You will notice the whole system become slugissh


Option Explicit

Private Declare Sub Sleep Lib "kernel32" (ByVal Milliseconds As Long)

Private Sub Command1_Click()
Sleep 20000 ' twenty second
End Sub

Private Sub Form_Load()
Command1.Caption = "Sleep"
End Sub

Depending on the type of message that windows needs to send your app, if the message contains a pointer to a memory block, and your app is a servce, the whole PC will appear to die.

So a sleep of 1 second is tha max you should ever use....hope this helps:~)

ps I created my own version of Now which uses clock ticks and works about 50% faster than Now.
>But NEVER use Sleep for more then one second...

And that's one of the reasons there is a built-in maximum Sleep duration of 25 milliseconds in my Pause routine. The whole purpose of the Pause routine was to combine the best of Sleep and DoEvents and overcome the limitations of using each in isolation while maximizing application AND Windows responsiveness.

As far as Sleep itself goes, anyone building Windows services that receives events with pointers to memory blocks should be well beyond using sleep for ANY significant duration of time. The ONLY reason to use Sleep with anything more than a few milliseconds is if the application really needs to be put to sleep AND no other process depends on it.

Kevin
zorvek the reaone why I thought that one of your sleep loos deserved praise becuase  it had no calculations within the loop. But the other one did.

Unfortunately any application can be subject to hanging the windows system. It is a feature of the way the windows sends system messages. Some messages need to have some meory allocated, in this case windows has to wait until the the message is received so it can destroy the memory that was allocated. But if you stick to very short pauses that is perfect.