Modify calendar invitiation entry button to also remove calendar entry on prompt

' This is where you customize everything that can be customized about this button.
' The year, month and day of the event.
Const EVENT_YEAR = 2007
Const EVENT_MONTH = 3
Const EVENT_DAY = 9
' The time zone where the event is taking place.
' This is the number of hours you must subtract to get UTC. 
' Sample values:
' USA: Eastern Time = -5, Eastern Time with Daylight Savings = -4.
' UK: GMT = 0, GMT with Daylight Savings = +1.
Const EVENT_TIME_ZONE = -5
' The start time of the event. 
' These values are in 24 hour clock, also known as military time.
' 13 = 1pm = 13, 2pm = 14, 3pm = 15, 4pm = 16, 5pm = 17.
' These values are in the time zone specified above
Const EVENT_HOUR = 12
Const EVENT_MINUTE = 30
' The duration of the event in hours.
Const EVENT_DURATION = .5
' The description of the event.
Const EVENT_DESCRIPTION = "EVENT Teleconference"
' The Notes If the person hosting the event.
Const EVENT_HOST = "Fatumata Soukouna"
' The location where the event is taking place.
Const EVENT_LOCATION = "Teleconference: US Toll Free:800 XXX-XXXX / International Toll: 706 XXX-XXXX  Passcode: XXXXXXX"
Const Event_body = "Presentation and Replay of this call will be available on the Tech Lib at: http://www.xxx.com"
' An icon to use for the event.
' Values are listed in the Domino Designer Help if you search for "icon column".
' Some good ones:
' 4 = a bunch of people
' 10 = a finger with string tied around it
' 11 = an "information" sign
' 15 = a loudspeaker broadcasting sound
' 23 = a newspaper
' 44 = a telephone
' 45 = a telephone off the hook
' 56 = nerdy glasses
' 67 = radio transmitter
' 70 = the earth
' 85 = smiley face
' 91 = bomb
' 97 = red diamond
' 139 = a video camera
' 148 = the sun shining
' 150 = a red exclamation mark
' 158 = hands shaking
' 163 = a man (spy?) in a red hat
' 166 = groucho glasses
' 173 = airplane flying
Const EVENT_ICON = 148
' All done. 
 
------------
 
Sub Click(Source As Button)
	' ############################################################################################
	' Attention users:
	' Configure this button  via the (Declarations) section, accessed from the Objects tab that should be to the left of this text.
	' ############################################################################################
	
	' No user-servicable parts below this line.
	' You may notice that the following code is tricky. It has to be, because of the following problems with the Notes APIs:
	' 1) Textual dates and times are interpreted according to the user's local OS settings when the code runs. 
	'     That means you can't use New NotesDateTime with a simple constant string to create a date and time field.
	' 2) There's no way to set a NotesDateTime directly to a given time, other than to use a string. You have to go via a
	'    LotusScript date/time value.
	' 3) LotusScript date/time values have no time zone associated with them, so you can't use them directly to create
	'    fields in a document.
	' 4) You can only convert a LotusScript date/time to a NotesDateTime in the local time zone of the user, not in UTC.
	' 5) @Zone and NotesInternational do not behave as documented. They are described as returning information about
	'    whether DST is in effect. In fact, they return whether DST will be in effect at any point during the year, so they're useless.
	
	' Step 1. Work out what time zone the user will be in on the appointment date, including any DST offset.
	' First, work out when noon is on the appointment date as a LotusScript date/time.
	Dim noon As Variant
	noon = Timenumber(EVENT_HOUR, EVENT_MINUTE, 0) + Datenumber(EVENT_YEAR, EVENT_MONTH, EVENT_DAY)
	' Then create a NotesDateTime at that local date/time.
	Dim startndt As New NotesDateTime("Now")
	startndt.LSLocalTime = noon
	Dim noongmt As Variant
	' Now work out the corresponding GMT time as a LotusScript date/time.
	noongmt = startndt.LSGMTTime
	Dim tzoffset As Variant
	' Subtract the two, multiply by 24 and round to 1 decimal place to get the user's time zone offset from GMT on the specified date.
	tzoffset = Round(24 * (noon - noongmt), 1)
	
	' Step 2. Work out a LotusScript date/time for the event.
	' First work it out in GMT, using the time zone offset we were given.
	Dim lsevent As Variant
	lsevent = Timenumber(EVENT_HOUR, EVENT_MINUTE, 0) + Datenumber(EVENT_YEAR, EVENT_MONTH, EVENT_DAY)
	lsevent = lsevent - (EVENT_TIME_ZONE / 24)
	' Then convert to user's time zone on that date, as computed in step 1.
	lsevent = lsevent + (tzoffset / 24)
	
	' Step 3. Convert to a NotesDateTime
	startndt.LSLocalTime = lsevent
	' Do the same for the end date/time
	Dim endndt As New NotesDateTime("Now")
	endndt.LSLocalTime = lsevent + (EVENT_DURATION / 24)
	
	' Step 4. Create the appointment document.
	' Find user's mail database, open it, create a document.
	' Dim session As New NotesSession
	' Dim maildb As NotesDatabase
	' Set maildb = session.CurrentDatabase
	' previous lines commented for testing
	
	Dim maildb As New NotesDatabase("", "")
	Call maildb.OpenMail
	
	Dim memo As NotesDocument
	Set memo = maildb.CreateDocument
	' Call function to write fields.
	Call WriteAppointment(memo, startndt, endndt, EVENT_DESCRIPTION, EVENT_HOST, EVENT_LOCATION, EVENT_ICON)
	Call memo.Save(True, False, False)
	Messagebox "Appointment added March 9 12:30pm est."
End Sub
 
----------------
 
Sub WriteAppointment(doc As NotesDocument, ndtstart As NotesDateTime, ndtend As NotesDateTime, _
desc As String, host As String, locn As String, icn As Integer)
	' Function to write essential fields to a document to create a calendar appointment
	' Arguments are:
	' NotesDocument to write to
	' NotesDateTime start of event
	' NotesDateTime end of event
	' String description of event
	' String name of host (e.g. John Doe/xxxxxxx/xxx)
	' String location of event
	' Integer icon to use in view
	
	' Work out the host's name in canonical format
	Dim nname As New NotesName(host)
	' Write the document fields
	doc.Form = "Appointment"
	doc.Principal = nname.Canonical
	doc.Chair = nname.Canonical
	doc.AltChair = nname.Canonical
	Call doc.ReplaceItemValue("StartDateTime", ndtstart)
	Call doc.ReplaceItemValue("EndDateTime", ndtend)
	Call doc.ReplaceItemValue("CalendarDateTime", ndtstart)
	Call doc.ReplaceItemValue("_ViewIcon", icn)
	doc.From = nname.Canonical
	Call doc.ReplaceItemValue("StartTime", ndtstart)
	doc.AppointmentType = "0"
	doc.Subject = desc
	doc.Location = locn
	doc.Body = Event_Body
	Call doc.ReplaceItemValue("EndDate", ndtend)
	Call doc.ReplaceItemValue("EndTime", ndtend)
	doc.Alarms = "1"
	Call doc.replaceItemValue("$Alarm", 1)
	Call doc.replaceItemValue("$AlarmDescription", desc)		
	Call doc.replaceItemValue("$AlarmOffset", -10)
	Call doc.replaceItemValue("$AlarmUnit", "M")
	Dim tmpitem As NotesItem
	Set tmpitem = doc.replaceItemValue("ExcludeFromView", "D")
	Call tmpitem.appendToTextList("S")
End Sub

Select allOpen in new window