Solved

Use spin button to move items in listbox up and down

Posted on 2008-10-09
2
962 Views
Last Modified: 2013-12-26
I have a list box with a numerous items. I want to put a spinbutton beside it so that the user can select and item to move up and down in the list. As they move it I want to adjust the data on the excel sheet accordingly. I know how to move the data. but i don't know how to link the spinbutton and control how to move the data as it is pressed up or down. Thanks
0
Comment
Question by:tchristie33
2 Comments
 
LVL 23

Accepted Solution

by:
irudyk earned 250 total points
ID: 22687610
Try using the following code.  Change SpinButton1 to the name of the name of your spin button control and change ListBox1 to the name of your list box control.
Private Sub SpinButton1_SpinDown()
Call MoveListItem(True)
End Sub
 
Private Sub SpinButton1_SpinUp()
Call MoveListItem(False)
End Sub
 
Function MoveListItem(blnShiftDown As Boolean)
 
If ListBox1.ListIndex < 0 Or _
ListBox1.ListIndex = 0 And Not blnShiftDown Or _
ListBox1.ListIndex = ListBox1.ListCount - 1 And blnShiftDown Then Exit Function
 
Dim i As Integer
Dim strListItems() As String
ReDim strListItems(ListBox1.ListCount - 1)
 
For i = 0 To ListBox1.ListIndex - IIf(blnShiftDown, 1, 2)
    strListItems(i) = ListBox1.List(i)
Next i
strListItems(i) = ListBox1.List(ListBox1.ListIndex + IIf(blnShiftDown, 1, 0))
strListItems(i + 1) = ListBox1.List(ListBox1.ListIndex - IIf(blnShiftDown, 0, 1))
 
For i = ListBox1.ListIndex + IIf(blnShiftDown, 2, 1) To ListBox1.ListCount - 1
    strListItems(i) = ListBox1.List(i)
Next i
 
ListBox1.List = strListItems
 
End Function

Open in new window

0
 
LVL 22

Assisted Solution

by:danaseaman
danaseaman earned 250 total points
ID: 22692279
You can swap List items using just a temp string. No intermediate array needed.
Following code moves List items Up or Down, checks for upper;lower bounds, and updates the ListIndex.

Option Explicit
 
Private Sub Form_Load()
   Dim i As Long
   For i = 1 To 10
      ListBox1.AddItem "Item " & Chr(64 + i)
   Next
End Sub
 
Private Sub SpinButton1_SpinDown()
   Dim SelIndex         As Long
   Dim Temp             As String
   
   SelIndex = ListBox1.ListIndex
   If (SelIndex >= 0) And (SelIndex < ListBox1.ListCount - 1) Then
      Temp = ListBox1.List(SelIndex + 1)
      ListBox1.List(SelIndex + 1) = ListBox1.List(SelIndex)
      ListBox1.List(SelIndex) = Temp
      ListBox1.ListIndex = ListBox1.ListIndex + 1
   End If
End Sub
 
Private Sub SpinButton1_SpinUp()
   Dim SelIndex         As Long
   Dim Temp             As String
   
   SelIndex = ListBox1.ListIndex
   If SelIndex > 0 Then
      Temp = ListBox1.List(SelIndex - 1)
      ListBox1.List(SelIndex - 1) = ListBox1.List(SelIndex)
      ListBox1.List(SelIndex) = Temp
      ListBox1.ListIndex = ListBox1.ListIndex - 1
   End If
End Sub

Open in new window

0

Featured Post

Netscaler Common Configuration How To guides

If you use NetScaler you will want to see these guides. The NetScaler How To Guides show administrators how to get NetScaler up and configured by providing instructions for common scenarios and some not so common ones.

Question has a verified solution.

If you are experiencing a similar issue, please ask a related question

Enums (shorthand for ‘enumerations’) are not often used by programmers but they can be quite valuable when they are.  What are they? An Enum is just a type of variable like a string or an Integer, but in this case one that you create that contains…
When you see single cell contains number and text, and you have to get any date out of it seems like cracking our heads.
Get people started with the process of using Access VBA to control Excel using automation, Microsoft Access can control other applications. An example is the ability to programmatically talk to Excel. Using automation, an Access application can laun…
Get people started with the utilization of class modules. Class modules can be a powerful tool in Microsoft Access. They allow you to create self-contained objects that encapsulate functionality. They can easily hide the complexity of a process from…

773 members asked questions and received personalized solutions in the past 7 days.

Join the community of 500,000 technology professionals and ask your questions.

Join & Ask a Question