• Status: Solved
  • Priority: Medium
  • Security: Public
  • Views: 515
  • Last Modified:

Timeout MSSqlServer 2005 from VB6 during Open Table

Hallo Experts,
My Vb6 Application tries to open a Table to add new records to this table.
Mostly during system backup time i get this message:
"Abfragetimeout abgelaufen (-2147217871)" (meaning something like "retrieval timeou") after 30 s.
I did not found a means to change this timeout (oconn.CommandTimeout = 120 did not work)
Any suggestion?
Josef
Dim oConn As ADODB.Connection
  Dim rst1 As ADODB.Recordset
 
  Set oConn = New ADODB.Connection
  With oConn
    .Provider = sProvider
    .Properties("Data Source") = sDataSource
    .Properties("User ID") = sUserID
    .Properties("Password") = sPassword
    .Properties("Initial Catalog") = sInitialCatalog
    .CursorLocation = adUseClient
'    .ConnectionTimeout = 120 'no difference
'    .CommandTimeout = 120    'no difference
    .Open
  End With 'oConn
 
  Set rst1 = New ADODB.Recordset
  rst1.CursorType = adOpenKeyset
  rst1.LockType = adLockBatchOptimistic
 
  rst1.Open "Messwerte", oConn.ConnectionString, , , adCmdTable
 
'here the timeout occurs

Open in new window

0
joschramm
Asked:
joschramm
  • 4
  • 4
1 Solution
 
Guy Hengel [angelIII / a3]Billing EngineerCommented:
change:
  rst1.Open "Messwerte", oConn.ConnectionString, , , adCmdTable

into:
  rst1.Open "select * from Messwerte where 1=0 ", oConn.ConnectionString

this will return 0 records, be very fast, and still allow you to add new records.

0
 
joschrammAuthor Commented:
Many thanks, Angelllll.
i tested your solution  "at home" - seems to work fine (but   h e r e  i get no timeouts at all, of course). Now i sent the application "into the field" and tomorrow i will know more.

You will hear from me,
hpefully josef
0
 
joschrammAuthor Commented:
responsetime is down from 15 s to 2 s (mean time during duty hours) respectively from far more then 30 s to 10 s (during backup time). But what magic is here at work? Due to the textbook you have to open the table then add a record.
How comes that your solution "still allow you to add new records"?
sincerly,
Josef
0
Transaction-level recovery for Oracle database

Veeam Explore for Oracle delivers low RTOs and RPOs with agentless transaction log backup and transaction-level recovery of Oracle databases. You can restore the database to a precise point in time, even to a specific transaction.

 
Guy Hengel [angelIII / a3]Billing EngineerCommented:
<Grading Comments>
responsetime is down from 15 s to 2 s (mean time during duty hours) respectively from far more then 30 s to 10 s (during backup time).
But what magic is here at work? Due to the textbook you have to open the table then add a record.
How comes that your solution "still allow you to add new records"?
sincerly,
Josef
</Grading Comments>

as explained, using the select to return 0 records will avoid that the opentable will have to return ALL (yes, all) the records from the table to the client computer.
so, imagine for a table with 1 Million records, and 10 clients try to add 1 record with the original code :)

this side effect is what the text books do not explain, as it would go much too far in details for just getting the kick off how to work in general... (and maybe to give the experts the way to look good, afterwards :) )

glad it worked for you.
0
 
Guy Hengel [angelIII / a3]Billing EngineerCommented:
ps:
>"Abfragetimeout abgelaufen (-2147217871)" (meaning something like "retrieval timeou") after 30 s.
means command timeout has expired...

indeed, the command timeout is at default 30 seconds. you could change the command timeout from 30 to another value (ie 0 for infinite timeout), but as you might want to agree: better make the query short than the wait time long :)
0
 
joschrammAuthor Commented:
> you could change the command timeout from 30 to another value (ie 0 for infinite timeout)
but how? (If it will be necessary in other circumstances...)

nevertheless:
> but as you might want to agree: better make the query short than the wait time long :)
I do agree indeed, severe.
Thanks again for your help
0
 
Guy Hengel [angelIII / a3]Billing EngineerCommented:
re: command timeout:

the main problem why the "command timeout" did not work in your original code was this line:
  rst1.Open "Messwerte", oConn.ConnectionString, , , adCmdTable

you passed the connection string instead of the connection object.
  rst1.Open "Messwerte", oConn, , , adCmdTable

that differences solves:
* the connection was already open, so your original code reopened it again with the recordset
* the commandtimeout set on the connection object was not incorporated in the connectionstring returned, hence "ignored"

another way to do it is using the Command Object:
  Dim oConn As ADODB.Connection
  dim oCmd as ADODB.Command
  Dim rst1 As ADODB.Recordset
 
  Set oConn = New ADODB.Connection
  With oConn
    .Provider = sProvider
    .Properties("Data Source") = sDataSource
    .Properties("User ID") = sUserID
    .Properties("Password") = sPassword
    .Properties("Initial Catalog") = sInitialCatalog
    .CursorLocation = adUseClient
'    .ConnectionTimeout = 120 'no difference
'    .CommandTimeout = 120    'no difference
    .Open
  End With 'oConn
 
  Dim oCmd as ADODB.Command
  Set oCmd = New ADODB.Command
  Set oCmd.ActiveConnection = oConn
  oCmd.CommandTimeout = 120
  oCmd.CommandText = "select * from Messwerte where 1=0 "
 
  Set rst1 = New ADODB.Recordset
  rst1.CursorType = adOpenKeyset
  rst1.LockType = adLockBatchOptimistic
 
  rst1.Open oCmd
 

Open in new window

0
 
joschrammAuthor Commented:
ah, now I understand it!
very good
Josef
0

Featured Post

Free Tool: Path Explorer

An intuitive utility to help find the CSS path to UI elements on a webpage. These paths are used frequently in a variety of front-end development and QA automation tasks.

One of a set of tools we're offering as a way of saying thank you for being a part of the community.

  • 4
  • 4
Tackle projects and never again get stuck behind a technical roadblock.
Join Now