Solved

Get the whole registry of a remote machine

Posted on 2007-08-11
1
216 Views
Last Modified: 2010-03-05
Hi,

Is there a software to get the remote registry edit it and upload it back for the changes.

Regards
Sharath
0
Comment
Question by:bsharath
1 Comment
 
LVL 26

Accepted Solution

by:
farhankazi earned 500 total points
ID: 19676921
Third party software:
http://www.emco.is/registry_merge/features.html

:: ================
:: READ THIS FIRST
:: ================
:: * To run this script you must have domain administrators rights.
:: * This script require "PSExec.exe" file (comes with PSTools) on C: drive root
:: * This script require "Computers.txt" file on C: drive root from where it will pick computer names.
:: * You need to set 'RegFile' variable's value inside the script
::    Like:
::             SET RegFile=C:\IESettings.reg   <-- registry file
::    WARNING:  Registry file should be in proper format.  
::    WARNING:  If you set this file incorrectly, you may cause serious problems that may require you to reinstall your operating system
::   For more info visit: http://support.microsoft.com/kb/310516
:: * Successful run will generate "C:\RegImportRpt.txt" file on C: drive root.
:: * Copy and Paste following script into notepad and save it with any name having .cmd extension.
:: Batch Script Start

@Echo Off
SETLOCAL
SET RegFile=C:\IESettings.reg

IF NOT EXIST C:\Computers.txt Goto ShowErr
FOR %%R IN (C:\Computers.txt) Do IF %%~zR EQU 0 Goto ShowErr
IF NOT EXIST %RegFile% ( Echo Can not find %RegFile% file. && Goto :EndScript)

IF EXIST C:\RegImportRpt.txt DEL /F /Q C:\RegImportRpt.txt
FOR %%F IN (%RegFile%) DO SET RegFName=%%~nF%%~xF

FOR /F %%c IN ('Type C:\Computers.txt') Do (
    Echo Processing: %%c
      PING -n 1 -w 800 %%c|Find /I "TTL" >NUL
      IF NOT ErrorLevel 1 (
            Echo Importing Regintry on: %%c >>C:\RegImportRpt.txt
            Copy /Y %RegFile% \\%%c\C$\ >>C:\RegImportRpt.txt
            PSExec \\%%c -s -i Regedit /S C:\%RegFName%
            DEL /Q /F \\%%c\C$\%RegFName%
      )ELSE (Echo %%c: Not able to connect >>C:\RegImportRpt.txt)
)      

Goto EndScript
:ShowErr
Echo "C:\Computers.txt" file does not exist or file is empty!
:EndScript
ENDLOCAL
:: Batch Script End
0

Featured Post

Free Webinar: AWS Backup & DR

Join our upcoming webinar with experts from AWS, CloudBerry Lab, and the Town of Edgartown IT to discuss best practices for simplifying online backup management and cutting costs.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

My previous article  (http://www.experts-exchange.com/OS/Microsoft_Operating_Systems/Server/Windows_Server_2008/A_4466-A-beginners-guide-to-installing-SCCM2007-on-Windows-2008-R2-Server.html)detailed one possible method to get SCCM 2007 installed an…
Remote Apps is a feature in server 2008 which allows users to run applications off Remote Desktop Servers without having to log into them to run the applications.  The user can either have a desktop shortcut installed or go through the web portal to…
This video Micro Tutorial explains how to clone a hard drive using a commercial software product for Windows systems called Casper from Future Systems Solutions (FSS). Cloning makes an exact, complete copy of one hard disk drive (HDD) onto another d…
With the advent of Windows 10, Microsoft is pushing a Get Windows 10 icon into the notification area (system tray) of qualifying computers. There are many reasons for wanting to remove this icon. This two-part Experts Exchange video Micro Tutorial s…

680 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question